The Horrible Pyramid — 9 of 15

Ryan Veeder

Release 1

Section - Wheel Chamber

Wheelroom is a room. "[if prog is 0]This room is unremarkable but for the presence of a large wooden wheel mounted in one wall[otherwise if prog is 1]There is a big wooden wheel sticking out of the wall for some reason[otherwise if prog is 2]For reasons you can definitely guess and in fact have already guessed, a wooden wheel is stuck in the wall and in fact is definitely stuck in the wall[otherwise if prog is 3]Here in this room is where the wooden wheel that leads to adventure and death can be found, but it is of no importance to an immortal bride of Magic Incarnate such as yourself[end if].[paragraph break]Southeast: Canopic Chamber. Southwest: Shrine.". The printed name of Wheelroom is "Wheel Chamber". Wheelroom is northeast of Shrine.

The sliding slab stone door is a door. The sliding stone door is northeast of Wheelroom and southwest of Tunnel. The sliding stone door is closed. The printed name of the sliding stab stone door is "stone door". The initial appearance of the stone door is "[if the location is wheelroom and slider is 0]A stone slab blocks the way to the northeast[otherwise if the location is wheelroom]There's a space open beneath the stone slab to the northeast[otherwise if slider is 0]A stone slab blocks the way to the southwest[otherwise]There's a space open beneath the stone slab to the southwest[end if]."

The description of the stone door is "It is a massive slab."

Instead of opening the stone door: say "The block of stone is too heavy for you to move it on your own."

Instead of closing the stone door: say "[if Slider is 0]The door is already closed[otherwise]The door is already closing itself[end if]."

Instead of taking the stone door: say "Moving the slab of stone on your own would be impossible."

The big large wooden wheel is here. The printed name of the wheel is "wheel". The wheel is scenery.

Instead of taking the wheel, say "The wheel is built into the wall."

The description of the wheel is "[if prog is 0]Though obviously constructed millenia ago, this wheel apparently can still be turned and actuate the connected mechanisms[otherwise if prog is 1]This ancient grody wheel can still turn around, which is kind of amazing[otherwise if prog is 2]The wheel can turn, just like the sun turns in the sky, just like the earth turns below the sun, just like your body turns into a disgusting mummy and then you steadfastly refuse to rot in the incredible dryness of The Horrible Pyramid[otherwise if prog is 3]This is that wheel that has already been mentioned and has served its purpose. It might as well just dissolve into dust just like that skellington guy's skin and internal organs did[end if]."

The cavity is part of the sliding slab stone door. Understand "space" and "hole" and "door" and "doorway" as the cavity. The cavity is an open container.

Does the player mean inserting something into the cavity: it is very likely.

Instead of examining the cavity, try examining the stone door.

Check inserting something into the cavity:

if Slider is 0:

say "There's no space to put anything under the door." instead;

otherwise if the cavity contains something:

say "[The list of objects contained by the cavity] is already holding the door up." instead;

otherwise if the noun is the crook or the noun is the flail:

now Slider is 6;

now the stone door is open;

continue the action;

otherwise:

say "[The noun] wouldn't do a good job of holding the door up." instead.

After inserting something into the cavity:

say "You jam [the noun] underneath the stone slab."

[This puzzle was a huge pain to implement and is probably a huge pain to solve. I apologize.]

Slider is a number that varies. Slider is 0.

The sliding stone door can be stuck. The sliding stone door is not stuck.

Before turning the wheel:

if the stone door is stuck:

say "You spin the wheel, but nothing happens. The stone door is stuck up in the ceiling." instead.

Instead of turning the wheel:

increase Slider by 5;

if Slider is greater than 10:

say "You continue turning the wheel, and the stone door continues to rise, but then something cracks[unicode 8212]the wheel no longer gives any resistance, and the door stops moving.";

now the stone door is stuck;

otherwise if Slider is greater than 8:

now the sliding stone door is open;

say "As you continue turning the wheel, the stone door rises further, now high enough for you to walk comfortably underneath.";

otherwise if Slider is 4:

say "You turn the wheel, and the stone door to the northeast begins to rise from the floor.";

otherwise:

say "You turn the wheel, and the stone door continues to rise."

An every turn rule:

if the stone door is not stuck:

if the the cavity contains something:

if the location is Wheelroom or the location is Tunnel:

say "[The list of things contained by the cavity] is holding up the door, preventing it from sliding shut.";

otherwise if Slider is greater than 0:

decrement slider;

if Slider is 0:

if the stone door is visible:

say "The stone door falls to the ground with a thump.";

if the location is Tunnel:

say "[line break]You have trapped yourself inside of the Horrible Pyramid, and it is here, inside of the Horrible Pyramid, where you will definitely suffocate and die.";

otherwise if the location is Dead End:

say "You hear a thump at the other end of the tunnel, which means that the sliding stone door has slid back down to the floor and sealed you inside of this tunnel inside of the Horrible Pyramid, and it is here, inside of the Horrible Pyramid, where you will definitely suffocate and die.";

otherwise:

if the stone door is visible:

if the current action is turning the wheel:

say "When you stop turning the wheel, the door begins sliding back down.";

otherwise if Slider is less than 5:

if the stone door is open:

now the stone door is closed;

if the location is Wheelroom:

say "The space under the door is no longer high enough for you to walk underneath comfortably.";

otherwise:

say "The stone door continues to slide down toward the floor.";

Check going northeast in Wheelroom:

if Slider is 0:

say "The stone door is completely flush with the floor; you can't get underneath." instead;

otherwise if the stone door is closed:

say "There's not enough space underneath the door for you to get through and be sure you'll get out." instead;

otherwise:

continue the action.

Check going southwest in Tunnel:

if Slider is 0:

say "The stone door is completely flush with the floor; you can't get underneath." instead;

otherwise if the sliding door is closed:

say "You roll underneath the rapidly lowering stone door.";

now the stone door is open;

continue the action;

otherwise:

continue the action.