The Horrible Pyramid — 4 of 15

Section - Defaults And Miscellaneous

Understand "admire [something]" as examining.

Instead of singing:

say "[if prog is 0]You hum softly to yourself[otherwise if prog is 1]You sing a song from a movie you saw[otherwise if prog is 2]You sing backwards, confusing all those around[otherwise if prog is 3]You sing an E over high C for as many seconds as you are able to hold onto it[end if].";

Understand "dance" as a mistake ("[if prog is 0]You don't remember how to dance[otherwise if prog is 1]You shuffle back and forth for a few seconds[otherwise if prog is 2]You spin around the room[otherwise if prog is 3]You undance a lifetime of previous dances. Blank slate[end if].").

Instead of attacking something:

say "[if prog is less than 2]Everything in this tomb needs to be treated with the utmost care and respect[otherwise]You can't break that! You and Apepsikret might need it in the afterlife.";

Mouthing is an action applying to one thing. Understand "kiss [something]" and "mouth [something]" as mouthing.

Instead of mouthing something:

say "[if prog is less than 2]That would be decidedly unprofessional[otherwise]You kiss [the noun] passionately, memorizing its surface with your tongue[end if].";

Instead of kissing the player:

say "What a good idea."

Instead of jumping:

say "You jump, but what this accomplishes is unknown to you.";

Instead of smelling:

say "Dust."

Instead of smelling something:

say "You fail to smell anything meaningful."

Instead of thinking:

say "You can't remember what you were trying to think about.";

Instead of waking up:

say "Right now, at least, you are definitely awake.";

Instead of sleeping:

say "You can sleep later.";

Understand "pray" as a mistake ("[if prog is less than 2]Praying in this tomb seems a trifle sacreligious[otherwise]You say a prayer to your god-king Apepsikret, asking for his blessing, which of course he will give to a loyal follower/love-slave like you[end if].").

Understand "use [text]" as a mistake ("[italic type]Sorry, 'use' is too vague a verb for this text parser. Can you try something else?[roman type]").

Before inserting something which is not carried by the player into something:

if the noun is in the second noun, say "It's already in there." instead;

say "First you take [the noun].[line break]";

silently try taking the noun;

if the player is not holding the noun, stop the action.

Before putting something which is not carried by the player on something:

if the noun is on the second noun, say "It's already on that." instead;

say "First you take [the noun].[line break]";

silently try taking the noun;

if the player is not holding the noun, stop the action.

Thanking is an action applying to nothing. Understand "awesome" or "okay" or "great" or "nice" or "yay" or "hooray" or "good" or "thanks" or "thx" or "thank you" as thanking.

Carry out thanking:

say "You're welcome."

Expressing displeasure is an action applying to nothing. Understand "dangit" or "dang" or "darn" or "drat" or "shut up" or "aw" or "aww" or "awww" or "agh" or "arg" or "argh" or "crud" as expressing displeasure.

Instead of swearing mildly, try expressing displeasure.

Instead of swearing obscenely, try expressing displeasure.

Carry out expressing displeasure:

say "[if prog is 0]You curse quietly[otherwise if prog is 1]You say a cuss word[otherwise if prog is 2]You swear loudly[otherwise]Silence! Apepsikret will not tolerate such naughty language[end if].";

Instead of saying sorry:

say "Apology accepted."

Understand "flip [something]" as turning.

Understand "Hail Apepsikret" as a mistake ("'Hail Apepsikret,' you say aloud.").

Instead of touching something:

if the noun is a monkey:

say "[if prog is 0]The silver is cool to the touch[otherwise if prog is 1]It feels smooth and cold; those are the main two feelings[otherwise if prog is 2][The noun] feels cold. Cold like a broken promise[otherwise if prog is 3]The figurine feels perfect, the way a human body feels when it's pressed up against another human body[end if].";

otherwise if the noun is wearable:

say "[if prog is 0]The gold is cool to the touch. The weight of [the noun] against your fingers is oddly exciting[otherwise if prog is 1]It feels oh so very cold, which is nice[otherwise if prog is 2]Except for how cold and hard it is, [the noun] feels exactly like your own body[otherwise if prog is 3]It feels so hot. The gold has basically melted into your skin, at least in a psychospiritual sense[end if].";

otherwise:

say "[if prog is 0]It feels dry[otherwise if prog is 1]It feels extremely dry, even moreso than you expected[otherwise if prog is 2]It feels optimally dry, like the way a great idea feels dry[otherwise if prog is 3]The tips of your tiny fingers are acutely aware of how perfect this object is[end if]."