Robin & Orchid — 88 of 88

Volume - The World

Part - NPCs And How They Act

Section - Sharon

Sharon is a woman.

The description of Sharon is "Sharon is the student teacher assisting the staff advisor for the West High [italic type]Warbler[roman type]. In the past the staff has always managed quite well without a student teacher, but she does come in handy as a chaperone for situations like this[if Sharon is asleep].[paragraph break]Even in sleep, there's a certain sourness to her expression. She looks a bit like a dog dreaming about a rabbit it can't catch[end if]."

The note of Sharon is "'Why do people like Sharon want to become teachers? (By [apostrophe]people like Sharon[apostrophe] I mean [apostrophe]people who obviously hate everything about teaching, even and especially students[apostrophe].) If you're already completely jaded and cynical after your first semester of student teaching, isn't that a sign that you should give up on K-12 education and possibly on life in general?'"

Rule for printing the description of a photo (called pic) when the subject of the pic is Sharon:

if the action taken of the pic is pushing the cots:

say "The photo shows Sharon bent over the nursery cots, rearranging them into some kind of grown-up sized bed.";

otherwise if the action taken of the pic is examining:

say "Sharon is staring at something out of frame. She looks rattled, in spite of her claim not to believe in ghosts.";

otherwise if the action taken of the pic is sleeping:

say "Sharon is lying on the cots, sleeping, or trying to sleep. The photo was taken at such an angle that you can't see her face, but her hunched position suggests that her makeshift bed is less than comfortable.";

otherwise:

say "The photograph caught Sharon at a bad moment; she looks like she smelt something particularly nasty."

Instead of kissing sharon:

if sharon is awake:

say "Such a gesture could only serve to further sour her mood.";

otherwise:

say "There must be a better way to awaken her."

The initial appearance of Sharon is "[sharon-init-appear]."

To say sharon-init-appear:

if the cat is in the nursery window:

say "Sharon is staring at the face in the window, her eyes wider than usual";

otherwise if Sharon is awake and the last action of Sharon is pushing the cots:

say "Sharon is shuffling some tiny cots around, trying to to turn them into a grown-up-sized bed";

otherwise if Sharon is awake:

say "Sharon is keeping an eye on you";

otherwise:

say "Sharon's makeshift bed doesn't look comfortable, but apparently she's fast asleep anyway";

now the blankets are mentioned.

[For some reason, which I think is an I7 bug, Inform won't let me just say "the last action of Sharon is [whatever]".]

When play begins:

now the last action of Sharon is the action of pushing the cots.

The monologue table of Sharon is the Table of Sharon's Chatter.

Every turn when Blanket Quest is happening and Sharon is monologuing (this is the Sharon talks a lot rule):

if Sharon is not in the nursery:

move Sharon to the nursery;

now the current interlocutor is Sharon;

have Sharon monologue.

Instead of going west in the Nursery when Blanket Quest is happening and the time since Blanket Quest began is 0 minutes:

say "You almost collide with Sharon in the doorway and stop short."

Table of Sharon's Chatter

To say end of Sharon's monologue:

now the last action of Sharon is the action of waiting;

if Sharon has the blankets:

say "Sharon looks at the makeshift cot bed and purses her lips. 'I guess that'll do,' she says.[run paragraph on]";

otherwise if the blankets are not in the nursery cupboards:

say "Sharon [if Robin has the blankets]takes the blankets from you[otherwise]picks up the blankets[end if]. 'Thanks, Robin,' she says. She looks at the makeshift cot bed and purses her lips. 'I guess that'll do.'[run paragraph on]";

now Sharon carries the blankets;

otherwise:

say "'Have you found the blankets yet?' [if the noun is Sharon]she[otherwise]Sharon[end if] asks.[paragraph break]";

if the blankets are discovered or the blankets are seen:

if the player is on the recliner and the posture of the player is standing:

say "'I'm just getting them now,' you say.[paragraph break]Sharon humphs impatiently.[run paragraph on]";

otherwise:

say "'Yes, but I can't reach them.' You point out the location of the blankets.[paragraph break]Sharon tries to pull them down from the cupboard and fails. She's barely taller than you are. 'This room was designed for giantesses,' she grumbles.[run paragraph on]";

otherwise:

say "You shake your head.[paragraph break]'They must be in one of these cupboards. Somewhere.' She looks up at them and sighs. Sharon is barely taller than you, and she obviously doesn't want to try to search the cupboards herself. 'Someone from the church would know.'[paragraph break]'Don't look at me,' Orchid says.[run paragraph on]".

Instead of giving the blankets to Sharon (this is the give Sharon the blankets rule):

say "Sharon takes the pile of blankets from you. 'Thanks, Robin,' she says.";

now Sharon carries the blankets;

rule succeeds.

Instead of showing the blankets to Sharon:

try giving the blankets to Sharon.

Instead of informing Sharon about the blankets when Robin carries the blankets:

try giving the blankets to Sharon.

Instead of talking to Sharon when Robin carries the blankets:

try giving the blankets to Sharon.

[The "greeting type is implicit" bit is necessary to make the give Sharon the blankets rule work, because:

- with Conversation Framework included, giving something to Sharon sometimes triggers an implicit saying hello action

- which in turn triggers this rule

- which would stop the action before actually getting to the giving bit, if this rule didn't specifically ignore implicit greetings.]

Instead of chatty behavior when the actual interlocutor is Sharon and Sharon is monologuing (this is the can't get a word in edgewise with Sharon rule):

if the current action is saying hello to Sharon and the greeting type is implicit:

continue the action;

say "Sharon ignores you and keeps talking."

Instead of talking to Sharon when Sharon does not carry the blankets and Robin does not carry the blankets: [this should only be possible after Sharon finishes her monologue but before she goes to sleep]

try quizzing Sharon about the blankets.

Instead of chatty behavior when the actual interlocutor is Sharon and Ghost Photography 101 is happening:

say "Sharon isn't paying attention to you. She's focused on the spectral face in the window."

After quizzing Sharon about the blankets:

say "'What was that about the blankets again?'[paragraph break]'Can you find them for me,' Sharon says question-marklessly. 'They're supposed to be in the nursery somewhere[em dash]that's what I was told, anyway.'"

After quizzing Sharon about Robin:

say "'What am I supposed to be doing again?'[paragraph break]";

if Sharon carries the blankets:

say "'You're the official photographer for the story, so try to get photos of anything spooky-looking that you manage to find.' Sharon's voice expresses strong skepticism about this possibility. 'You and Orchid will be writing the story together[em dash]but for tonight you're just doing research.'";

otherwise:

say "'Can you find me the blankets?' Sharon says. 'I was told they're in here somewhere.'".

After quizzing Sharon about Orchid:

say "Sharon says, 'You're the official photographer for the story, but you and Orchid will both write it and share the credit. Do try to work together.'"

The West High Warbler is a thing.

The printed name of the Warbler is "West High [italic type]Warbler[roman type]".

Understand "paper" and "newspaper" and "story" as the Warbler.

The Warbler is familiar.

Instead of quizzing Sharon about when the second noun is the Polaroid or the second noun is the Warbler:

try quizzing Sharon about Orchid.

After quizzing Sharon about Casey:

say "'Thank goodness for the school doesn't allowed boy-girl sleepovers,' Sharon says. 'Two girls is quite enough bother for me.'"

After quizzing Sharon about Jennie:

say "'I don't believe in ghosts, but I'm sure you and Orchid can find something spooky to write about. Goodness knows I wouldn't be spending a night in this church if I had a say in the matter.'"

After quizzing Sharon about Sharon:

say "'I suppose you girls will be running around half the night,' Sharon says, 'but I plan to get some sleep. Don't wake me up unless it's really serious.'"

Last after quizzing Sharon about something:

say "Apparently Sharon can't be bothered answering your question."

Last after asking Sharon about:

say "Apparently Sharon can't be bothered answering your question."

Last after informing Sharon about something:

say "Sharon listens to you with her eyebrows raised."

Last after telling Sharon about:

say "Sharon listens to you with her eyebrows raised."

Last after requesting Sharon for something:

say "Sharon quirks an eyebrow. 'What makes you think I'd be able to help you with that?'"

Instead of chatty behavior when the actual interlocutor is Sharon and Tutorial is happening and Ghost Photography 101 has ended:

say "Sharon completely ignores you."

Does the player mean quizzing Sharon about the ghostly figure:

it is very likely.

Does the player mean informing Sharon about the ghostly figure:

it is very likely.

Does the player mean requesting Sharon for the ghostly figure:

it is very likely.

Persuasion rule when asking Sharon to try doing something:

say "Historically it has been [italic type]Sharon[roman type] who bosses [italic type]you[roman type] around.";

persuasion fails.

Instead of chatty behavior when the actual interlocutor is Sharon and Sharon is asleep:

if the current action is saying hello to Sharon and the greeting type is implicit:

continue the action;

try waking Sharon.

After listening when Sharon is monologuing:

say "Sharon is still talking."

[TODO: Why doesn't Sharon just ask Orchid to look for the blankets, if Robin and Sharon are both too short? Maybe we need an excuse to get Orchid out of the room temporarily. Or, better, give her something to do that stops her from helping with the blankets.]

At the time when Sharon goes to bed:

say "Sharon yawns. 'Right, I'm going to bed now. Keep out of trouble, don't break anything, and don't wake me up unless it's [italic type]really, really[roman type] serious, got it?' Without waiting for an answer, she lies down on the row of cots, facing away from you, and pulls the blankets over herself.";

now Sharon is on the cots;

now the blankets are on the cots;

now the last action of Sharon is the action of sleeping.

Instead of shaking Sharon when Sharon is asleep:

try waking Sharon instead.

[Waking Sharon ends the game]

Instead of waking Sharon when Sharon is asleep:

if Aiden is in the Nursery:

say "Sharon stirs, rubs her eyes, and looks at you, then Orchid, then Aiden. She says something that one does not typically say in a church.[paragraph break]***";

wait for any key;

say paragraph break;

say “‘What did she say?’[paragraph break]’I won’t repeat it.'[paragraph break]Casey slumps back in his chair. ‘You would make a great Christian,’ he mutters.[paragraph break]’I’m sure I would.’ You try not to smile.[paragraph break][if the player does not have evidence of the black sphere]’So, how did they manage the spooky lights in the hallway?’[paragraph break]’I think they just used a cheap party ball from the mall. The atmosphere, more than anything, is what made it seem at all spooky.’[paragraph break][end if][if the player does not have evidence of the can of goo]’What about the ectoplasm?’[paragraph break]’That could have been any kind of non-paranormal gunk. Maybe it was car wax.’[paragraph break][end if][if the Engelgurt is not comprehended]’Well, how did Aiden fly around in the sanctuary?’[paragraph break]’I’m entertaining a hypothesis. I noticed components from an unusual mechanism lying around in the balcony.’[paragraph break]’The Engelgurt?’[paragraph break]’If you like. I assume that, while I was chasing after Aiden, Orchid was up in the balcony disassembling the rig so it would look ever so slightly less suspicious.’[paragraph break][end if]'Hey, did you hear what happened to Orchid?’[paragraph break]’I heard that she’s suspended from the next two issues of the paper.’[paragraph break]Casey pouts. ‘I wanted to be the one to tell you.’[paragraph break]’Sorry. Why don’t you tell me what happened to Aiden?’[paragraph break]’I’d love to! Except, I didn’t know anything happened to Aiden. I didn’t think they could do anything, since he’s not on the newspaper?’[paragraph break]’Unfortunately for Aiden, in this case the left and right hands are in close communication. The drama department is putting him on probation for an as-yet undetermined period.’[paragraph break]Casey perks right back up. ‘Robin! That is the best thing I’ve ever heard! Although the thing about Orchid is pretty great too.’[paragraph break]’Well, Orchid is getting what she wanted anyway, I think. The [italic type]Warbler[roman type] is going to run a story that people will actually read, for once[unicode 8212]except this one is true.’";

end the story finally;

otherwise:

say "On second thoughts, maybe what you wanted to say isn't urgent enough to brave Sharon's wrath at being woken."

Section - Orchid

Orchid is a woman.

The description of Orchid is "Orchid, like most girls your age, is taller than you. Her cheeks are covered in freckles that you had never seen before tonight; she must put makeup on over them for school. You have the uneasy feeling that there are more freckles on her left cheek than her right.[paragraph break][if the cat is in the nursery window]She's staring at the face in the window and[em dash]has she turned pale? Her freckles look even more prominent[otherwise if Ghostly Apparition is happening]She catches your eye, scowls, and nods fiercely in the direction of the ghostly figure[otherwise]She notices you examining her, and you look away[end if]."

Understand "freckle" and "freckles" as Orchid.

The note of Orchid is "'Here's an anecdote about Orchid. This happened just recently. I didn't tell you, because I wanted to save it for here. Okay:[paragraph break]'I'm at school after hours because of rehearsals. But we're still in the fairly lazy stage of the production, so there's lots of time to just goof off around the school. So while the underclassmen are sitting around in the hall running lines, I head up to the drama office, because there are donuts there.[paragraph break]'But Orchid and Aiden Kingsley are already up in the office, and as soon as I poke my head in Orchid looks up and says [']Actors only, please!['] and I'm like [']Actually, I am an actor,['] and she says, [']Well, you know what I mean.['][paragraph break]'No, Orchid! I do not have the slightest idea what you mean. I would have just grabbed a donut and left, but you're not allowed to take the donuts out of the drama office, so I just left.[paragraph break]'I wouldn't say I hate Orchid. Hate is a very strong word. I completely hate Aiden, though.'"

Instead of showing something to Orchid:

if Orchid is waiting for an answer:

continue the action;

say "Orchid apparently doesn't have time for that right now."

Instead of showing Casey's notes to Orchid, say "Casey said not to show them to Orchid[unicode 8212]and if Orchid saw anything in there to make her mad at Casey, she'd probably get really mad at you, too."

Instead of informing Orchid about Casey's notes:

try showing Casey's notes to Orchid.

Rule for writing a paragraph about Orchid:

if the location is Sanctuary and Sanctuary was not visited:

now Orchid is mentioned;

otherwise if Ghost Photography 101 is happening:

say "Orchid is clutching your arm.";

otherwise if the location is the Nursery:

say "Orchid is lounging around, [if Orchid is monologuing]lecturing you[otherwise]yawning[end if].";

otherwise if Ghostly Apparition is happening and the ghostly figure is visible:

say "Orchid is watching the ghostly figure closely.";

otherwise if Aiden is in the location:

say "Orchid stands near Aiden, her arms crossed.";

otherwise:

say "Orchid is hanging around."

Rule for printing the description of a photo (called pic) when the subject of the pic is Orchid:

if the action taken of the pic is examining:

say "The photo shows Orchid staring intently at something.";

otherwise if the action taken of the pic is talking vaguely:

say "Orchid appears to be staring directly at the camera. Her mouth is open in a silent lecture.";

otherwise if the action taken of the pic is freaking out:

say "The photo is slightly out of focus[em dash]well, it's hard to take a good photo of someone when she's clinging to your arm. But the image is clear enough for you to see that Orchid's eyes are wide and her mouth is hanging open slightly.";

otherwise if the action taken of the pic is screaming:

say "Orchid's face is scrunched up and her mouth is wide open. Even her freckles look angry.";

otherwise if the action taken of the pic is scowling:

say "Orchid scowls out of the photo at you, her eyebrows scrunched and her mouth turned down at the corners.";

otherwise: [waiting]

say "The photo shows Orchid standing around aimlessly, a slight frown on her face."

The monologue table of Orchid is the Table of Orchid's Bossiness.

Table of Orchid's Bossiness

remark

"'You'd better hold onto this,' she says, handing you the camera, 'you're the official photographer. Just don't forget, if you see something that might be evidence of a ghost, make sure you take a photo of it.'[paragraph break]You slip the camera strap around your neck."

"[if the current action involves Orchid]She[otherwise]Orchid[end if] notices your notebook. 'What's all that?' she asks.[paragraph break]'Oh, Casey gave it to me. It's just some notes about things in the church.'[paragraph break]'Is there anything about me in there?'[paragraph break]'I don't think so,' you lie, and Orchid loses interest."

"'Oh, and,' Orchid adds, 'don't turn the lights on while you're looking around unless you have to. Some ghosts won't appear unless it's dark, and we've only got tonight to gather all our evidence.'"

After looking for the first time [when the first room description is printed, in the nursery]:

now the last action of Orchid is the action of talking vaguely;

now the current interlocutor is Orchid;

have Orchid monologue.

Every turn while Orchid is monologuing:

have Orchid monologue.

Instead of chatty behavior when Orchid is monologuing:

say "Orchid says, 'Hang on,' and keeps talking."

Instead of chatty behavior when Orchid is not monologuing and Sharon is off-stage: [the SINGLE TURN between Orchid shutting up and Sharon arriving]

say "Orchid yawns and misses whatever you were trying to say."

Instead of chatty behavior when the actual interlocutor is Orchid and Sharon is in Nursery and Sharon is monologuing:

say "Sharon talks over you, drowning you out."

Instead of chatty behavior when the actual interlocutor is Orchid and Tutorial is happening and Ghost Photography 101 is not happening and Ghost Photography 101 has happened:

say "Orchid brushes you off."

Instead of going somewhere when Orchid's Instructions is happening:

say "Orchid catches your arm before you can leave. 'Hang on,' she says, 'we should finish figuring out our plans first.'"

When Orchid's Instructions ends:

now the last action of Orchid is the action of waiting.

After quizzing Orchid about the Warbler for the first time:

say "'Book reviews and stories about school sports!' Orchid says. 'That's not what people want to read. They want something [italic type]exciting[roman type], something they can talk about. And that's what this story is going to be, for once. If I get to be editor-in-chief...' She drones on for several more minutes about her plans for the [italic type]Warbler[roman type], but you've tuned out.";

After quizzing Orchid about the Warbler:

say "You really don't need to hear Orchid's spiel about How To Run A School Newspaper again."

After quizzing Orchid about Orchid:

say "Don't get her started."

After quizzing Orchid about Sharon:

say "Orchid pulls a face[if Sharon is in the location], but is too circumspect to say anything in Sharon's presence[end if]."

After quizzing Orchid about Casey:

say "'Yeah, it's too bad he couldn't come tonight,' Orchid says with perfect insincerity."

After quizzing Orchid about Aiden:

say "'Aiden Kingsley? I didn't think you knew him. He's just a guy from drama.'"

After quizzing Orchid about Heather:

say "Orchid just laughs at your mention of Heather."

After quizzing Orchid about Jennie:

say "'Don't forget to take a photo of any ghost evidence you come across!' Orchid says and glares at you as if she already suspects you of having overlooked a vital clue."

Instead of quizzing Orchid about when the second noun is Robin or the second noun is the Polaroid:

try quizzing Orchid about Jennie.

Last after quizzing Orchid about something when the location is the Nursery:

say "Orchid shrugs."

Last after asking Orchid about when the location is the Nursery:

say "Orchid shrugs."

Last after informing Orchid about something when the location is the Nursery:

say "Orchid says, 'Really?' with a glazed expression in her eyes."

Last after telling Orchid about when the location is the Nursery:

say "Orchid says, 'Really?' with a glazed expression in her eyes."

Last after answering Orchid that when the location is the Nursery:

say "Orchid smiles wearily at you and doesn't answer."

Persuasion rule for asking Orchid to try doing something:

say "Before you can finish asking, Orchid squints at you, and you shut up.";

persuasion fails.

At the time when Orchid critiques your photography:

now the last action of Orchid is the action of talking vaguely;

now the current interlocutor is Orchid;

if a photo shows the cat:

say "[if the current action is chatty behavior and the actual interlocutor is Orchid]She[otherwise]Orchid[end if] peeks over your shoulder at the photo you took. 'Hey, that's good!' she says. 'I guess you can see how it's a cat now, but it looked really spooky, didn't it?'";

otherwise if a photo shows Orchid freaking out:

say "[if the current action is chatty behavior and the actual interlocutor is Orchid]She[otherwise]Orchid[end if] peeks over your shoulder at the photo of her and turns pink. 'What did you do that for? Why didn't you take a photo of that face? I mean, I know it wasn't actually a ghost, but it could've been! We have to make sure we've got photos of all the ghost evidence we find, if we're going to do this investigation properly.'";

otherwise:

say "'Why didn't you take a photo of the face?' Orchid asks. 'I mean, I know it wasn't actually a ghost, but it could've been! We have to make sure we've got photos of all the ghost evidence we find, if we're going to do this investigation properly.'"

To decide if a photo shows Orchid freaking out:

repeat with pic running through photos that show Orchid:

if the action taken of the pic is freaking out:

decide yes;

decide no.

Instead of saying yes when Ghost Photography 101 has ended and the time since Ghost Photography 101 ended is 2 minutes and a photo shows the cat:

say "'Yeah, I almost thought we'd found our ghost already!'[paragraph break]Orchid laughs and says, 'We'll have to keep looking.'".

Instead of saying no when Ghost Photography 101 has ended and the time since Ghost Photography 101 ended is 2 minutes and a photo shows the cat:

say "'I don't think so,' you say, 'it was just hard to tell what it was in the dark.'[paragraph break]'Oh,' says Orchid. 'I see. Well, I hope we can find a ghost that [italic type]will[roman type] meet your high standards.'".

When Ghost Hunt begins:

move Orchid tidily to the Sanctuary;

now the current interlocutor is nothing;

say "Orchid says, 'We'd better get started. How about this: you check out the basement, and I'll go upstairs and look around there, and then we'll meet up and compare notes. Don't forget to take a photo if you find any evidence of a ghost!' She slips out of the room. A moment later, you hear her footsteps echoing in the stairwell as she heads back up to the main floor."

After quizzing Orchid about the blankets when the blankets are not seen:

say "[one of]'Hey, Orchid? Do you know where the blankets are? You go to this church, right?'[paragraph break]Orchid shrugs. 'Yeah, but as a rule I don't hang around the nursery. I guess they're probably somewhere in[em dash]' She waves her hand vaguely at the cupboards on the wall[or]Orchid said she didn't know where the blankets are kept[stopping]."

Instead of requesting Orchid for the blankets:

if the blankets are discovered:

try asking Orchid to try taking the blankets;

otherwise:

try quizzing Orchid about the blankets.

Instead of talking to Orchid when the blankets are undiscovered:

try quizzing Orchid about the blankets.

Instead of kissing Orchid, say "The reason your overnight investigatory team had to consist of two girls was to minimize the chances of any funny business."

[imagining an alternative universe game where we decided to rip off Gone Home and there is a whole other plotline where Robin and Orchid totally hook up]

Instead of chatty behavior when Ghost Photography 101 is happening and the actual interlocutor is Orchid:

say "Orchid doesn't seem to hear you. She's just staring open-mouthed at the face in the window."

Instead of chatty behavior when Ghostly Apparition is happening and Ghostly Apparition has been happening for at least two turns and Orchid is visible:

if the current action is saying hello to Orchid and the greeting type is implicit:

continue the action;

if Orchid is in the location:

if the ghostly figure is visible:

say "Orchid shushes you and gestures urgently at the camera.";

otherwise:

say "Orchid gives you a push and mutters, 'Never mind that now, follow the ghost!'";

otherwise:

say "You can't bring yourself to shout across the big empty church at Orchid."

Section - Aiden

Aiden is a man. [GROSS]

Aiden can be transparent.

Aiden is transparent.

When play begins:

now the last action of Aiden is the action of waiting.

The photo description of Aiden is "Aiden smirks at the camera, apparently unconcerned at having been caught."

Does the player mean quizzing Aiden about the ghostly figure:

it is very likely.

Does the player mean informing Aiden about the ghostly figure:

it is very likely.

Does the player mean requesting Aiden for the ghostly figure:

it is very likely.

The ghostly figure is a woman. [It's actually Aiden, but I think it's gonna be easier to treat the fake ghost as a separate NPC.]

The ghostly figure is neuter. [as well as female, thanks to Felix Larsson's Second Gender extension]

The ghostly figure is evidential.

The ghostly figure is not familiar.

Understand "pale" and "movement" as the ghostly figure.

Understand "ghost" and "jennie" and "jenny" and "bancroft" as the ghostly figure [when the ghostly figure is on-stage]. [Removed to improve performance.]

When play begins:

now the last action of the ghostly figure is the action of floating.

Rule for writing a paragraph about the ghostly figure:

if the ghostly figure is in the Sanctuary:

say "A ghostly figure floats near the ceiling.";

otherwise:

now the ghostly figure is mentioned. [instead there'll be a paragraph about the figure leaving]

The description of the ghostly figure is "The glowing figure is wearing a pale dress and her hair is in pigtails[if Jennie is noted], just like Casey said[end if]. You can't make out the expression on her face, but she's holding her hands out as if she's reaching for something or asking for something."

Rule for printing the description of a photo (called pic) when the subject of the pic is the ghostly figure:

if Aiden is seen:

say "Now you know the ghostly figure was Aiden in glow-in-the-dark makeup and a pigtailed wig, it looks a lot less ghostly. You can almost make out a shadowy mustache under his makeup.";

otherwise:

say "In the photo, the ghostly figure stands out starkly against the darkness of the church. The glow emanating from her obscures her features, but you can just make out her pigtails and the shape of her dress."

Before photographing something enclosed by the ghostly figure with the Polaroid:

try photographing the ghostly figure with the Polaroid instead.

[Rule for printing the name of the ghostly figure when Aiden is seen:

say "fake ghost".

Understand "fake" as the ghostly figure when Aiden is seen.] [Removed to improve performance.]

The ghostly figure can be transparent.

The ghostly figure is transparent.

Does the player mean querying about the ghostly figure:

if the ghostly figure is on-stage:

it is very likely;

otherwise:

it is very unlikely.

Does the player mean querying vaguely about the ghostly figure:

if the ghostly figure is on-stage:

it is very likely;

otherwise:

it is very unlikely.

The ghostly figure's pigtails are part of the ghostly figure.

The ghostly figure's pigtails are plural-named and privately-named.

The printed name of the ghostly figure's pigtails is "pigtails".

Understand "pigtail" and "pigtails" as the ghostly figure's pigtails.

The description of the pigtails is "You can barely make out her pigtails in the darkness."

Does the player mean querying about the ghostly figure's pigtails:

if Hazy Place is visited:

it is very unlikely;

otherwise:

it is likely.

Does the player mean querying vaguely about the ghostly figure's pigtails:

if Hazy Place is visited:

it is very unlikely;

otherwise:

it is likely.

Rule for clarifying the parser's choice of the ghostly figure's pigtails:

do nothing.

The ghostly figure wears a pale dress.

Understand "old-fashioned" and "clothes" and "wispy" as the pale dress.

The description of the pale dress is "Her dress is old-fashioned, and it glows eerily."

Rule for clarifying the parser's choice of the pale dress:

do nothing.

Does the player mean querying about the pale dress:

if the glowing dress is not seen:

it is likely;

otherwise if the player is in Hazy Place:

it is very unlikely;

otherwise:

it is possible.

Does the player mean querying vaguely about the pale dress:

if the glowing dress is not seen:

it is likely;

otherwise if the player is in Hazy Place:

it is very unlikely;

otherwise:

it is possible.

Instead of querying Casey's notes about when the second noun is the ghostly figure's pigtails or the second noun is the pale dress:

try querying Casey's notes about Jennie Bancroft.

Instead of doing something when the current action implies touching the ghostly figure or the current action implies touching the ghostly figure's pigtails or the current action implies touching the pale dress:

say "The ghostly figure is too [if the ghostly figure is in the sanctuary]high up and too [end if]far away."

Does the player mean querying about the ghostly figure:

it is very unlikely. [instead we want the player to find the Jennie Bancroft note]

Does the player mean querying vaguely about the ghostly figure:

it is very unlikely.

Instead of querying Casey's notes about the ghostly figure:

try querying the notes about Jennie Bancroft.

Does the player mean following the ghostly figure:

it is very likely.

Does the player mean quizzing Orchid about the ghostly figure:

it is very likely.

Does the player mean informing Orchid about the ghostly figure:

it is very likely.

Does the player mean requesting Orchid for the ghostly figure:

it is very likely.

Does the player mean implicit-quizzing the ghostly figure:

it is very likely.

Does the player mean implicit-informing the ghostly figure:

it is very likely.

Does the player mean implicit-requesting the ghostly figure:

it is very likely.

Rule for clarifying the parser's choice of the ghostly figure:

do nothing.

Persuasion rule for asking Aiden to try doing something:

let aido be indexed text;

now aido is "[the current action]";

replace the text "asking Aiden to t" in aido with "T";

say "'[aido] yourself,' Aiden grumbles.";

persuasion fails.

Section - The Cat

The cat is a neuter animal.

The cat is not familiar.

Understand "face" and "pale" and "in window" and "in the window" as the cat.

Understand "gideon" as the cat when Hazy Place is visited and the location is not Hazy Place.

Rule for printing the name of the cat when the cat is in the nursery window:

say "face in the window".

The description of the cat is "[if the cat is in the nursery window]The face almost seems to be floating in midair. You can't make out any details in the dim light[otherwise]The cat is almost completely white, except for a small black spot on the end of its tail. When it sees you looking at it, it narrows its pale blue eyes at you[end if]."

The initial appearance of the cat is "[if the location is Hazy Place]The cat is cradled in her arms[otherwise]The cat is sitting in the middle of the room, staring at you[end if]."

Rule for printing the description of a photo (called pic) that shows the cat:

if the action taken of the pic is searching the window:

say "It's the photo you took of the cat looking in through the window. How did you ever think it was a person? It's much too small and pale to be anything human. Although outside the window, obscured by the glass, it did look pretty ghostly.";

otherwise:

say "The cat was facing away from you but it must have noticed you taking a photo, because its head is turned back towards the camera. Its big blue eyes stare out of the photo at you."

Instead of chatty behavior when the actual interlocutor is the cat and the cat is in the nursery window:

say "Your throat constricts and you can't get the words out."

Persuasion rule for asking the cat to try doing something:

say "The cat listens thoughtfully to your instructions and does nothing of the sort.";

[TODO: this response is probably a bad idea, because what if the player tries "CAT, GO [direction the cat was already headed]"?]

persuasion fails.

First instead of showing something to the cat:

say "The cat stares up into your face, apparently unaware of [the noun]."

[this is what our cat does. every time. "kitty, look at this nice toy/yummy food/reflection of you/lolcat/box you can sit in!" kitty: ........]

Instead of chatty behavior when the noun is the cat:

if the current action is saying hello to and the greeting type is implicit:

continue the action;

say "The cat waits patiently for you to finish your speech."

[The cat is going to rush off as soon as the player enters the room, so there isn't much point in including a paragraph about it being in the room as well as the one about it leaving.]

Rule for writing a paragraph about the cat when the cat is leading the player and the cat is not waiting for the player and the cat is not in Hazy Place:

now the cat is mentioned.

The cat can be leading the player. The cat is not leading the player.

The cat can be waiting for the player. The cat is not waiting for the player.

The cat has a room called the destination.

The cat has a direction called the next move.

When Distracted by a Cat begins:

now the cat is in Hall1;

now the destination of the cat is Boiler.

Printing cat stuff is a truth state that varies.

Printing cat stuff is false.

Before reading a command:

now printing cat stuff is false.

When the Cat Hints begins:

let way be the best route from the location to Boiler through lit rooms, using even locked doors;

if the way is nothing:

now the time since progress counter is the time to hints - 1;

[we can try to start the scene next turn]

rule fails;

let entry be the door way from the location;

if the entry is a door and the entry is closed:

now the time since progress counter is the time to hints - 1;

[we can try to start the scene next turn, when maybe the door is open]

rule fails;

now the puzzle being hinted is a random available puzzle;

now the destination of the cat is the home of the puzzle being hinted;

now the cat is leading the player;

[say "DEBUG: The puzzle being hinted is [the puzzle being hinted]. The cat is aiming for [the destination of the cat].";]

move the cat to the location;

now printing cat stuff is true;

if the way is up or the way is down:

say "The cat trots [if the way is up]down[otherwise]up[end if] the stairs and [one of]purrs[or]mews[at random] at you.";

otherwise:

say "The cat strolls in from [the way] and [one of]purrs[or]mews[at random] at you."

Every turn when a cat-following scene is happening and the cat is not in the destination of the cat and the cat is in the location:

now printing cat stuff is true;

if the cat is not leading the player:

now the cat is leading the player;

if the cat is waiting for the player and the cat is in Sunday and the player is in the location of the cat for the first turn:

[have the cat wait around for the player for one turn]

make no decision; [skip the rest of this rule, but keep going through any other every turn rules]

otherwise if the cat is waiting for the player for the second turn:

[the cat must be waiting for the player to open a door, UNLESS THERE'S A BUG OF COURSE]

let way be the next move of the cat;

let barrier be the door way from the location;

if the barrier is a door and the barrier is closed:

[The player didn't open the door for the cat. Naughty player! Cat gives up and goes home.]

now the destination of the cat is Boiler;

have the cat move on, silently;

if the cat is not in the location:

say "The cat whisks its tail at you, then turns and runs off [if the next move of the cat is down]down the stairs[otherwise if the next move of the cat is up]up the stairs[otherwise]to [the next move of the cat][end if].";

otherwise:

have the cat move on, silently;

say "As soon as there's a cat-width between the door and the doorframe, the cat slips through it.";

make no decision; [we're done with this rule]

[say "DEBUG: the puzzle being hinted is [the puzzle being hinted]. The destination of the cat is [the destination of the cat].";]

have the cat move on;

if the cat is in the location:

[the cat couldn't go any further because something (i.e. a door) blocked its path]

let way be the next move of the cat;

let barrier be the door way from the location;

if the barrier is a door and the barrier is closed:

say "[one of]The cat mews at you, then turns away and scratches at [the barrier][or]The cat rubs up against [the barrier] and mews[at random].";

now the cat is waiting for the player;

otherwise:

say "The cat pauses in the middle of the room, looking confused."; [This should never happen, BUT.]

[the cat gives up and goes home]

now the destination of the cat is Boiler.

[A standard phrase to move the cat to its next location. Normally it uses "try the cat going..." to move the cat, but if we use the "silently" option it uses "silently try the cat going" instead.]

To have the cat move on, silently:

if the destination of the cat is an obvious room and the location of the cat is an obvious room:

now the next move of the cat is the best route from the location of the cat to the destination of the cat through lit obvious rooms, using even locked doors;

otherwise:

now the next move of the cat is the best route from the location of the cat to the destination of the cat through lit rooms, using even locked doors;

if silently:

silently try the cat going the next move of the cat;

otherwise:

try the cat going the next move of the cat.

[CATS CAN'T OPEN DOORS

or anything else for that matter]

Check the cat opening something:

stop the action.

[The first time the cat appears, it waits in the Basement Stairway for a turn to let the player get a look at it.]

Last carry out the cat going:

if Distracted by a Cat is happening and the cat is in Sunday:

now the cat is waiting for the player;

otherwise:

now the cat is not waiting for the player.

[Report which way the cat went when it left the player's location.]

Report the cat going when the room gone from is the location:

if the cat is not leading the player:

say "The cat looks up at you for a moment and mews. Then it spins around and dashes off to [the next move of the cat].";

otherwise:

if the next move of the cat is up:

say "The cat scampers up the stairs.";

else if the next move of the cat is down:

say "The cat bounds downstairs.";

else:

say "[one of]You're still on the other side of the room when the cat scampers off to [the next move of the cat][or]The cat wanders off to [the next move of the cat], glancing back at you as if to check whether you're following[or]The cat watches you for a moment, but runs off to [the next move of the cat] before you can get near it[at random].";

rule succeeds.

Every turn when a cat-following scene is happening and the cat is in Boiler and the player is in Boiler:

remove the cat from play;

now the time since progress counter is 0;

now the cat is not leading the player;

say "[one of]The cat mews at you, slinks behind one of the room's many pipes and fixtures, and is gone[or]As you enter, the cat ducks behind one of the pipes[stopping]."

Every turn when the Cat Hints is happening and the cat is in the destination of the cat and the cat is in the location and the cat is not in Boiler:

now the destination of the cat is Boiler;

let the hintable be the linked evidence of the puzzle being hinted;

say the cat hint of the hintable;

say line break.

The time since cat visibility is a number that varies.

The time since cat visibility is 0.

To possibly end the cat chase:

if Distracted by a Cat is happening and the cat is in Hall1:

continue the action;

if the cat is not in the location:

now the cat is not leading the player;

remove the cat from play;

now the time since progress counter is 0.

[If the player goes in the wrong direction instead of following the cat, the cat just gives up and the cat-following scene ends.]

Last carry out going when a cat-following scene is happening:

if the cat is not in the location:

[check if the player went where the cat was going to go BEFORE the cat]

let the provisional destination be nothing;

if the destination of the cat is an obvious room and the location of the cat is an obvious room:

now the provisional destination is the best route from the location of the cat to the destination of the cat through lit obvious rooms, using even locked doors;

otherwise:

now the provisional destination is the best route from the location of the cat to the destination of the cat through lit rooms, using even locked doors;

[say "DEBUG: the provisional destination is [the provisional destination]. The noun is [the noun]. The cat is in [the location of the cat]. The cat is heading for [the destination of the cat].";]

if the provisional destination is a direction:

now the provisional destination is the room provisional destination from the location of the cat;

if the provisional destination is a room and the provisional destination is the location:

have the cat move on, silently;

if the cat is in the provisional destination:

say "The cat bounds [if the location is a hallway and the location of the cat is a hallway]down the hall[otherwise]into the [lower case name of the location][end if] ahead of you.";

if the cat is in the location:

now the time since cat visibility is 0;

otherwise:

possibly end the cat chase;

continue the action.

First after doing something other than going when a cat-following scene is happening:

if the cat is in the location:

now the time since cat visibility is 0;

otherwise:

if Cat Hints is happening and the destination of the cat is Boiler:

possibly end the cat chase;

otherwise:

increment the time since cat visibility;

if the time since cat visibility >= 10:

possibly end the cat chase;

continue the action.

[the player isn't allowed to touch the cat]

Instead of doing something when the current action implies touching the cat and a cat-following scene is happening:

if the cat is in the destination of the cat:

say "The cat scampers away from you before you can touch it.";

otherwise:

[say "DEBUG: the puzzle being hinted is [the puzzle being hinted]. The destination of the cat is [the destination of the cat].";]

have the cat move on, silently;

say "The cat dodges your hand and bounds off [if the next move of the cat is up]upstairs[otherwise if the next move of the cat is down]downstairs[otherwise]to [the next move of the cat][end if]."

The time since progress counter is a number that varies.

The time since progress counter is 0.

The time to hints is a number that varies.

The time to hints is 50.

Every turn during Uncovering a Hoax:

increment the time since progress counter.

First carry out photographing an evidential thing with (this is the photographic reset the time since progress counter rule):

if the player does not have evidence of the noun:

now the time since progress counter is 0.

First carry out taking an evidential thing (this is the grabby hands reset the time since progress counter rule):

if the player does not have evidence of the noun:

now the time since progress counter is 0.

A puzzle is a kind of object.

A puzzle has a thing called the linked evidence.

A puzzle has some text called the non-spoilery name.

A puzzle can be walkthroughable or non-walkthroughable. A puzzle is usually walkthroughable.

To decide what room is the home of (teaser - a puzzle):

decide on the location of the linked evidence of the teaser.

Definition: a puzzle is available if it is not complete.

Definition: a puzzle is complete if the player has evidence of the linked evidence of it.

The puzzle being hinted is a puzzle that varies.

A thing has some text called the cat hint.

The cat hint of a thing is usually "[if the item described is evidential]Whoops, Emily and Ryan forgot to put in a hint for this thing. Silly them![otherwise]BUG: [the item described] isn't evidence, why is the cat hinting it???"

Towers of OCD is a puzzle.

The non-spoilery name of the Towers of OCD is "the glistening container".

Definition: Towers of OCD is available if it is not complete and the Dark Basement is complete.

The can of goo is a thing. [necessary for silly old Inform to not get confused]

The linked evidence of Towers of OCD is the can of goo.

Definition: Towers of OCD is complete if the player has evidence of the can of goo.

The cat hint of the can of goo is "The cat leaps up onto the amplifier, looks up at the highest shelf and mews."

The Secret Passageway is a puzzle.

The sliding door is a door.

The linked evidence of the Secret Passageway is the sliding door.

Definition: The Secret Passageway is complete if the sliding door is comprehended.

The cat hint of the sliding door is "The cat pads over to the back of the room and rubs up against the wall, purring."

The Dark Basement is a puzzle.

Definition: The Dark Basement is available if it is not complete and the Secret Passageway is complete.

The fuse box is a thing.

The linked evidence of the Dark Basement is the fuse box.

Definition: the Dark Basement is complete if the west basement switch is switched on.

The cat hint of the fuse box is "The cat sits down underneath the fuse box and starts licking its paw."

The Lighting Rig is a puzzle.

Definition: The Lighting Rig is available if it is not complete and the Secret Passageway is complete.

The black sphere is a thing.

The linked evidence of the Lighting Rig is the black sphere.

Definition: the Lighting Rig is complete if the black sphere is comprehended and the player has evidence of the black sphere.

The cat hint of the black sphere is "The cat [if the black cloth is in the Tunnel and the black sphere is in the Tunnel]steps delicately across the cloth and sniffs [otherwise if the black sphere is not in the Tunnel]stretches up to sniff [otherwise]sniffs [end if]at the black sphere."

The Scary Male Bathroom is a puzzle.

The non-spoilery name of the Scary Male Bathroom is "the men's restroom".

The glowing tissue paper is a thing.

The linked evidence of the Scary Male Bathroom is the glowing tissue paper.

[The tissue paper doesn't need a cat hint because the cat can't get into the men's bathroom. It'll just go up to the door and then the standard cat-wants-to-go-through-a-closed-door behaviour will handle that.] [NICE -rcv]

The Hooky Thing is a puzzle.

The non-spoilery name of the Hooky Thing is "finding a hook-shaped thing".

The Hooky Thing is non-walkthroughable.

Definition: The Hooky Thing is available if it is not complete and the Dark Basement is complete.

The shepherd's crook is a thing.

The linked evidence of the Hooky Thing is the crook.

Definition: The Hooky Thing is complete if the player carries the crook.

The cat hint of the crook is "The cat bats a paw at the end of the crook, then jumps back."

The Flying Rig is a puzzle.

The non-spoilery name of the Flying Rig is "the tangle of bars and cables".

Definition: The Flying Rig is available if it is not complete and the Dark Basement is complete.

The Engelgurt is a thing.

The linked evidence of the Flying Rig is the Engelgurt.

Definition: the Flying Rig is complete if the Engelgurt is comprehended and the player has evidence of the Engelgurt.

The cat hint of the Engelgurt is "The cat springs onto the pile of bars and things and from there up onto the railing of the balcony but[em dash]probably wisely[em dash]immediately jumps back down again."

The Final Confrontation is a puzzle.

The non-spoilery name of the Final Confrontation is "the trapdoor".

The pull-cord is a thing.

The linked evidence of the Final Confrontation is the pull-cord.

Definition: the Final Confrontation is available if it is not complete and the Scary Male Bathroom is complete and the Flying Rig is complete and the Lighting Rig is complete [and Towers of OCD is complete]. [we admit defeat, Towers of OCD has problems and you do not have to complete it to finish the game, even if you are relying on the walkthrough]

Definition: the Final Confrontation is complete if the Steeple is visited.

The cat hint of the pull-cord is "The cat puts its paws up on the wall below the trapdoor and stretches, yawning widely."

Section - Random Church People Mentioned in Notes

[Well why don't you put this in a better place, if you're so smart?]

[FINE I WILL, BECAUSE YOU'RE RIGHT, I AM THAT SMART]

The West High Warbler is a familiar thing. Understand "newspaper" and "journalism" and "school" as the West High Warbler.

The note of the West High Warbler is "'So, we understand that West High is a lousy school, but I think the [italic type]Warbler[roman type] is pretty good for a high school newspaper. We do a good job. I mean you and me specifically. It's too early to say who's going to be editor-in-chief next year but I'm pretty sure it's you.'"

Grace United Methodist Church is a familiar thing. Understand "methodists" as Grace United Methodist Church.

The note of Grace United Methodist Church is "'I have been going to Grace United Methodist since I was a little baby. I got baptized there, I got confirmed there, I met most of my friends there. I know you think churches are stupid, so you probably think my church is stupid, but I love my church, so shut up.'"

Does the player mean querying about Grace United Methodist when the location is not Dining:

it is likely.

Does the player mean querying vaguely about Grace United Methodist when the location is not Dining:

it is likely.

Casey is a man.

The note of Casey is "'Dear Robin. I am Casey, your friend. I am writing to you from the past. Back here in the past it is very dark, but we have hope that you, in the future, will be able to rekindle the flame of enlightenment and lead us to wisdom. Have you seen a ghost yet? If you haven't seen a ghost, keep looking around until you do. Thanks. Sincerely, Casey.'"

Patrick the youth leader is a man.

The note of Patrick the youth leader is "'Patrick the youth leader is Grace's youth leader currently. In the distant past there was a different, previous youth leader, but we don't talk about her.[paragraph break]'Actually, I'm looking over the other notes I've written and it looks like I've probably said too much about Patrick the youth leader too.'"

Gwen is a woman. Understand "homeschooled" and "home schooled" and "home-schooled" as Gwen. [I believe that Robin would consider it disrespectful to refer to Gwen as "Homeschooled Gwen" when she doesn't know her, even if Casey does]

Instead of querying the notes about Gwen: try querying the notes about the abstract painting.

Heather is a woman.

The note of Heather is "'Remember Heather? She's on the newspaper, but she never says or does anything? I don't really care for her, but if you like her I'm willing to reconsider.'"

Tammy is a woman.

The note of Tammy is "'If you don't know Tammy, Tammy is this girl who goes to church but kind of hates it and always brings some non-church-related reading material to pass the time. She describes herself as a [apostrophe]hobby reader[apostrophe], which is a really awful term, but it's Tammy, so who cares.'"

Minnie is a woman.

The note of Minnie is "'Minnie was this hardcore college girl who used to play music here. She had tattoos. Sometimes she played acoustic guitar as accompaniment on Sunday mornings, but she brought her electric guitar to youth group and played Christian rock and everybody loved her.[paragraph break]'But every youth group night, she'd have to lug her amp in and out. It wasn't a big amp, but it was heavy enough to be a pain to carry around. Plus it didn't sound very good.[paragraph break]'But then, on Minnie's birthday, Patrick the youth leader somehow caused this gigantic halfway-decent amplifier to appear. And it had to stay at the church, that was the whole point of it, but it was understood that this was Minnie's amplifier.[paragraph break]The last paragraph has been erased and rewritten a few times. 'The details of the reason that Minnie stopped coming to church aren't my business to tell you about. She had to leave, and her amp stayed behind, and now it's in the basement where nobody will ever use it.'"

Marcie Kempulfers is a woman.

The note of Marcie Kempulfers is "'Marcie Kempulfers is in charge of the bell choir and that kind of thing and she's boring.'"

Pastor Ivan Shearer is a man.

The note of Ivan Shearer is "'Good old Pastor Ivan! What can you say about someone like Pastor Ivan? Not much!'"

Chad is a man. [I want to leave him unnoted so bad, but being unnoted is basically a clue that you're important, and Chad is not.]

The note of Chad is "'Chad's an all right guy. Or, he used to be. I haven't heard from him in a while.'"

The lock-in is a familiar thing. Understand "lockin" and "lock in" and "sleepover" and "slumber party" and "karaoke" as the lock-in.

The note of the lock-in is "'I just realized that you never got around to asking me how the lock-in went. Let me give you a taste of what you missed: Patrick the youth leader brought a two-foot cube of popcorn, and over the course of the night we chiseled pieces off and ate them. They were so crusty, and so nasty.[paragraph break]'We did karaoke in the sanctuary, and Orchid was hogging the machine. Naturally. So in an effort to restore balance, Patrick the youth leader started bugging Heather, who has never expressed any interest in singing in front of people, to get up there. She whimpered about it a lot, but peer pressure is a powerful force[unicode 8212]actually I guess Patrick the youth leader isn't really Heather's peer?[unicode 8212]anyway, she did get up, and she sang the quietest, creakiest, most pathetic version of [']Take On Me['] that has ever been sung on this earth. It was horrible! And it was everyone's fault![paragraph break]'What else? There was a lot of praying. And obviously we drank too much pop and we played Romans and Christians for like three minutes and then we played Sardines, and it was great. The whole thing was great. I'm intentionally omitting the greatest parts here, to make you feel bad about not coming.'"

The presbyterian denomination is a familiar thing. Understand "presbyterians" as the presbyterian denomination.

The note of the presbyterian denomination is "'You probably think it's pretty racist of me to rag on Presbyterians as much as I do. Well, Robin, there's a lot you don't know about me. It's very possible that I have very good reasons for saying all the terrible things I've said, and you just don't know what they are, because I'm a complicated person with a lot of secrets. So don't judge.'"

The youth group is a familiar thing.

The note of the youth group is "'Currently the youth group has about a dozen members. It depends on whether you count tagalong junior high students, or the one or two people who are supposedly banned but show up anyway, or nominal members who never show up because they're too cool for us.[paragraph break]'Ours is a diverse youth group, although I guess it's mostly white Christians. Teondis was black, but he left the group when Orchid broke up with him. We also had an atheist member for a while, but he quit showing up for some reason. We're diverse in other ways, though.[paragraph break]'I keep suggesting cool names for the youth group, so we don't have to keep calling it just [']the youth group['] anymore, but none of them catch on. I don't have the clout with these people that I should. Patrick the youth leader has a lot of influence, obviously, and he makes a lot of suggestions, but his are all super hokey. We could probably get somewhere if we ever teamed up, but that seems unlikely.'"

Teondis is a man.

The note of Teondis is "'Fun fact about Teondis: I am pretty sure that is the correct spelling of his name.'"

Theater is a familiar thing. Understand "drama" and "plays" as theater.

The note of theater is "'Orchid and I are both in plays and stuff at school, but for very different reasons. I want to act[unicode 8212]or do props or lights, if that's what's demanded of me[unicode 8212]so I can show you, the audience, a different world, where people other than you have problems other than yours, and by distracting you with those fake people's fake problems I can hopefully relieve the incredible stress of your actual problems, which if you never took a break from worrying about them would definitely reduce you to a crumbled angry skeleton of a person. I want to save you from your self-inflicted torture of taking everything so dang seriously all the time.[paragraph break]'Orchid is in theater because she likes the attention.'"

Part - Things About Rooms And The Things In Them

Chapter - The Basement

The EntireBasement is a region.

Storage West, Storage East, Sunday, Youth, Blacklight, Nursery, Basement Stairway, and Boiler are in the EntireBasement.

[Basementhall is in the EntireBasement.]

Section - Nursery

Nursery is a room.

"[if unvisited]Sharon, in her wisdom, decided that everybody should sleep in this cramped corner of the church basement.[paragraph break][end if][if the toys are not in the toybox]Battered toys spill out of the toybox and across the floor, piling up in a corner of the room.[otherwise]The nursery looks much homier now you've tidied all the toys into the toybox.[end if] Cupboards are mounted high on the walls, out of reach of tiny fingers, and an enormous blue recliner sits underneath them. It's already dark outside, and the doors [west] and [south] are dark as well.[paragraph break]Your sleeping bag is lying on [if the toys are in Nursery]a tidy patch of[otherwise]the[end if] floor, ready for when you finish your investigation."

The note of Nursery is "'What I heard is that you guys are going to sleep in the nursery, which doesn't make sense because there are couches in the youth rooms, but I guess those couches are pretty grody actually. I see your point. They keep some blankets up in the cupboards, but somebody as short as you is probably going to have to climb up on top of the recliner to reach them. No offense, Robin. I'm just saying. You're really short.'"

Carry out querying the notes about Nursery:

now the blankets are discovered;

now the nursery cupboards are transparent.

Instead of going from the Nursery during Blanket Quest:

if Sharon carries the blankets:

say "Sharon hasn't finished her lecture yet.";

otherwise:

say "Sharon said the blankets were in here somewhere. You'd better find them for her before you start exploring."

Instead of going from the Nursery during Ghost Photography 101:

say "Orchid is still clinging to your arm."

Instead of going from Nursery when Tutorial is happening and Ghost Photography 101 has happened and Ghost Photography 101 is not happening:

say "Maybe you should see if there's anything else Sharon needs first."

After going from the Nursery:

now the current interlocutor is nothing;

continue the action.

Robin Monaghan is here. [Not necessary, I just like to make it explicit.]

[Sharon isn't here. Yet. She enters after Orchid finishes her monologue.]

Orchid is here.

The recliner is an enterable supporter in the Nursery. It is scenery.

Understand "enormous" and "blue" and "corduroy" as the recliner.

Understand "chair" and "armchair" as the recliner.

The description of the recliner is "The armchair is covered in lumpy blue corduroy. At least it's clean."

The note of the recliner is "'The nursery's recliner is one of the most important pieces of furniture in the church, because anybody who has to babysit rowdy preschoolers needs somewhere comfortable where they can collapse in exhaustion. It's also an important strategic position whenever the floor is lava.'"

Before entering the recliner when not specifically sitting and not specifically standing:

if the blankets are in the nursery cupboards:

now the chosen posture is standing;

otherwise:

now the chosen posture is sitting.

After entering the recliner when the chosen posture is standing:

say "You step up onto the seat of the recliner, adding at least a foot to your height.".

After entering the recliner when the chosen posture is sitting:

say "You sit down on the recliner and almost disappear into its cushiony depths."

Instead of pushing or pulling or turning the recliner:

say "The recliner is bogged in the carpet."

Instead of pushing the recliner to:

try pushing the recliner.

The nursery cupboards are openable closed containers in the Nursery. They are plural-named and scenery.

Understand "cupboard" and "top" and "shelf" and "shelves" as the nursery cupboards.

The description of the nursery cupboards is "The nursery cupboards are numerous and mounted high up on the walls, presumably so the kids can't get into them[if something is in the nursery cupboards and the nursery cupboards are open].[paragraph break]In the nursery cupboards [is-are a list of things in the nursery cupboards][end if]."

The nursery cupboards are not contents-mentionable-in-description.

Before doing something with something (called untouchable) that is in the closed nursery cupboards:

if the current action implies touching the untouchable or the current action is examining the untouchable:

say "(first opening the nursery cupboards)[command clarification break]";

silently try opening the nursery cupboards;

if the nursery cupboards are closed:

stop the action.

Instead of opening or searching the nursery cupboards when the player is not on the recliner or the posture of the player is not standing:

if the blankets are seen or the blankets are discovered:

say "You can barely reach the cupboards from down here.";

otherwise:

say "There are way too many cupboards, and you can't even see what's on the top shelves from here, much less reach them. Surely there's a better way to find out where the blankets are kept than just hunting through everything."

Instead of searching the closed nursery cupboards:

say "(first opening [the nursery cupboards])[command clarification break]";

try opening the nursery cupboards.

Instead of searching the nursery cupboards when the nursery cupboards contain nothing:

say "There's nothing else of interest in the cupboards."

After opening the cupboards when the blankets are in the nursery cupboards:

if the blankets are discovered:

say "Yes, there are the blankets. Right where Casey said they'd be.";

otherwise:

say "It takes some hunting to find them, but there are the blankets, up on the top shelf."

The blankets are in the nursery cupboards. They are plural-named.

The blankets can be discovered or undiscovered. They are undiscovered.

The blankets are familiar.

Understand "blanket" and "sheet" and "sheets" as the blankets.

The description of the blankets is "The blankets are small, thin, and colorful. Probably they're designed for making kids[apostrophe] afternoon naps fun, not for actually sleeping under."

Instead of querying Casey's notes about when the second noun is the blankets or the second noun is the nursery cupboards:

try querying Casey's notes about Nursery.

Instead of taking the blankets when the blankets are in the nursery cupboards and the player is not on the recliner:

say "You can just see the blankets over the edge of the shelf, but you can't quite reach them."

Instead of taking the blankets when the blankets are in the nursery cupboards and the player is on the recliner and the posture of the player is sitting:

say "Sitting on the recliner is comfortable, but not a practical position from which to reach the blankets."

Instead of wearing the blankets:

say "You throw a light-colored blanket over your head and moan, 'Woooo! I'm a spooky ghost!' No one laughs, so you take it off again."

Instead of taking or pulling the blankets when Sharon is asleep:

say "You give the blankets a gentle tug, but Sharon stirs and pulls them closer around herself."

Instead of jumping when Robin is in the Nursery and the blankets are in the nursery cupboards:

say "Jumping briefly puts you within reach of the cupboards, but the effect doesn't last long enough to be a solution to your problem."

The nursery window is a closed transparent scenery container in the Nursery.

Understand "reflection" as the nursery window.

The note of the nursery window is "'The nursery window doesn't open at all, which is a fire hazard if you ask me. I'm no fire marshal, but I've got some opinions.'"

Rule for printing the name of the nursery window when the asking which do you mean activity is going on or photo-name-printing is true:

say "nursery window".

The description of the nursery window is "You have a foggy idea that the window probably overlooks the church parking lot, but it's too dark to see anything except your own reflection."

Instead of examining the nursery window when the cat is in the nursery window:

try examining the cat.

Instead of searching the nursery window: try examining the nursery window.

Instead of opening the nursery window:

say "It seems to be stuck[if the cat is not in the window]. Anyway, it's really too cold to have the windows open[end if]."

When Ghost Photography 101 begins:

now the cat is in the window;

now the cat is seen;

now the last action of the cat is the action of searching the nursery window;

now the last action of Orchid is the action of freaking out;

now the last action of Sharon is the action of examining the cat;

say "Suddenly Orchid gasps and grabs your arm. 'Someone's outside!' she squeaks, pointing at the window.[paragraph break]Behind the glass, you see a pale face, blurry in the dim light."

Every turn when the cat is in the window and the time since Ghost Photography 101 began is 3 minutes:

say "Sharon says sharply, 'Well, aren't you going to take a photo?' but her voice sounds shakier than usual."

Instead of photographing the window with something when the cat is in the window:

try photographing the cat with the Polaroid.

After photographing something with something when the cat is in the window:

remove the cat from play;

now the last action of the cat is the action of waiting;

now the last action of Orchid is the action of waiting;

now the last action of Sharon is the action of waiting;

Orchid critiques your photography in one turn from now;

Sharon goes to bed in two turns from now;

say "The click of the shutter sounds loud in the silence and seems to startle the creature outside the window. It turns and vanishes out of the light, its tail flicking past the glass. Orchid gives a high-pitched giggle.[paragraph break]'Scared of a cat!' Sharon says. 'You better not freak out and wake me up every time you mistake a shadow for a ghost tonight.'"

The cots are an enterable supporter in the Nursery. They are plural-named and scenery. They are not contents-mentionable-in-description. The usual posture of the cots is sitting.

Understand "tiny" and "bed" and "beds" and "cot" as the cots.

The description of the cots is "Each cot is composed of scratchy fabric stretched over an aluminum frame, and there is no way any of them could be very comfortable[if Sharon is on the cots].[paragraph break]Sharon is sleeping on the cots, hunched up awkwardly underneath the blankets[end if]."

The note of the cots is "'The cots in the nursery are for little pre-school babies. Nobody else in their right mind would sleep on those cots. Any couch in the church is more comfortable. You can even sleep in the pews. Don't be a schmuck.'"

Instead of taking or pushing or pulling or turning the cots:

if Sharon is in Nursery and Sharon is awake:

say "Sharon shoos you away from the cots.";

otherwise if Sharon is asleep:

say "You can't mess with the cots without waking Sharon.";

otherwise:

say "You adjust the alignment of the cots slightly."

After entering the cots when the chosen posture is sitting:

say "You perch on the edge of one of the cots and focus on not sliding down into the sagging center of the mattress."

Instead of entering the cots when the chosen posture is standing and Sharon is not in the Nursery:

say "The frame of the cot creaks and bends as soon as you put your weight on it, so you quickly step back down."

Instead of entering the cots when Sharon is awake and Sharon is in the Nursery:

say "Sharon whisks the cot out from under you[if the chosen posture is standing]r foot[end if] before you can [if the chosen posture is sitting]sit down[otherwise]step up onto it[end if]."

Instead of entering the cots when Sharon is asleep:

say "There's no room for you on the cots while Sharon is sleeping on them. You'd be [chosen posture] on her instead."

Instead of sleeping in the cots:

say "Sharon is [if Sharon is asleep]sleeping[otherwise]going to sleep[end if] there."

Instead of putting something on the cots while Sharon is awake and Sharon is in the nursery:

if the noun is the blankets, try giving the noun to Sharon instead;

say "Sharon sweeps [the noun] off the cot onto the floor.";

now the noun is in the location;

if the noun is the toys, now the noun is undescribed.

Instead of putting something on the cots while Sharon is asleep:

say "There's hardly room for [the noun] on the cots while Sharon's sleeping on them."

The toys are a thing in the Nursery. They are plural-named and undescribed.

Understand "battered" and "toy" as the toys.

Understand "cars" and "wooden" and "blocks" and "tea" and "set" and "teaset" and "block" as the toys.

The description of the toys is "Toy cars, a lot of wooden blocks, a tea set, that kind of thing. It looks like someone tried to take a bite out of one of the blocks."

Instead of eating the toys, say "The prospect raises a sick feeling in your stomach. All these toys are probably covered in germs."

Instead of putting the toys on something:

say "The toys belong in the toybox."

Instead of inserting the toys into something when the second noun is not the toybox:

say "The toys belong in the toybox."

After taking the toys when the toys were in Nursery:

say "You gather up an armful of toys."

After inserting the toys into the toybox:

say "You sit down for a moment and arrange the toys neatly in the box. A bit of time spent organizing is always very relaxing.[paragraph break]There. Much better."

Instead of taking the toys when the toys are in the toybox:

say "You just put the toys away. Don't start making a mess again."

Instead of pushing the toys:

if the toys are in the toybox:

try taking the toys;

otherwise:

try inserting the toys into the toybox.

Instead of inserting something into the toys:

say "The toys are too small and probably too unhygienic to be a suitable container for anything."

The toybox is a scenery container in the Nursery.

Understand "toy box" and "box" as the toybox.

The hide description of the toybox is "[if the toybox contains the toys]You won't fit in the toybox now that all those toys are inside[otherwise if sharon is asleep]As you consider your whim to jump inside of the toybox, you look over at Sharon. She might wake up, and wonder what you're doing, at any moment[otherwise]It's too late for you to disappear unnoticed now.[end if]."

The description of the toybox is "It's just a bright red box made of lightweight plastic. You imagine that the toddlers in the church probably knock it over a lot. At least it's not heavy enough to do them any damage."

The note of the toybox is "'The toybox is one really bad hiding place for games like Sardines, because to get inside you have to dump out all of the toys. It's not because the pile of toys lying on the floor looks suspicious or out of place at all; it's because Patrick the youth leader will insist that you put all the toys away afterward.'"

The note of the toys is "'When church people need to get rid of their kids['] old toys, they always think of the church before they think of the thrift store. So there are way too many old beat-up toys in the nursery, and it's a huge pain to put them all away, and once in a while you have to disinfect all of them, which is also a huge pain. This is an example of purely altruistic actions leading to terrible negative consequences.'"

Instead of searching the toybox when nothing is in the toybox:

say "The toybox is almost empty."

Instead of entering the toybox:

say "Even the weight of the toys has left stress marks in the plastic. It definitely would not bear your weight."

Instead of taking the toybox:

if the toys are in the toybox:

say "You imagine the sorrow of the small children running eagerly into the nursery only to discover that their precious toys are missing, and decide to leave the toybox where it is.";

otherwise:

say "The toybox is light enough, but it's too large to carry around comfortably. You decide to leave it where it is."

Instead of turning the toybox:

if the toys are in the toybox:

say "You can't bear the thought of spilling the toys everywhere again after you've just tidied them up.";

otherwise:

say "You upend the toybox and discover a crack in the bottom. Doesn't seem like it'll be much use for anything except containing toys, so you turn it up the right way again."

Instead of pushing or pulling the toybox:

say "You shift the toybox slightly, so that it's sitting exactly parallel to the wall."

The sleeping bag is an enterable container in the Nursery. It is scenery.

The indefinite article of the sleeping bag is "your".

Understand "magenta" as the sleeping bag.

The description of the sleeping bag is "This is the sleeping bag you got in fifth grade. You still fit in it just fine, so you can't replace it, even though it's in an unbearable shade of magenta."

Instead of taking the sleeping bag:

say "It'll be fine staying here while you investigate."

Instead of sleeping when the location is the nursery:

try entering the sleeping bag.

Instead of sleeping when the location is not the nursery:

say "When you feel you've got all the evidence you need, your sleeping bag is waiting for you in the nursery."

Instead of entering something during Ghost Photography 101: [mainly to prevent Robin from going to bed at an inopportune moment]

say "Orchid's grasp on your arm is too tight for you to go anywhere."

Instead of entering the sleeping bag when Orchid is in the nursery and Aiden is not in the nursery and Ghost Photography 101 is not happening:

say "Orchid says, 'You can't go to bed yet, we haven't even started our investigation!'"

Instead of entering the sleeping bag when Aiden is in the nursery:

say "It's too late for that now. You have to do something about Orchid and Aiden."

Check entering the sleeping bag:

[We might be able to help the player a bit at this point by actually listing the evidence they've found so far.]

say "Before you get into your sleeping bag, you quickly review the evidence you've collected. Are you sure you have everything you need for the story?";

say ">> [run paragraph on]";

if the player consents:

continue the action;

otherwise:

say "After a moment's thought, you change your mind about going to bed. Maybe there's still something you missed." instead.

To decide whether no evidence was encountered:

if the cat is not seen:

decide yes;

decide no.

To decide whether only some fake ghost evidence was encountered:

if the cat is seen and the ghostly figure is not seen:

decide yes;

decide no.

To decide whether all the fake ghost evidence was encountered:

if the ghostly figure is seen:

decide yes;

decide no.

To decide whether hoax evidence was found:

if the player has evidence of the black sphere or the player has evidence of the cheap-looking mirror or the player has evidence of the black cloth:

decide yes;

if the player has evidence of the can of goo:

decide yes;

if the player has evidence of the Engelgurt:

decide yes;

if the player has evidence of the glowing tissue:

decide yes;

decide no.

To decide whether no hoax evidence was found:

if hoax evidence was found:

decide no;

decide yes.

After entering the sleeping bag:

say "[line break]You put your belongings aside and snuggle down in the sleeping bag.[paragraph break]";

say "***";

wait for any key;

say paragraph break;

if no evidence was encountered: [this should not be possible, as Orchid should stop you from going to bed at this point]

say “‘So, you didn’t find any indication that there was a ghost. At all.’[paragraph break]’Well, what did you expect, Casey? Ghosts aren’t real.’[paragraph break]’But, I mean, the church is still pretty spooky at night. You could have gotten at least a [‘]what a spooky church[‘] story out of it. How much did you look around?’[paragraph break]’I’m sorry you’re disappointed,’ you say, ‘but I wrote what I wrote, and they’ll just have to print it.’”;

end the story saying “They ended up running Heather’s book review instead.”;

otherwise if only some fake ghost evidence was encountered:

say “‘And this is all you have?’[paragraph break]Casey [if the player carries exactly one photo]considers your single photo[otherwise]spreads your photos out on his desk[end if].[paragraph break][if a photo shows the flickering lights]’Some spooky lights. Okay.’ He furrows his brow.[paragraph break][otherwise if the flickering lights are seen]’Well, I saw some spooky lights,’ you offer.[paragraph break]’Did you take a picture?’[paragraph break]’I did not.’[paragraph break][otherwise if a photo shows the cat]'It's a cat.'[paragraph break]You nod.[paragraph break][otherwise]’Well, I also saw a spooky cat.’[paragraph break]’A cat?’[paragraph break]You nod.[paragraph break][end if][if the player carries something that contains ectoplasm]You pull out your jar of ectoplasm. ‘I also found this!’[paragraph break]He squints at the slimy stuff in the jar. It looks rather more mundane in the light of day. You start stuffing it back in your bag.[paragraph break][otherwise if a photo shows an ectoplasm]He squints at the image of the ectoplasm. ‘Sure, sure. Fairly legit, I guess’ he says.[paragraph break][otherwise if an ectoplasm is seen]’I also encountered some ectoplasm.’[paragraph break]’So what happened to it?’[paragraph break]’I washed it off. It was all over my hand, Casey. It was disgusting.’[paragraph break][end if]He tries to smile. ‘You’re going to write a whole article just based on this?’[paragraph break]’Well,’ you say, ‘I’m going to try.’”;

end the story saying “They ended up running Heather’s dressage article instead.”;

otherwise if all the fake ghost evidence was encountered and no hoax evidence was found:

say “‘It sounds like you had quite the spooky evening!’[paragraph break]’It certainly seemed that way at the time, but now I’m not so sure. Take a look at [if the player carries exactly one photo]this[otherwise]these[end if],’ you say, handing Casey your photo[if the player carries more than one photo]s[end if].[paragraph break][if a photo shows the flickering lights]He points at the image of the flickering lights. ‘I imagine these were more impressive in motion.’[paragraph break]’How did you know they were moving?’[paragraph break]’Well, they look kinda like lights from a party ball.’[paragraph break]You look at the picture again. He has a point.[paragraph break][otherwise]’You saw some spooky lights. But you didn’t get a picture.’[paragraph break]’I was very frightened,’ you say.[paragraph break]’Well, what did they look like?’[paragraph break]You describe the lights to Casey, and he frowns. ‘They sound like the kind of lights you get from one of those party balls.’[paragraph break][end if][if the player carries something that contains an ectoplasm]’And you collected some ectoplasm?’[paragraph break]'Well, I collected this.' You hand him the jar.[paragraph break]'Looks like ectoplasm to me!'[paragraph break]'Does it look like it could be anything else?'[paragraph break]'Yeah, I guess. It could be...'[paragraph break]'It could be anything.'[paragraph break][otherwise if a photo shows the ectoplasm]He turns his attention to the image of the weird slime. 'If this isn't ectoplasm, then what is it?'[paragraph break]'It could be any kind of non-paranormal gunk,' you say. 'It could be car wax, for all we know.'[paragraph break][otherwise]'You also saw some ectoplasm.’[paragraph break]’Yes, I did.’[paragraph break]’Well, what happened to it?’[paragraph break]’I washed it off. It was all over my hand, Casey. It was disgusting.’[paragraph break][end if][if a photo shows the ghostly figure]He lifts the photo of the floating girl. ’Now, this photo looks like a ghost,’ he says, ‘but I mean, it also kind of looks like any number of fake ghost photos you see all over the place. Not that I don’t believe it was a real ghost, but other people might not find it so convincing.’ He tries to smile.[paragraph break][otherwise]’But you did see a real ghost?’[paragraph break]’Yes.’[paragraph break]’You saw a free-floating, full-torso, vaporous apparition. But you didn’t get a picture.’[paragraph break]’It was a very stressful situation.’[paragraph break][end if]";

if the player has evidence of the flickering lights or the player has evidence of a random ectoplasm or the player has evidence of the ghostly figure:

say "He sighs. ’So, what are you thinking?’[paragraph break]’I think I was duped.’”;

end the story saying “They ended up running the story anyway.”;

otherwise:

say "He tries to smile. ‘You’re going to write a whole article just based on this?’[paragraph break]’Well,’ you say, ‘I’m going to try.’";

end the story saying "They ended up running Heather's travelogue from Peoria instead";

otherwise if hoax evidence was found:

say “‘Okay, what have you got?’[paragraph break]’Well.’ You take a bit longer than necessary to pull the photos out of your backpack. It’s nice to have Casey at your mercy, for once. ‘For a while, I almost thought there was really a ghost.’[paragraph break]’Surely not!’ Casey gasps.[paragraph break]";

if the player has evidence of the black sphere and the black sphere is comprehended:

say "’For example, I saw some [italic type]spoooooky[roman type] lights in the basement. But then I found this.’ ";

if the player encloses the black sphere:

say "You reveal the party light sphere";

otherwise: [the proof is a photo]

say "You reveal your photo[if more than one photo shows a lighting-rig-componentish thing]s[end if] of [list of lighting-rig-componentish things shown by a photo with definite articles]";

say ".[paragraph break]Casey chortles. ’What a cheap effect!’[paragraph break]";

otherwise:

say "’For one thing, I saw these lights in the basement.’ [if a photo shows the flickering lights]You pass Casey the photo you took.[paragraph break]’Well, those look fake[otherwise]You quickly describe the flickering lights.[paragraph break]'Well, that sounds fake[end if]. Did you find out how they did it?’[paragraph break]’I’m entertaining a hypothesis,’ you say, and you quickly move on to your next exhibit.[paragraph break]";

if a photo shows the can of goo:

say "’I also found this [‘]ectoplasm[‘]. Which turned out to be this:’ You show Casey the photo you took of the can of goo.[paragraph break]’I know that shelf! How the heck did you get up there?’[paragraph break]’Don’t ask.’[paragraph break]";

otherwise:

say "’And I found this clearly fake ectoplasm.’[paragraph break]’How do you know it was fake?’[paragraph break]’It’s obviously not real ectoplasm, Casey.’[paragraph break]’Oh, the word [‘]obviously[‘]. That’s real journalism.’[paragraph break]";

say "Then Casey leans in. ‘But I heard you saw a real ghost. She flew around and everything.’[paragraph break]’Well, I did see something like that.’[paragraph break]’But?’[paragraph break]";

if the player has evidence of the glowing tissue:

say "’I found this piece of tissue paper. The substance on the tissue was glowing just like the ghost.’[paragraph break]’And where did you find this?’[paragraph break]’I found it in the men’s room,’ you say, and Casey’s eyes go wide, but you go on before he has a chance to say anything.[paragraph break]";

if the Engelgurt is comprehended:

say "’I also found the [‘]Engelgurt[‘].’[paragraph break]’From the Christmas play, yeah!’ Casey nods.[paragraph break]’Only it wasn’t in the storage room. It was up on the balcony.’[paragraph break]’So...’[paragraph break]’So the [‘]ghost[‘] was not flying unassisted.’[paragraph break]";

otherwise if a photo shows the Engelgurt and the Engelgurt is not comprehended:

say "’I also found this.’ You hand him the picture of the strange device you found in the balcony.[paragraph break]He looks it over. ‘This is the Engelgurt! The flying machine from the Christmas play!’ He grimaces. ‘That ghost was no ghost, Robin.’[paragraph break]";

otherwise:

say "’I think something fishy was going on with that ghost.’[paragraph break]’Sounds like it.’[paragraph break]";

say "Casey leans back in his chair. ‘So, do you think it was Orchid?’[paragraph break]’It couldn’t have been. She was right there in the room with me. And the only other person in the church was Sharon.’[paragraph break]’Well, can’t you write some kind of exposé? ‘Church Ghost Obviously Completely Fake[quotation mark]?’[paragraph break]’I don’t think I can make it stick, but I’ll try. I definitely won’t let them print Orchid’s ghost story with my name on it, though. It’s a bunch of lies.’”;

end the story saying “They ended up running the story without your name on it.”;

otherwise:

say "BUG: Emily screwed up some code here, whoopsies!".

The walls are a backdrop.

Understand "wall" as the walls.

The walls are in Balcony, Stairs, Altar, Sanctuary, Narthex, Dining, Kitchen, Main Floor Stairway, Mens, Ladies, Tunnel, Storage East, Storage West, Boiler, Basement Stairway, Nursery, Sunday, and Youth.

The description of the walls is "You don't notice anything notable about the walls."

Section - Youth Room

Youth is south of Nursery. The printed name of Youth is "Youth Room".

Youth is light-switchable.

Understand "youth room" as Youth.

The description of Youth is "A large part of this room is taken up by a rickety ping pong table. Couches line the edges of the room, some of them close enough to the table that they're probably not safe to sit on if someone is actually playing ping pong. On the other hand, you can't see any ping pong paddles anywhere, so maybe that's not an issue. In between the couches, doors lead [north], [west], and [south]."

The note of Youth is "'So, this is where us High School Christians hang out and experience fellowship. There are also junior high kids.[paragraph break]'Actually, what happened was, the junior high and high school groups used to be consolidated, but then Orchid and some other high schoolers thought they needed a separate group for mature people. The criterion was supposed to be [']maturity['], but I mean you can't tell people that they can't join your group because they're too immature, that's elitist, so instead the criterion for the new group was, whether you're in high school or not.[paragraph break]'And in the big kids group we just play tag and gossip anyway, so, so much for maturity! Orchid just didn't want to have to put up with junior high kids; that's what was going on.'"

The ping pong table is a scenery supporter in Youth. The description of the ping pong table is "This scratched, peeling ping pong table has seen better days."

Understand "ping-pong" as the ping pong table.

The note of the ping pong table is "'The ping pong table actually belongs to Patrick the youth leader, which originally meant that we had to take extra special care not to sit on it or scratch it up or anything, but eventually we realized that if it belongs to the [italic type]church[roman type] then we need to be careful with it but if it belongs to [italic type]Patrick the youth leader[roman type] then we can abuse it however we want.[paragraph break]'I think Heather or somebody wanted to repaint the whole thing and put a Jesus fish on there or something but that plan has yet to pan out.'"

Instead of playing the ping pong table:

say "The complete lack of ping pong paddles, a ping pong ball and an opponent makes that impractical."

Instead of pushing or pulling or turning when the noun is the ping pong table or the noun is the youth room couches:

say "There's very little room left in the youth room to rearrange the furniture."

A couch is a kind of supporter.

A couch is usually enterable, scenery, and plural-named.

Understand "grody" and "couch" and "couches" as "[couch]".

Understand "[couch]" as a couch.

[Before printing the name of a couch (called sofa) when the asking which do you mean activity is going on or photo-name-printing is true:

say "[location of the sofa] ";

Understand "[something related by locality] [couch]" as a couch.] [Removed to improve performance.]

Instead of querying Casey's notes about a couch:

say "'An interesting tidbit! Over the years since Patrick the youth leader introduced these couches that he got for free into our basement, the couches in the youth room eventually got so grody that we had to switch them with the couches in the blacklight room, where it's slightly harder to tell how grody a couch is. Imagine Patrick the youth leader's chagrin when he found out that the couches he took out of the blacklight room were super grody anyway!'"

Instead of doing something when the current action implies touching the youth room couches or the current action implies touching the blacklight room couches:

say "You'd rather not touch the couches. In fact, you'd rather not even get too close to them."

The youth room couches are a couch in Youth.

The description of the youth room couches is "The couches appear to be haunted by the ghosts of years of snacks and soft drinks. Casey wasn't kidding when he said they were grody."

The garish golden quiz tournament trophy is in Youth.

The printed name of the quiz trophy is "trophy".

The initial appearance of the quiz trophy is "A garish golden trophy catches your eye."

The description of the quiz trophy is "The figurine on top is a generic gold-painted plastic person raising its arms in victory. The text at the bottom reads: 'BIBLE QUIZ TOURNAMENT CHAMPIONS[quotation mark]."

Understand "bible quiz" and "bible tournament" and "bible trophy" and "figurine" and "person" and "plastic" and "plastic person" and "text" as the quiz trophy.

The note of the quiz tournament trophy is "'If you come across a trophy in the youth room: that trophy, we won in a Bible Quiz Tournament, like three years ago(?). We were competing with youth groups from the Lutheran church and the Presbyterian church up the street, and we did not take these Bible Quiz Tournaments seriously [italic type]at all,[roman type] but apparently the other groups took them even less seriously, and we took home the trophy five out of six times. I'm pretty sure the Presbyterians never won once.[paragraph break]'After that, we stopped having Bible Quiz Tournaments, and since we won the last one the trophy just stayed in the church, even though it was actually originally provided by one of the other churches.[paragraph break]'Robin, I'm not saying Presbyterians are dumb. But man, Robin: their kids sure are.'"

After doing something when the current action is querying Casey's notes about the quiz trophy or the current action is examining the quiz trophy:

now the printed name of the quiz trophy is "Bible Quiz Tournament trophy";

continue the action.

Instead of inserting something into the quiz trophy:

say "This isn't a cup sort of trophy, it's the kind with a figurine of a little victorious person on it."

Instead of putting something on the quiz trophy:

say "The trophy doesn't have enough of a flat surface to be putting things on it."

The trolley is a supporter in Youth. The printed name of the trolley is "TV trolley".

The description of the trolley is "A cube of black metal bars, mounted on casters."

The trolley is pushable between rooms.

Understand "tv trolley" as the trolley.

Rule for writing a paragraph about the trolley:

if the trolley is in Youth:

say "A trolley with an ancient TV [if the super nintendo is on the trolley]and a Super Nintendo [end if]on it is standing in front of one of the couches.";

otherwise:

say "The TV trolley is standing in the middle of the room, looking lonely."

Instead of taking the trolley:

say "The trolley would be too big and awkard to pick up even if it didn't have a TV on it."

Instead of putting something on the trolley when the noun is not the Super Nintendo:

say "It looks like the trolley was specially designed for the TV and SNES. There isn't really room for anything else on it."

Some casters are part of the trolley. The description of the casters is "The casters are small wheels stuck to the bottom of the TV trolley. They have hair and lint stuck in them."

The note of the trolley is "'Yeah, we have video games at church. I think the SNES belongs to Chad. Does Chad even come to church anymore? Well, he's gotta come back someday. To get his SNES.'"

Instead of querying Casey's notes about the casters:

try querying the noun about the trolley.

The television set is a device. It is on the trolley. Understand "TV" and "telly" and "faux" and "wood" and "paneling" as the television set.

The description of the television set is "It must be a pretty old set, based on the faux wood paneling on the sides."

The note of the television set is "'For some reason, we never actually watch TV on the TV in the youth room. We just play video games. I guess it's because on TV you never know if you're gonna see something sinful, like a lady in a bikini, or a tattoo.'[paragraph break]Underneath this, Casey wrote 'Speaking of bikinis:' and then erased it."

Instead of taking the television set,

say "Far too heavy."

The television set is switched off.

Instead of switching on the television set,

say "You have better things to do than watching television right now."

The Super Nintendo Entertainment System is on the trolley.

Understand "snes" as the Super Nintendo Entertainment System.

The printed name of the Super Nintendo Entertainment System is "SNES".

The Super Nintendo is not contents-mentionable-in-description.

The description of the Super Nintendo Entertainment System is "A thin layer of dust on the power switch[if Bubsy is in the Super Nintendo] and the Bubsy cartridge in the slot[end if] suggests that the SNES hasn't been used for a while."

After taking the Super Nintendo when the Super Nintendo was on the trolley:

say "You unplug the SNES from the TV and pick it up."

After putting the Super Nintendo on the trolley:

say "You plug the SNES back into the TV."

Instead of switching on the Super Nintendo Entertainment System, say "This is no time for video games[if the Super Nintendo Entertainment System contains the Bubsy cartridge]. Especially not Bubsy[end if]."

Instead of playing the Super Nintendo:

try switching on the Super Nintendo.

Instead of playing Bubsy:

say "This is no time for video games. Especially not Bubsy."

Instead of switching off the Super Nintendo:

say "The SNES is already turned off."

Check inserting something into the Super Nintendo Entertainment System:

if the noun is not the Bubsy cartridge:

say "The slot of the SNES won't contain [the noun]." instead.

The note of the super nintendo entertainment system is "'We used to play nothing but Tetris Attack, all the time. But eventually it started to cause some strife among the youth group. So Patrick the youth leader took Tetris Attack away.'"

The Super Nintendo Entertainment System contains a Bubsy cartridge. Understand "busby" as Bubsy. The description of the Bubsy cartridge is "The front of the cartridge features a picture of a grinning, winking cat and the subtitle 'Claws Encounters of the Furred Kind'."

The note of the Bubsy cartridge is "'I don't even know what Bubsy is about. A squirrel? It doesn't even have a proper two-player mode. You have to wait and watch the other guy play. It's bad for the group. I miss Tetris Attack.'"

Tetris Attack is a thing.

Understand "panel de pon" as Tetris Attack.

It is familiar.

The note of Tetris Attack is "'Tetris Attack is this really great game that we used to play all the time in youth group. It isn't really anything like Tetris; it's actually a reskin of a Japanese game called Panel De Pon. How it works is, there are all these different colored squares, and you have to switch them around two at a time, and...'[paragraph break]Casey's notes on Tetris Attack continue for several pages. He's even included some diagrams. This is not information pertinent to your investigation."

Section - Black Light Make-Out Room

Blacklight is south of Youth. The printed name of Blacklight is "Black Light Room".

Blacklight is not light-switchable. [Because we have the lights-on message in the room description.]

Understand "black light" and "black-light" and "blacklight" and "make-out" and "make" and "out" and "makeout" as "[blacklight-room]".

Understand "[blacklight-room]" and "[blacklight-room] room" as Blacklight.

The description of Blacklight is "[if unvisited]You flip the light switch, but the only things that light up are your shirt and your socks.[paragraph break][end if]The black walls in here have been painted with Bible verses that glow underneath the UV lights. The couches are glowing, too; unsettlingly green. The door to the north, on the other hand, is barely visible.[paragraph break]Propped up in one corner is a rough wooden cross."

After looking in Blacklight when Blacklight encloses the black sphere and the black sphere is lit:

say "The party light sphere casts flashing blue lights across the walls and ceilings, giving the room an irreligious resemblence to a nightclub.";

continue the action.

After switching on the small button in Blacklight when the black sphere was comprehended:

say "The party sphere lights up, casting flickering blue lights across the walls and ceilings. Now all you need are some glow sticks."

After switching off the small button in Blacklight:

say "The party lights die out and the room returns to its usual eerie glow."

The note of Blacklight is "'Yes! This room! So, Patrick the youth leader got us together a few years ago and had us paint the walls of this room black, and then paint Bible verses on it, and then install black lights instead of normal lights, so it would look like a Christian rave or whatever. And I mean it looks fairly cool, I guess.[paragraph break]'But when you have a dark room, with purple lights, and a bunch of couches, and then you invite teenagers into the room and leave them in that room unattended, what happens is, the teenagers will use that room for what Patrick the youth leader calls [']heavy petting['].[paragraph break]'So that's why this room is called the Black Light Make-Out Room.'"

Carry out querying Casey's notes about Blacklight:

now the printed name of Blacklight is "Black Light Make-Out Room".

Instead of exiting when the player is in Blacklight:

try going north instead.

Some blacklights are scenery in Blacklight. Understand "uv" and "lights" and "light" and "black" and "black-light" and "black lights" and "black light" and "bulb" and "bulbs" as the blacklights.

The description of the blacklights is "Long fluorescent bulbs radiate a dim purple light. If you remember correctly, you shouldn't look directly at them."

Instead of querying Casey's notes about the blacklights:

try querying Casey's notes about Blacklight.

Does the player mean doing something with the blacklights:

it is likely.

Does the player mean doing something with the light switch when the location is Blacklight:

it is unlikely.

Instead of switching off the blacklights:

try switching off the light switch.

Instead of switching on the blacklights:

try switching on the light switch.

The blacklight room couches are a couch in Blacklight.

Understand "stains" and "stain" and "glowing" as the blacklight room couches.

The description of the blacklight room couches is "The black lights reveal several glowing stains on the couches."

Some verses are scenery in Blacklight. The printed name of the verses is "verses painted on the walls". The verses are plural-named. Understand "bible" and "verse" or "verses" or "paint" or or "word" or "words" or "painted" or "on" or "walls" or "wall" as the verses.

The description of the verses is "There are maybe a dozen different verses, painted in different UV-sensitive colors, but one in particular demands your attention:[paragraph break][italic type]For the wages of sin is death, but the free gift of God is eternal life.[roman type][paragraph break]It should be 'The wages of sin [italic type]are[roman type] death.'"

The note of the verses is "'I had nothing to do with the verses in the black light room. After we painted the walls black, I wanted to reserve one wall for a big mural of a dolphin, and that idea got voted down, so I got mad and went home.'"

The rough wooden cross is scenery in Blacklight. The description of the wooden cross is "You have to guess that whoever constructed this cross purposefully chose the roughest, most splintery lumber available.[paragraph break]Around the center plank (which is twice as tall as you are), on top of the crossbar, is a 'crown of thorns' made from rusty barbed wire."

Instead of taking the rough wooden cross, say "The wooden cross is far too unwieldy, and splintery."

The note of the rough wooden cross is "'If you ask me I think that big gnarly cross in the black light room is in kind of poor taste, mostly because of the barbed wire crown on top. It doesn't belong in a church, it belongs in a grungy music video, with some rotting steak or something.[paragraph break]'I dunno, I feel like the torture of Christ isn't exactly radical? But I guess Patrick the youth leader likes it.'"

The rusty barbed wire crown of thorns is part of the rough wooden cross. The description of the crown of thorns is "The wire was probably stolen from the fence around a junk yard. Your jaw clenches involuntarily."

Instead of taking the crown of thorns, say "Even if you were tall enough to pull it over the top of the cross, you wouldn't want to carry that crown around with you."

Instead of querying casey's notes about the crown of thorns:

try querying casey's notes about the rough wooden cross.

Section - Basement Stairway

Basement Stairway is a privately-named room.

Understand "stairway" and "basement stairway" as Basement Stairway.

Basement Stairway is west of Nursery and south of boiler and north of Sunday. [I don't want to call it a 'hallway' but this room basically only exists to connect rooms. maybe Basement Stairway is actually a good name for it]

Basement Stairway is backstory-visited and light-switchable.

The description of Basement Stairway is "This room is apparently just for show; there are no tables or chairs. A wide staircase runs up to the main floor of the church, and doorways lead [east], [south] and [north]. Mounted on the wall is a gigantic abstract painting."

The note of Basement Stairway is "'Man, I already wrote something about Gwen's painting. There's nothing else to say about the bottom of the stairs.'"

Instead of going up from Basement Stairway during Investigating the Basement:

if the flickering lights are seen: [that means the player went into the hallway but not right to the end for some reason]

say "You know, maybe you should take a closer look at those weird lights you saw before you go upstairs.";

otherwise:

say "Orchid said she'd investigate upstairs. You'd better finish checking out the basement before you go up and join her."

The gigantic abstract painting is scenery in Basement Stairway. Understand "Homeschooled Gwen" or "Gwen" or "Gwen's" or "Gwen's painting" as the gigantic abstract painting.

The description of the gigantic abstract painting is "The piece is very pleasant, if not particularly interesting: the inoffensive greens and pinks could suggest river waters, or branches waving in the wind. Its size is probably its most impressive quality."

The note of the gigantic abstract painting is "'I'll tell you about the big painting at the bottom of the stairs, but first I have to tell you about Homeschooled Gwen.[paragraph break]'Homeschooled Gwen, so called because she was totally homeschooled, went to our high school. Yes! She was not in fact [italic type]completely[roman type] homeschooled, because her parents sent her to West for seventh-period geometry, because they did not remember the quadratic formula. It is: x equals negative b plus or minus the square root of b squared minus 4ac, over 2a.[paragraph break]'But Gwen's parents couldn't remember that, even though I, Casey, memorized it so easily. So Gwen went to West High. And she was in my Geometry class.'"

go-on is a truth state that varies.

[I rewrote this code so that you wouldn't end up with a bunch of "if the player consents" indented halfway across the screen. I admit there are probably better things I could've been doing with my time. Anyway, you can now just stick the rest of the story in the Table of Gwen's Story and the code should deal with it. I included the thing where the last want-to-continue ignores the player's input, by the way.]

After querying Casey's notes about the gigantic abstract painting:

say "You pause before flipping the page. This story barely seems relevant to the church, much less your investigation. Are you sure you want to keep reading? ";

repeat with count running from 1 to the number of rows in the Table of Gwen's Story:

say "[line break]>> [run paragraph on]";

now go-on is whether or not the player consents;

if go-on is true or count is the number of rows in the Table of Gwen's Story:

say the instalment in row count of the Table of Gwen's Story;

say line break;

otherwise:

say "You close the notebook to save the rest of the story of Homeschooled Gwen for another time.";

rule succeeds.

Table of Gwen's Story

instalment

"You turn the page:[paragraph break]'So, due to being homeschooled, Gwen was not at all socialized for interacting with us teens of the modern era. What I am saying is that she was super weird. I was friends with her mostly out of morbid curiosity. Here are some of the weird stunts she pulled in Geometry: Told us all individually what breed of dog we would be if we were dogs. Read us stories, apparently like Wendy read to the Lost Boys. Gave us a survey about what we found attractive in girls.[paragraph break]'When I say [']us['] I mean just the boys in class. Gwen was super boy-crazy, because, due to being homeschooled all of her life, Gwen had never seen a boy before. Yes.'[paragraph break]This looks like it might be turning into an extended rant against the institution of homeschooling (Casey can be something of a jerk when it comes to things he knows nothing about). Do you want to continue?"

"Casey goes on:[paragraph break]'I mean she had probably seen a male human before. She had a dad; we found that out eventually. But you know what I mean.[paragraph break]'Anyway one day after school, after seventh-period geometry, I was hanging out in the mud room waiting for my ride home, and Gwen was there too, waiting for her own ride back to her own horrible school-home hybrid, and then [italic type]Patrick the youth leader[roman type] showed up, because he's still allowed on school grounds. And he asked me about the lock-in.'[paragraph break]It is increasingly clear to you that this story has no bearing on your investigation. Do you want to keep reading it?"

"You turn another page.[paragraph break]'Or he asked me about [italic type]something.[roman type] Probably the lock-in. But we were talking, and Gwen was there, and Patrick the youth leader WITHOUT CONSULTING ME BEFOREHAND looks over at Gwen and asks her if she wants to come to the lock-in. And of course Gwen says yes, because there will be boys there.[paragraph break]'Gwen came to the lock-in, and after that she started coming to the high school group meetings. And an unfortunate percentage of people in the group did not seem to catch on right away that Gwen was a nutbar, so she felt very welcome and emotionally supported by us, and when Patrick the youth leader opened the floor for [']discussion['] after his sermons we all got to listen to her insane opinions about Thanksgiving, and family togetherness, and sex, etc., etc.'[paragraph break]You look up from the notes. Maybe there's something else you should be doing. Do you want to continue reading?"

"'Then, this was around the end of last semester, Patrick the youth leader gave all of us in the group one of his CHALLENGES. His CHALLENGE to us this particular week was for us to think about our relationship to the church. I mean, like, [']spend the next seven days thinking about this, and come back next week with something really profound.['] A lot of Patrick the youth leader's CHALLENGES are basically attempts to get us to say something profound.[paragraph break]'And of course we all forgot about this CHALLENGE immediately, because come on. He never follows up on any of them anyway. He just read in some youth leader magazine that you should give your youth group CHALLENGES.[paragraph break]'And when we came back the next week, of course, Patrick the youth leader doesn't bother asking anyone what brilliant answers we came up with to his incredibly vague CHALLENGE. We had a sermon and then we played Sardines or whatever.[paragraph break]'But before we could leave, Patrick the youth leader called us all together, because Gwen had something to share with us.'[paragraph break]Keep reading?"

"'Now that I think about it, she must have brought the painting in with her, left it behind a couch or something, and waited for three hours or however long for Patrick the youth leader to ask for people's answers to his CHALLENGE of the previous week. She was just too freaked out and embarrassed to bring it up herself, until the very last possible moment.[paragraph break]'So yeah it was this painting. I'm not gonna bother describing this painting, because you can see it yourself. But if you think about it, all those tiny brushstrokes on a canvas that huge must have taken a zillion hours to do, and she supposedly only had a week to paint it. I guess that's what the church meant to Gwen.'[paragraph break]It goes on a little longer, but that feels like an end to the 'substance' of the story, such as it is. Should you bother reading the rest?"

"[if go-on is false]You are unable to master your curiosity and continue reading anyway.[paragraph break][end if]'Well, sometime during the summer, Gwen quit coming to the youth group. It took me a while to figure out what happened but it turns out she got [italic type]grounded[roman type] from [italic type]church[roman type] because her parents found out she had a [italic type]crush[roman type] on a [italic type]boy[roman type] who went there.[paragraph break]'So, that is the story on Homeschooled Gwen. You will never meet her, because her parents will never let her out of the house again.'"

Section - Boiler Room

Boiler is a privately-named room. The printed name of Boiler is "Boiler Room". Understand "boiler room" as Boiler.

Boiler is light-switchable.

The description of Boiler is "[if unvisited]All of a sudden you feel very claustrophobic. [end if]This must be a fairly large room, but most of the space is given over to snaking pipes, anonymous machinery, and the church's giant boiler."

The note of Boiler is "'I've only been inside of the boiler room very briefly, but I have to assume it's a really cool place to hang out. Make sure you tell me all about it when you get the chance.'"

Some pipes are scenery in boiler.

Understand "snaking" as the pipes.

The description of the pipes is "Many of the pipes run all the way down to the floor from their tangled maze in the ceiling, making some corners of the room impossible to reach."

Instead of searching the pipes, say "There are few gaps wide enough to stick your head through, and they only reveal more of the same scenery."

Instead of searching the pipes when the cat is in Hazy Place:

say "A space leads north through the pipes, but you can't tell where it goes."

Instead of looking under the pipes:

try searching the pipes.

Instead of entering the pipes:

if the cat is in Hazy Place:

try going north;

otherwise:

say "You can't find a gap in the pipes that's large enough to fit a human."

The note of the pipes is "'I believe that the boiler room has a lot of pipes. It stands to reason.'"

The anonymous machinery is scenery in boiler.

The anonymous machinery is ambiguously plural.

The printed name of the anonymous machinery is "machinery".

Understand "gauge" and "pressure gauge" and "valve" and "valves" and "gauges" and "fixture" and "fixtures" as the machinery.

The description of the machinery is "A menagerie of valves and pressure gauges stick out from the pipes at awkward angles, some dangerously close to your eye level."

Instead of turning or switching on or switching off the machinery:

say "You don't know what any of this stuff does, and you probably shouldn't fiddle with it."

Instead of querying Casey's notes about the anonymous machinery:

try querying the notes about the trueboiler.

The trueboiler is privately-named scenery in boiler.

The printed name of the trueboiler is "boiler".

Understand "boiler" and "giant boiler" as the trueboiler.

The description of the trueboiler is "A massive faceless hulk of an appliance. You can hear it murmuring quietly to itself[unicode 8212]or maybe you're hearing something else."

The note of the trueboiler is "'One thing I do know is that the church's boiler is incredibly inefficient. That's what certain adults in the congregation keep whining about, anyway.'"

Instead of touching something that is scenery in boiler, say "Your guess is that anything in here that doesn't burn your hand when you touch it will probably break immediately instead."

Instead of switching on the trueboiler, say "It's on right now, as far as you can tell."

Instead of switching off the trueboiler, say "If there is indeed a switch somewhere that deactivates the boiler, you have no idea where it is."

Instead of listening to boiler, say "Now you can only hear air currents: the whisper of an empty building at night."

Instead of listening to the trueboiler, say "As you perk up your ears to listen closer, the noise stops."

Instead of inserting something into the trueboiler, say "The boiler has no obvious orifices that could contain [the noun]."

Instead of opening the trueboiler: say "You can't find anything that looks like it would open."

Instead of searching the trueboiler: say "Even after a thorough looking-over, you have no idea how this thing works."

Instead of leaving when the player is in Boiler: try going south.

Section - Sunday School Room

Sunday is a room. The printed name of Sunday is "Sunday School Room". The lower case name of Sunday is "Sunday School room". Sunday is west of Youth.

Sunday is light-switchable.

Understand "sunday" and "sunday room" and "sunday school room" and "school room" and "school" and "schoolroom" as Sunday.

The description of Sunday is "This is a room designed for small people. Low benches are arranged like pews in two rows, facing toward a small table that serves as an altar. A poster explaining the Ten Commandments hangs on one wall, and doors lead [north], [east] and [west]."

The note of Sunday is "'The Sunday School room is a lot of fun for a variety of reasons, some of which I have to leave for other sections. But one very important thing to know is that the Sunday School room is a choke point between the storage hallway and the rest of the basement.[paragraph break]'This is very important to know for fire safety reasons, but also for when you're playing Romans and Christians, because the Roman can camp at that door and just pick off Christians as they come around the corner. This is one reason we've switched to playing Sardines instead, in recent years.'"

The small table is a scenery supporter in Sunday. Understand "doily" as the small table. Understand "altar" as the small table [while the location is Sunday]. [removed to improve performance]

The description of the small table is "As altars go, it is fairly tacky: sponge-painted to simulate age, draped with an excessively ornate doily."

The note of the small table is "'The little altar thing in the Sunday School room is a really horrible hiding place when you're playing Sardines. Even with the lights off, it's totally obvious if someone is under there. But, even though it's such a dumb place to hide, everyone always looks there first, which is important for certain meta-Sardines reasons that I won't get into here.'"

The hide description of the small table is "You crouch under the table for a second, feel ridiculous, and decide to exit."

The small white cross is on the small table.

The small white cross is crowbarish.

The description of the small white cross is "This is a nice little cross for a table. Nothing fancy."

The note of the small white cross is "'Man, when I was a little kid in Sunday School, and we had those little kid Bible lessons, I always used to stare at that little white cross, to pass the time or something. I'm pretty sure I was too smart for Sunday School. Sunday School is a weird thing to be too smart for, I guess.[paragraph break]'Although I guess when the high schoolers broke off to be their own mature group, that was basically the same thing. Kind of. In that situation it was because we were too cool for the junior high kids. But that's still really weird.[paragraph break]'What I mean is, it's really weird for people who identify as Christians to also identify as being too cool for something.'"

The bird cage is on the small table. Understand "birdcage" and "perch" as the bird cage.

The description of the bird cage is "The curving faux-wrought-iron bars and caked-on 'rust' identify this as one of the non-functioning, overpriced decorations which are so popular in craft stores. What does a Sunday School need with a bird cage?"

The note of the bird cage is "'Can't really tell you what the Sunday School bird cage is for; it showed up after I graduated. I think it might have something to do with like, Old Testament animal sacrifices? Back when you had to give the priest two of your doves instead of just praying for forgiveness?'"

Instead of searching the bird cage:

say "The bird cage contains a convenient perch for a bird, but no bird."

Instead of opening or closing the bird cage:

say "The bird cage seems to be welded closed. It must be purely decorative."

Instead of inserting something into the bird cage:

try opening the bird cage.

Rule for printing room description details of the bird cage: do nothing.

Some low benches are scenery in Sunday. The low benches are an enterable supporter. The low benches are plural-named. Understand "bench" and "low bench" as the low benches. Understand "pew" or "pews" as the low benches [while the location is Sunday]. [removed to improve performance.]

The description of the low benches is "The benches only come up to about a foot off the ground, but they're longer than you are tall, and built from heavy unfinished pine."

The note of the low benches is "'You can use the benches in the Sunday School room for one of two things. Well, you can also sit on them. But you can use them for two other things:[paragraph break]'For one, there's just barely almost enough space to hide under one, if you're skinny, so they make a great Sardines hiding place because each next person who finds you can hide underneath a different pew and it technically counts as one [']spot['].[paragraph break]'For the other: You can't tell anybody this, but one time Gwen and I snuck in big branches from one of the trees outside and we jumped around on those benches and had an awesome swordfight. It was intense. When it was over with we were both panting and sweaty and there were pieces of bark all over the floor that we had to sweep up before Patrick the youth leader saw it.[paragraph break]'I guess I basically liked Gwen, even though she was super weird.'"

After entering the benches:

say "You [if the chosen posture is sitting]sit down uncomfortably on[otherwise]step up onto[end if] one of the tiny benches."

After getting off the benches:

say "You get off the low bench.";

try looking.

The hide description of the low benches is "You roll underneath one of the benches. The sight of the unfinished wood underneath, as you lie with your arms at your sides, reminds you of the interior of a coffin. You crawl back out."

Instead of taking the low benches:

say "The benches are surprisingly heavy for their size. You start to pick one up, almost drop it on your foot, and decide to leave it be."

Instead of pushing or pulling or turning the low benches:

say "You straighten the rows of benches a little."

The Ten Commandments poster is scenery in Sunday. The description of the Ten Commandments poster is "The Ten Commandments are retold here by little cartoon children, in language appropriate to the target demographic: 'Thou shalt not covet thy neighbour's house, thou shalt not covet thy neighbour's wife,' etc., becomes 'Don't be jealous of what other people have.'[paragraph break]As rusty as you are in this area, you can't remember which commandment is the one about adultery. It must be the seventh one, which is translated here as 'Be faithful and loyal.'"

The note of the Ten Commandments poster is "'Man, I know you're gonna have some issue with how that poster misconstrues the original meaning of the scripture or something. I am gonna tell you in advance to just calm down. Don't worry about it. Look for a ghost.'"

Instead of taking the Ten Commandments poster, say "The poster should probably stay up on the wall."

Section - Hallway

[Personally I like these all having the same name and being distinguished by different landmarks?]

Basementhall is a region. Hall1 is in basementhall. Hall2 is in basementhall. Hall3 is in basementhall. Hall4 is in basementhall.

Basementhall is in the EntireBasement.

A hallway is a kind of room. The printed name of a hallway is usually "Hallway".

A hallway is usually not light-switchable.

The faux-hall is a privately-named thing.

The printed name of the faux-hall is "basement hallway".

Understand "hall" and "hallway" and "basement" as the faux-hall.

The note of the faux-hall is "'The basement hallway, as you will notice, is super creepy, and this is because it's really long. There's a lot of room for somebody to be sneaking up behind you. Actually, make sure you don't read this particular note while you're standing in the hallway, because it'll freak you out if you do.'"

Carry out looking in a hallway when the flickering lights are unseen:

now the flickering lights are seen.

[I don't know why the lights don't get marked as seen automatically, but they don't. Sigh.]

Instead of querying Casey's notes about a hallway:

try querying Casey's notes about the faux-hall.

A mural is a kind of thing.

A mural is usually scenery.

A mural is usually Biblical.

Understand "mural" and "mural of" and "wall" as a mural.

Understand "murals" and "walls" as the plural of a mural.

Before printing the name of a proper-named mural when photo-name-printing is true:

say "the ".

After printing the name of a mural when photo-name-printing is true:

say " mural".

The note of a mural is usually "'I volunteered to paint a mural in the basement, and Patrick the youth leader gave me permission, so I painted a mural of the Four Beasts (the man and the lion and the ox and the eagle) and it was a GREAT MURAL but once they saw it they went ahead and covered it up with JONAH.'"

The faux-mural is a mural. It is plural-named.

Understand "murals" as the faux-mural.

The printed name of the faux-mural is "murals".

First does the player mean querying about a mural (called art):

if the art is the faux-mural:

if the player is in Back Room:

it is likely;

otherwise:

it is very likely;

otherwise:

it is very unlikely.

First does the player mean querying vaguely about a mural (called art):

if the art is the faux-mural:

if the player is in Back Room:

it is likely;

otherwise:

it is very likely;

otherwise:

it is very unlikely.

Rule for clarifying the parser's choice of the faux-mural:

do nothing.

Instead of taking or turning or pushing or pulling a mural:

say "[The noun] [is-are] painted onto the wall."

Hall1 is a hallway. Hall1 is west of Sunday.

The description of Hall1 is "[hall1-desc]."

To say hall1-desc:

say "The hallway runs north";

if the west basement switch is switched off:

say " into darkness. It's hard to tell how long it might be from here, though the Sunday School room to the east provides some light at this end. [one of]A huge figure looms out of the shadows[em dash]no, wait, it's just a plywood image of a lighthouse[or]The plywood lighthouse, on the other hand, peacefully fails to provide any light[stopping]. Behind the lighthouse and partially obscured by it is a mural of Jesus blessing the little children";

if the flickering lights are on-stage:

say ".[paragraph break]A movement catches your eye. Some tiny lights seem to be floating at the far end of the hall, flickering occasionally";

otherwise:

say ", past the plywood lighthouse, all the way up to the door to the tunnel. A doorway to the east leads into the Sunday School room, and on the wall opposite it is the mural of Jesus blessing the little children".

The plywood lighthouse is scenery in Hall1. Understand "light house" and "house" as the lighthouse. The description of the plywood lighthouse is "The piece of plywood is about eight feet tall and an inch thick. A minimum of detail has been painted on to convey that this tapered rectangle is supposed to be a lighthouse. There are no supports; it's just propped up against the wall."

Instead of switching on the plywood lighthouse, say "The plywood image is merely a symbol of a lighthouse, and can't shed any light of its own."

Instead of switching off the plywood lighthouse, say "The plywood lighthouse can't be turned off or on."

Instead of pulling or pushing or taking the plywood lighthouse, say "You get the feeling that if you tried to move this thing anywhere, it would fall on top of you and snap in half."

The note of the plywood lighthouse is "'The lighthouse symbolizes how the church is a beacon of guidance to the rest of the world. I don't mean my church specifically, I mean all of Christianity. Or at least Methodists.'"

Jesus is a mural in Hall1.

Jesus is male and neuter.

The description of Jesus is "As is traditional, Jesus is depicted with very long hair, a white robe and a beatific smile."

Instead of querying Casey's notes about Jesus when Hall1 is not visited:

try consulting Casey's notes about "Jesus" instead.

[this is a long-winded way of getting the "you can't find that in the notes" response, because looking up Jesus and getting the thing about the murals doesn't make sense before you've seen the Jesus mural]

Instead of kissing Jesus:

say "You're pretty sure that kissing images of Jesus is not a United Methodist tradition."

The little children are a mural in Hall1.

The little children are plural-named and ambiguously plural.

Understand "blessing" as the little children.

The description of the little children is "Happy little children of various ethnic backgrounds are crowded around Jesus."

Last check going to Hall1 from Sunday when the west basement switch is switched off and Sunday is light-switchable:

say "You flick the hallway light switch on, but nothing happens. In the end, you turn the Sunday School room lights back on so you can see what you're doing.";

now Sunday is not light-switchable.

Instead of switching on the light switch when the location is a hallway and the west basement switch is switched off:

say "You flick the light switch on and off a few more times. Nope, still nothing."

Instead of switching off the light switch when location is a hallway and the west basement switch is switched off:

say "The lights are already off."

Hall2 is a hallway. Hall2 is north of Hall1.

Hall2 is dimly lit.

The description of Hall2 is "[hall2-desc]."

To say hall2-desc:

if the west basement switch is switched off and the location does not enclose the lit black sphere:

if the flickering lights are on-stage:

say "The tiny lights to the north continue to drift aimlessly. ";

say "Thanks to the light filtering in from the south end of the hall, you can make out some kind of mural painted on the wall, but you can't tell what it's supposed to represent in the gloom";

otherwise:

say "The hallway continues to run north and south. The wall here is taken up by a mural of a beached whale and a man lying on the sand".

The whale is a mural in Hall2.

Understand "beached" as the whale.

The description of the whale is "The plump blue whale is flicking its tail in the air in a cheerful sort of fashion. It doesn't seem at all bothered by having beached itself and vomited up a human."

Rule for printing the name of the whale when photo-name-printing is false and the west basement switch is switched off and the location does not enclose the lit black sphere:

say "bluish blob".

Understand "bluish" and "blob" as the whale.

Jonah is a mural in Hall2.

Jonah is male and neuter.

Understand "man" and "lying" and "human" as Jonah.

The description of Jonah is "It looks like Jonah hasn't recovered from his ordeal in the belly of the whale yet."

Rule for printing the name of Jonah when photo-name-printing is false and the west basement switch is switched off and the location does not enclose the lit black sphere:

say "the indistinct smear".

Understand "indistinct" and "smear" as Jonah.

The beach is a mural in Hall2.

Understand "sand" and "sea" as the beach.

Understand "yellow" and "blue" as the beach.

The description of the beach is "Bright yellow sand, bright blue sea. Clearly a tropical paradise."

Rule for printing the name of the beach when photo-name-printing is false and the west basement switch is switched off and the location does not enclose the lit black sphere:

say "swathe of yellow".

Understand "swathe" and "of" and "yellow" as the beach.

Hall3 is a hallway. Hall3 is north of Hall2.

Hall3 is dimly lit.

The description of Hall3 is "[hall3-desc]."

To say hall3-desc:

if the west basement switch is switched off and the location does not enclose the lit black sphere:

if the flickering lights are on-stage:

say "The flickering lights are only a little way to the north now. Otherwise, it's";

otherwise:

say "It's";

say " almost completely dark. At least you can still see the light at the south end of the hallway. The rectangles to the east and west must be doorways to somewhere, but they're barely distinguishable from the walls";

otherwise:

say "A huge rainbow arches across the wall in this part of the hallway. Underneath it, a door leads west, with an identical door opposite on the east wall".

The huge rainbow is a mural in Hall3.

Understand "arch" as the rainbow.

The description of the huge rainbow is "The rainbow is painted in a bright, cartoony style, with thin black lines between each of the colors. Unfortunately whoever painted it put the indigo and violet stripes in the wrong order." [The rainbow on the window at our local Christian bookshop has this problem. I try not to look at it.]

Rule for printing the name of the huge rainbow when the west basement switch is switched off and photo-name-printing is false:

say "wall".

Index map with Hall1 mapped west of Sunday.

Section - End of Hallway

[There's kind of a lot of stuff going on here so it seems neater for it to have its own section.]

Hall4 is a dark hallway. The printed name of hall4 is "End of Hallway". The lower case name of hall4 is "the end of the hallway". Hall4 is north of Hall3.

Understand "end of hall/hallway" and "end of the hall/hallway" and "hall/hallway end" as Hall4.

The description of Hall4 is "The hall ends here at a heavy door to the north. A huge mural of David fighting Goliath adorns the west wall, but it's marred by a streak of gray gunk clinging to the wall."

Rule for printing the description of a dark room when the location is Hall4 and the flickering lights are in Hall4:

say "It is pitch dark, and you can't see a thing except for the flickering lights floating across the ceiling."

Rule for printing the description of a dark room when the location is Hall4:

say "It is pitch dark, and you can't see a thing except for the dim light trickling in from the south end of the hallway."

Carry out going to Hall4:

now Hall4 is visited. [even though it's still dark and entering a dark room usually doesn't count as visiting it]

Check going a direction in Hall4 when Hall4 is dark and the noun is not south:

unless the room gone to is Tunnel and the Tunnel is visited:

say "It's too dark to see where you're going. A dim light from the south end of the hallway shows you the way back, but if you wander around at random you're probably just going to walk into walls." instead.

The flickering lights are a backdrop. The flickering lights are plural-named and evidential. The flickering lights are in Basementhall.

Understand "tiny" and "floating" and "light" and "blue" as the flickering lights.

The description of the flickering lights is "The lights float across the ceiling like rings of blue smoke, blinking in and out to a frantic, inaudible rhythm."

The photo description of the flickering lights is "Blue lights trail across the photograph, bright against the darkness of the hallway."

Does the player mean doing something with the flickering lights: [as opposed to the light switches]

it is very likely.

[The lights need to be visible in the darkness.]

After deciding the scope of the player when the location is Hall4 and Hall4 is dark:

if the flickering lights are in Hall4:

place the flickering lights in scope.

[And you need to actually be able to look at them and stuff, even though it's dark.]

Visibility rule:

if the noun is the flickering lights:

there is sufficient light.

Instead of doing something when the current action implies touching the flickering lights:

say "The lights are insubstantial (you don't want to say 'ghostly[quotation mark]) [if the location is Hall4]and you can't reach them[otherwise]and they're floating further down the hall[end if]."

Check going north from Hall3 when the flickering lights are on-stage:

if a photo shows the flickering lights:

say "As you approach the lights, they flicker one more time and vanish, leaving you in complete darkness.";

remove the flickering lights from play;

continue the action.

After photographing the flickering lights with when Hall4 is visited:

remove the flickering lights from play;

say "A moment after the shutter clicks, the lights flicker one more time and vanish, leaving you in [if the location is not Hall4]almost [end if]complete darkness. The photo slides out of the camera and falls into your hand."

Instead of following the flickering lights:

if the location is Hall4:

say "The flickering lights are right here.";

otherwise if the location is a hallway:

try going north;

otherwise:

say "You are not aware of any such thing."

David is a mural in Hall4.

David is male and neuter.

Understand "west" as David.

The description of David is "David stands poised, ready to sling a stone at Goliath. The mural makes him look like a ten-year-old. You can't really remember the the details of the story now, but surely he'd have to be a bit older than that before he was allowed to do battle with giants."

The giant is a mural in Hall4.

The giant is male and neuter.

Understand "Goliath" and "west" as the giant.

The description of the giant is "Goliath is stooping slightly to avoid hitting his head on the ceiling of the hallway."

Rule for printing the name of the giant when the location is Hall4 and in darkness:

say "wall".

Instead of touching the giant:

let goop be a random ectoplasm in Hall4;

try touching the goop.

One ectoplasm is in Hall4. [I love how ectoplasm is countable in this world]

After deciding the scope of the player when the location is Hall4 and Hall4 is dark:

place the giant in scope;

let goo be a random ectoplasm in Hall4;

place the goo in scope.

[so the player can feel the wall in the dark. yes, this is weird]

[Understand "wall" and "walls" as an ectoplasm when the location is Hall4 and the item described is in Hall4 and in darkness.] [removed to improve performance]

Robin can be grossed out. Robin is not grossed out.

[She becomes grossed out on her first encounter with ectoplasm.]

Instead of touching an ectoplasm when the noun is in Hall4 and Hall4 is dark:

if the player is grossed out:

say "You run your hand across the wall until you find the patch of ectoplasm again, then rub it between your fingers. It's thick and gooey, with a slightly oily texture[if the player does not carry ectoplasm]. And now it's all over your hand again[end if].";

if the player does not carry ectoplasm:

let goop be a random off-stage ectoplasm;

now the player carries the goop;

otherwise:

discover the ectoplasm at the end of the hall.

Rule for writing a paragraph about ectoplasm (called goo) when the goo is in Hall4:

now the goo is mentioned.

Instead of going south from Hall4 for the first time:

if the flickering lights are in Hall4:

remove the flickering lights from play;

say "As you turn to leave, the lights flicker one more time and vanish, leaving you in complete darkness. ";

if the player is not grossed out:

discover the ectoplasm at the end of the hall;

otherwise:

continue the action.

To discover the ectoplasm at the end of the hall:

say "You run a hand along the wall to help you find your way, and your fingers trail through something cold and slimy. Ugh, now it's on your hand.";

now the player is grossed out;

let goo be random off-stage ectoplasm;

now the player carries the goo.

Orchid can be glimpsed. Orchid is not glimpsed.

[Or it might be Aiden. Or Sharon sleepwalking. Or it might be a GHOST but codewise let's say it's Orchid.]

Every turn when in Hall4 and Orchid is not glimpsed and Hall4 is lit and Robin was in Tunnel:

say "Echoing footsteps draw your attention to a figure walking down the south end of the hallway, but whoever it is goes into the Sunday School room before you can see their face.";

now Orchid is glimpsed.

Section - Storage West

Storage West is a dark room. [Storage West is southwest of Hall3 and northwest of Hall2.]

The lower case name of Storage West is "the western storage room".

Understand "western" and "west" and "storage room" and "store room" and "storeroom" as Storage West.

The note of Storage West is "'There are two storage rooms, one on each side of the basement hallway. There is some neat stuff in those rooms, let me tell you.'"

[a manger, extra chairs, dozens of tiny hempen robes, big cloth signs for parade floats, tricycles, a 50s-era office desk—I will have to go back and check for more. Probably the reason these are locked is because they were such good hiding places for Sardines]

[shepherd's crook, notable absence of angel rig]

[The description of Storage West is an automagically generated list of all this stuff...]

A manger, a huge stack of plastic chairs, a tin of half-used crayons, a pile of tiny hempen robes, a shepherd's crook, some big cloth signs, a tricycle, an unopened packet of marshmallows, an exercise ball, and some paper streamer chains are in Storage West.

[I left the office desk out because I like the "Robin can only put things down in the manger" joke. This is probably not a good reason.]

The description of the manger is "This is clearly a manger from a Nativity scene[unicode 8212]some wisps of hay are still caught in the corners. But baby Jesus is nowhere to be seen."

The manger is a floor-standing container.

Understand "wisps" and "of" and "hay" as the manger.

Instead of taking the manger, say "It's not a huge manger, but carrying it around in both hands would be a pain."

Instead of entering the manger, say "As small as you are, the manger is smaller."

The manger is Biblical.

The note of the manger is "'So last year, Orchid said she wanted to run the Christmas play. And Marcie Kempulfers, who always runs the Christmas play every year, thought that was a great idea. She said it would be really cute to have a little girl be in charge of the play. This was last year, so Orchid was either fifteen or sixteen years old, I think.[paragraph break]'The first thing Orchid suggested was that they use a real baby to play the baby Jesus. Some church person had a baby, and Orchid, because she's completely a girl, was totally nuts for this baby. But Marcie says oh no, we always use a doll for the baby Jesus, real babies cause so many headaches.[paragraph break]'You can see where this is going. But I'll write more about it in some other entries. This is Entry One of Four.'"

The hempen robes are ambiguously plural.

Understand "robe" and "hemp" and "hempen robe" and "stack" and "stack of robes" as the hempen robes.

The hempen robes can be tidy. The hempen robes are not tidy.

Understand "tidy" as the hempen robes [when the hempen robes are tidy]. [removed to improve performance]

The description of the hempen robes is "The robes could only be worn by children, but they could represent any number of Bible characters. [if the hempen robes are tidy]They have been folded and stacked up neatly[otherwise]They've been tossed on the floor in a pitiable heap[end if]."

Rule for printing the name of the hempen robes:

if the hempen robes are tidy:

say "neat stack of hempen robes";

otherwise:

say the printed name of the hempen robes.

Instead of taking or pushing the hempen robes when the hempen robes are not tidy:

say "You pick up the robes, but only to fold them neatly and put them back in a tidier pile.";

now the hempen robes are tidy.

Instead of taking or pushing the tidy hempen robes:

say "You can't bring yourself to disturb them again."

The note of the hempen robes is "'So next Orchid says she wants the shepherds to sing a song. You have to understand that the shepherds are played by the littler kids, and the older kids play angels or Mary and Joseph or the wise men, and while every older kid ends up having to sing a song at some point, the shepherds do not. I think Orchid wanted them to sing [']Silent Night['], which is a pretty good choice for little kids to sing. I will admit that Orchid made a good call here.[paragraph break]'But Marcie did not agree. I'm pretty sure Marcie thinks that because it's impossible to get little kids to carry a tune or understand Italian music vocabulary, nobody wants to hear them sing in church, which is a critical misconception and I think indicates some sort of psychological defect in Marcie Kempulfers's brain. Anyway.[paragraph break]'Marcie made up this insane justification to have the bell choir play [']Silent Night['] instead. She said the bell choir had already practiced it, which was technically true, although specifically they had practiced it during the previous calendar year. But Marcie got her way.[paragraph break]'I hope you're not reading this as me defending Orchid, because I would never do that. Don't worry; we will get to the part where Orchid is horrible in the next entry. This is Entry Two of Four.'"

The description of the shepherd's crook is "A wooden pole with a large hook at one end. Presumably this is for the Christmas play. Judging by its size, the shepherds are played by children."

Understand "pole" and "wooden pole" and "hook" as the crook.

The shepherd's crook is crowbarish.

Instead of waving the crook, say "No matter how much you wave it, it's still just a crook."

The note of the Engelgurt is "'Well, Marcie shut down a couple more of Orchid's ideas, and Orchid eventually figured out her real problem, which was: she kept telling Marcie her ideas. If she was going to change anything about the Christmas program, she was going to have to do it behind Marcie's back.[paragraph break]'So she got her dad to build this crazy device, the Engelgurt, which used a system of rods and pulleys and winches to make someone glide across a room, like an angel.[paragraph break]'A couple nights before the Christmas program, Orchid and her dad came in and set up the Engelgurt while nobody else was around. I mean, I have to assume her dad was involved, although I don't remember him ever getting in trouble over it. Whatever.[paragraph break]'The night of the program came around and for a while everything went exactly as Marcie planned. Jesus was a doll, and the bell choir played [']Silent Night['], and so on. But in the middle of the angels singing [']Angels We Have Heard On High['], Orchid appears up in the balcony, in her non-regulation homemade angel robe, and starts floating down to Earth, and oh no I've run out of space! Cliffhanger! This is Entry Three of Four!'"

The note of the shepherd's crook is "'Okay. Just as she's about to land, Orchid's robe gets caught on one of the shepherd's crooks, and the Engelgurt suffers a critical failure and Orchid falls to the floor and according to some witnesses almost dies. The whole service gets shut down so that Orchid can go to the emergency room, although I think all that happened was she sprained her ankle.[paragraph break]'Of course, Orchid is in huge trouble with Marcie Kempulfers and with the church in general, but what does being in trouble with a church even mean? It's not like they can expel you. We're Methodists. They didn't even get rid of the Engelgurt; it's still in the storage room.[paragraph break]'And anyway Orchid wasn't sorry at all. She kept saying, [']At least it was new!['] [']At least it was exciting!['] Because that's how she operates.[paragraph break]'That's it. This is Entry Four of Four.'"

A storage door is a kind of door. A storage door is usually privately-named and scenery.

Understand "store" and "storage" and "store room" and "storage room" and "storeroom" and "storeroom's" and "room's" and "door" as a storage door.

[Understand "to" and "to the" as a door when the item described is in the location.] [removed to improve performance.]

Understand "doors" as the plural of a door.

[The last door is a storage door that varies.

Carry out going when the door gone through is a storage door:

now the last door is the door gone through.] [removed to improve performance.]

Instead of querying Casey's notes about a storage door, try querying Casey's notes about Storage West.

The west storage room door is a storage door. It is west of Hall3 and east of Storage West.

Rule for printing the name of the west storage room door when the location is Storage West and the current action is looking:

say "door leading out to the hall".

Understand "leading" and "out" and "to" and "the" and "hall" as the west storage room door.

[Rule for printing the name of the northwest storage door:

if the location is Hall3 or the location is Storage West:

say "door to the [if the location is Hall3]west[otherwise]northeast";

otherwise:

say "west storage room's northern door".

Understand "to west/w" and "to the west/w" as the northwest storage door when the location is Hall3.

Understand "northeast" and "ne" as the northwest storage door when the location is Storage West.

Understand "west" and "northern" as the northwest storage door when the location is not Hall3 and the location is not Storage West.

Instead of going west in Hall3: try going southwest.

The southwest storage door is a storage door. It is northwest of Hall2 and southeast of Storage West.

Rule for printing the name of the southwest storage door:

if the location is Hall2 or the location is Storage West:

say "door to the [if the location is Hall2]west[otherwise]southeast";

otherwise:

say "west storage room's southern door".

Understand "west" and "w" as the southwest storage door when the location is Hall2.

Understand "southeast" and "se" as the southwest storage door when the location is Storage West.

Understand "west" and "southern" as the southwest storage door when the location is not Hall2 and the location is not Storage West.

Instead of going west in Hall2: try going northwest.

Instead of going east in Storage West: try entering the last door.] [REMOVED TO IMPROVE PERFORMANCE]

Instead of leaving when the player is [directly] in Storage West: try going east.

Instead of going nowhere when in darkness and (the location is Storage West or the location is Storage East):

say "You stumble about in the dark and [one of]stub your toe on[or]trip over[or]stumble into[or]bump into[or]bruise your hand on[at random] something."

Before going when in darkness and (the room gone to is Hall2 or the room gone to is Hall3) and (the room gone from is Storage East or the room gone from is Storage West):

say "Your flailing about in the dark eventually discovers a door."

[move the doors to the end of the list of junk in Storage West]

Rule for writing a paragraph about something in Storage West:

let junk be the list of things in Storage West;

remove {walls, Robin, light switch, west storage room door} from the junk, if present;

add {west storage room door} to the junk;

say "You can see [junk with indefinite articles] here."

After printing the name of a container (called the item) in Storage West while looking:

if something is in the item:

say " (in which [is-are a list of things in the item])";

otherwise:

say " (empty)".

The description of the huge stack of plastic chairs is "Taller than you are. Looks wobbly."

The plastic chairs are ambiguously plural. Understand "chair" or "plastic chair" as the plastic chairs.

Instead of taking or pulling or pushing or turning or climbing or entering the plastic chairs, say "You'd probably knock the whole stack over if you tried that."

The note of the plastic chairs is "'The plastic chairs in the storage room are the flimsiest dang chairs you'll ever come across. I won't name any names, but I know somebody who stood on top of one of them and it flattened out like Bambi underneath him. They had to throw the chair away, but the guy I'm talking about refuses to feel guilty, because there's no way it was his fault.'"

The tin of half-used crayons is ambiguously plural.

The description of the crayons is "Some of the crayons are half-used. Some of them are more like three-quarters used, or even four-fifths used. The rest are broken."

Instead of inserting something into the crayons, say "The tin is already pretty much full."

The note of the crayons is "'Before a certain unnamed individual left the church, we used to have art activities in Sunday School all the time. It was awesome. But things change, and people change, and on and on. I think there are some crayons left in the storage room.'"

The indefinite article of the big cloth signs is "several".

Understand "several" as the big cloth signs.

The description of the big cloth signs is "You can see that there's text printed on them, but as they're rolled up, you can't read them."

Instead of opening the big cloth signs: say "There's no room to unroll them in here, and anyway you'd never be able to roll them up again."

Instead of taking the big cloth signs: say "You start to pick up one of the signs, but it slips through your hands and starts to unroll, so you quickly push it back into place."

The note of the big cloth signs is "We hang up the cloth signs in the sanctuary for Advent. I think they say [']Hope['], [']Wait['], [']Expect['], and [']Await['].'"

The description of the tricycle is "A pale blue toddler's tricycle, not unlike the one you had when you were a kid. Yours had streamers on the handles, but if this one ever did, they're long gone."

Instead of entering the tricycle: say "The tricycle creaks under your weight, so you quickly get off it again."

Instead of taking the tricycle: say "The tricycle is wedged in among all the other junk and you can't pull it free."

Instead of pushing or pulling or turning the tricycle: say "The tricycle is wedged in among all the other junk, and there's no room for it to move."

Instead of pushing the tricycle to: try pushing the tricycle.

Understand "ride [something]" as entering.

The note of the tricycle is "'When I was in preschool here, things were laid out differently, and the youth room was just this big empty room. And there were two tricycles. I don't know what happened to the other one.[paragraph break]'Anyway, me and another kid would ride the tricycles around the room in a circle, and we'd sing the theme song from COPS, which goes: [apostrophe]Bad boy, bad boy. Whatcha gonna do? Whatcha gonna do when they come for you?[apostrophe][paragraph break]'There are more words to the song, but that was the only part we knew, and we sang it over and over and over again. Actually, it's still the only part I know.'"

The marshmallows are ambiguously plural.

The marshmallows can be open.

The marshmallows can be openable.

The marshmallows are closed and openable.

The marshmallows can be tasted. The marshmallows are not tasted.

The description of the marshmallows is "The best before date is smudged, but judging by the [if the marshmallows are handled]hardness of the marshmallows[otherwise]layer of dust on the packet[end if] you suspect they're well past it by now."

The note of the marshmallows is "'I think I left some marshmallows in one of the storage rooms a while back. They're yours if you can find them.'"

After opening the marshmallows:

now the printed name of the marshmallows is "packet of marshmallows";

say "You tear the packet open. The marshmallows rattle against each other in a way that marshmallows never should."

Instead of closing the open marshmallows:

say "You fold down the top of the marshmallow packet and it promptly springs open again."

Instead of smelling the marshmallows:

if the noun is open:

say "Well, you can't [italic type]smell[roman type] anything wrong with them.";

otherwise:

say "You can't smell anything through the packet."

Instead of touching the marshmallows: say "The marshmallows are as hard as rock candy."

Instead of tasting or eating the marshmallows:

if the marshmallows are not open:

say "(first opening [the marshmallows])[command clarification break]";

silently try opening the marshmallows;

if the marshmallows are tasted:

say "A second experiment hardly seems necessary.";

otherwise:

say "You pick one of the elderly marshmallows out of the bag and eye it suspiciously. It looks okay, but it feels more like a cookie than a marshmallow. Are you sure you actually want to eat it?[line break]";

say ">> ";

if the player consents:

say "You pop the marshmallow into your mouth and crunch down on it.[paragraph break]Okay, that is definitely not how eating a marshmallow is supposed to go.";

now the marshmallows are tasted;

otherwise:

say "Probably wisely, you return the marshmallow to the bag."

The exercise ball is floor-standing.

The description of the exercise ball is "A huge neon pink exercise ball. Some church member is into yoga?"

Instead of taking the exercise ball: say "It's too big, you'd drop everything else you're carrying."

Instead of pulling or pushing or turning the exercise ball: say "The ball doesn't roll very far before bumping up against some of the other junk in the room."

Instead of pushing the exercise ball to: try pushing the exercise ball.

The note of the exercise ball is "'When I was a little kid, that exercise ball was a serious object. Shoving that thing around could have some pretty drastic effects on the world around me. Like, I could knock over some things I could never have knocked over on my own.[paragraph break]'But now I'm a teen, and I'm way taller than that exercise ball, and it's about as inconsequential to me as any other object. I have no idea what I'm going to think about exercise balls when I'm an actual adult.'"

Instead of exercising in the presence of the exercise ball:

say "You sit on the exercise ball and do a few crunches while breathing deeply and rhythmically. Feeling refreshed and energized, you stand up again."

Instead of entering the exercise ball when the chosen posture is sitting:

try exercising.

The description of the paper streamer chains is "Colorful chains made out of paper streamers, like you might use as decorations for a kid's birthday party. The links are all different sizes, and there doesn't seem to be any pattern to the choice of colors. At a guess, you'd say the Sunday School children made these."

Understand "streamers" as the paper streamer chains.

Instead of taking the paper streamer chains, say "The chains are on the other side of a mountain of junk, far out of your reach."

The note of the paper streamer chains is "'If you're in the storage room and you see some paper chains, DON'T TOUCH THOSE CHAINS. Those chains are way too old to still hold together, and yet they do still hold together, because nobody has moved them or paid any attention to them in about fifteen years. Take nothing but pictures, Robin.'"

Section - Storage East

Storage East is a dark room. [Storage East is southeast of Hall3 and northeast of Hall2.]

The lower case name of Storage East is "the eastern storage room".

Understand "eastern" and "east" and "storage room" and "store room" and "storeroom" as Storage East.

Instead of querying Casey's notes about Storage East, try querying Casey's notes about Storage West.

The description of Storage East is "This place is a mess.[paragraph break][towers of ocd puzzle status]."

The east storage room door is a storage door. It is east of Hall3 and west of Storage East.

[Rule for printing the name of the northeast storage door:

if the location is Hall3 or the location is Storage East:

say "door to the [if the location is Hall3]east[otherwise]northwest";

otherwise:

say "east storage room's northern door".

Understand "east" and "e" as the northeast storage door when the location is Hall3.

Understand "northwest" and "nw" as the northeast storage door when the location is Storage East.

Understand "east" and "northern" as the northeast storage door when the location is not Hall3 and the location is not Storage East.

Instead of going east in Hall3: try going southeast.

The southeast storage door is a storage door. It is northeast of Hall2 and southwest of Storage East.

Rule for printing the name of the southeast storage door:

if the location is Hall2 or the location is Storage East:

say "door to the [if location is Hall2]east[otherwise]southwest";

otherwise:

say "east storage room's southern door".

Understand "east" and "e" as the southeast storage door when the location is Hall2.

Understand "southwest" and "sw" as the southeast storage door when the location is Storage East.

Understand "east" and "southern" as the southeast storage door when the location is not Hall2 and the location is not Storage East.

Instead of going east in Hall2: try going northeast.

Instead of going west in Storage East: try entering the last door.] [Removed to improve performance. LOOK AT THIS STUFF

NO DON'T LOOK AT THIS STUFF, JUST SKIP RIGHT OVER IT LIKE THE COMPILER, THANKS]

Instead of leaving when the player is [directly] in Storage East: try going west.

[this code is complete spaghetti, argh]

To say towers of ocd puzzle status:

say "A series of rickety shelves mounted to the north wall have failed to put the room into any kind of order. ";

[lowest shelf status]

if nothing is on the lowest shelf:

say "For some reason, there's nothing on the lowest shelf, even though there's stuff everywhere else. ";

otherwise:

let item be a random thing on the lowest shelf;

say "On the lowest shelf is [an item]";

say ". ";

[cabinet status]

say "Near the shelves is [a sturdy cabinet], maybe [base height of the sturdy cabinet in words] feet tall";

if a non-player thing (called item) is on the cabinet:

say ", on which is [an item]";

say ". ";

[amplifier status]

say "In front of the cabinet and blocking the lower two-thirds of its door stands a huge amplifier";

if a non-player thing (called item) is on the amplifier:

say " with [an item] on it";

[ark statuses]

if an ark (called top ark) is on an ark (called bottom ark) and the bottom ark is in Storage East:

say ". [A bottom ark] is sitting on the floor by the cabinet, with [a top ark] on top of it";

otherwise if an ark is in Storage East:

say ". [A list of arks in Storage East] [if two arks are in Storage East]are[otherwise]is[end if] sitting on the floor by the cabinet";

if a non-player thing (called item1) is on Noah's Ark and a non-player thing (called item2) is on the Ark of the Covenant:

say ". There's [an item1] on Noah's Ark and [an item2] on the Ark of the Covenant";

otherwise if a non-player thing (called item) is on Noah's Ark:

say ". There's [an item] on Noah's Ark";

otherwise if a non-player thing (called item) is on the Ark of the Covenant:

say ". There's [an item] on the Ark of the Covenant";

[goo status]

if the can of goo is on the shelves:

say ". [paragraph break]You can just make out a container of some kind on the very top shelf, glistening strangely".

Before listing nondescript items of Storage East:

now all steppers are not marked for listing;

now all bulky things are not marked for listing.

Before printing a locale paragraph about the lowest shelf:

now everything on the lowest shelf is mentioned.

[To create this puzzle, we will need to create a world in which supporters have relative height and can stack on top of each other and you can only climb a tall one if you're on a shorter one already etc. etc.

I am out of my depth] [-I wrote this comment next to my original worthless attempt at programming the Towers of OCD; obviously Emily figured it out just fine. The concept of the puzzle is still mostly my fault though.]

A thing can be bulky. A thing is usually not bulky.

After taking a bulky thing:

say "You heft up [the noun]."

Check inserting a bulky thing into:

if the second noun is the lowest shelf or the second noun is the wall shelves:

try putting the noun on the lowest shelf instead;

otherwise:

say "[The noun] is too bulky to fit in [the second noun]." instead.

A stepper is a kind of supporter. A stepper is usually enterable. A stepper is usually portable. A stepper is usually bulky.

A stepper has a number called base height.

[I feel like this is drawing too much attention to itself at the moment. It might work better if we stopped Inform from putting it in a separate paragraph. Or it might be better to just write the info into the descriptions manually, like you were going to originally.]

After examining a stepper when the location is Storage East and the noun is not an ark:

say "[The noun] [is-are] about [if base height of the noun is 1]a foot[otherwise][base height of the noun in words] feet[end if] tall";

if the noun is on something (called the platform):

say " on its own, but sitting on top of [the platform], it's more like [total height of the noun in words] feet";

say "."

To decide what number is the total height of (platform - a supporter):

if the platform is not a stepper:

decide on 0;

let h be the base height of the platform;

if the platform is on a stepper (called the underthing):

now h is h plus the total height of the underthing;

[say "Considering [the platform]: its base height is [base height of the platform], its total height is [h], and it is in/on [the holder of the platform].[line break]";] [DEBUG]

decide on h.

[maths, yesssss. not to mention RECURSION. I LOVE RECURSION]

To decide what number is the total height of (platform - a room):

decide on 0.

To decide what number is the reach:

let r be 1;

if the player is on a stepper (called platform):

now r is r plus the total height of the platform;

decide on r.

The entering action has an object called the previous location.

Setting action variables for entering:

now the previous location is the holder of the player.

After entering a stepper when the location is Storage East:

if the previous location is the noun:

say "You [if the chosen posture is sitting]sit down to consider your options[otherwise]stand up, ready for action[end if]";

otherwise:

say "You climb [if the holder of the player is not a stepper or the total height of the noun is greater than the total height of the previous location]up[otherwise if the total height of the noun is less than the total height of the previous location]down[otherwise]across[end if] onto [the noun]";

let n be the total height of the holder of the can of goo minus 1;

unless n is greater than the reach:

say ". You now have a clear view of the glistening container";

say "."

Check putting it on:

if the noun is a stepper and something is supported by the second noun:

say "[The noun] is too large to fit on [the second noun] while [the list of things supported by the second noun] [if the number of things supported by the second noun is greater than 1]are[otherwise]is[end if] still on it." instead;

if the second noun is a stepper and the second noun supports a stepper (called the encumbrance):

say "There's no room for [the noun] on [the second noun] while [the encumbrance] is on [the second noun]." instead;

if the second noun is a stepper and the second noun is on a stepper:

say "Stacking [the noun] on [the second noun] on [the holder of the second noun]? On second thoughts, piling things that high seems a bit dangerous." instead.

Check entering a stepper:

if the player is on the noun:

if the posture of the player is the chosen posture:

say "You're already [chosen posture] on [the noun]." instead;

otherwise:

continue the action;

unless the total height of the noun <= 2 and (the player is in the location or the player is on something that is not a stepper):

if the total height of the noun is greater than the reach:

say "[The noun] [is-are] too [if the base height of the noun is 1]high up[otherwise]tall[end if] for you to climb up on top of [it-them] safely";

if the player is on a stepper (called platform):

say ", even though you're on [the platform]";

otherwise:

say " from your current position";

say "." instead;

if something is supported by the noun:

say "There's [a list of things supported by the noun] on top of [the noun]; you'll have to clear it off before you climb up." instead.

Check entering a stepper:

if the player carries a bulky thing (called the encumbrance) and the total height of the noun is greater than the total height of the holder of the player:

say "You can't climb up onto [the noun] while you're holding [the encumbrance], it's too big and awkward." instead.

Check entering an enterable thing when the noun is not a stepper and the noun is on a stepper:

say "You're not sure that it's safe to climb onto [the noun] while [it-they][if the noun is plural-named][']re[otherwise][']s[end if] on [the holder of the noun]." instead.

[The default handling of getting off is buggy w/r/t steppers - it moves you down onto the thing that the thing you're on is on. Can't be bothered making it move you down to the previous stepper instead, and anyway it would be kind of annoying for the player to have to climb all the way down all the steps. So I'm just making it so that GET OFF or DOWN or whatever just gets you straight down to the floor.]

Carry out an actor getting off a stepper:

surreptitiously move the actor to the location;

rule succeeds.

Report an actor getting off a stepper:

say "You clamber down again.";

try looking;

stop the action.

Instead of going up while the location is Storage East:

say "You'll have to be more specific about what you want to climb up onto."

Check examining the can of goo:

if the noun is supported by a stepper (called the current-stepper):

let n be the total height of the current-stepper minus 1;

if n is greater than the reach:

say "[The noun] is up on top of [the current-stepper]; you can't get a look at it from your current height." instead.

[Check photographing it with:

if the noun is supported by a stepper (called the current-stepper):

let n be the total height of the current-stepper minus 1;

if n is greater than the reach:

say "[The noun] is up on top of [the current-stepper]; you can't take a proper photo of it from your current height." instead.]

Last instead of doing something when the current action implies touching the can of goo:

let the current-stepper be the holder of the noun;

let n be the total height of the current-stepper minus 1;

[say "The current-stepper is [the current-stepper]. Its base height is [the base height of the current-stepper], its total height is [the total height of the current-stepper], and its reachability is [n]. The reach is [the reach].";]

if n is greater than the reach:

say "[The noun] is up on top of [the current-stepper]; you can't reach it from your current [one of]position[or]height[or]altitude[then at random]." instead;

otherwise:

say "[The can of goo] is still far out of reach, but at least from here you can take a clear picture of it." instead.

[Check putting it on:

if the second noun is a stepper:

let n be the total height of the second noun minus 1;

if n is greater than the reach:

say "You can't reach up to [the second noun] from your current [one of]position[or]height[or]altitude[then at random]." instead.]

Check putting it on:

if the second noun is the lowest shelf and the player is on a stepper (called platform):

say "You can't reach the lowest shelf while you're on things." instead.

Check taking:

if the noun is bulky and the player carries a bulky thing (called the encumbrance):

say "It's too awkward to pick up [the noun] while you're still holding [the encumbrance]." instead.

Check taking:

if the noun is a stepper and the player is on a stepper (called the platform):

say "It's too awkward to pick up [the noun] while you're on [the platform]." instead.

Check taking:

if something (called the encumbrance) is on the noun:

say "It's too awkward to pick up [the noun] while [the encumbrance] is on it." instead.

Instead of pushing or pulling a portable stepper:

say "If you need to move [the noun], you'd be better off picking [it-them of the noun] up and putting [it-them of the noun] where you want [it-them of the noun]."

Instead of jumping in Storage East:

if the player is on a stepper:

say "You feel that would be dangerous and probably fruitless.";

otherwise:

say "You can't jump high enough to see the glistening container properly."

An ark is a kind of stepper. The base height of an ark is 2. An ark is floor-standing.

An ark is usually Biblical.

Does the player mean entering an ark that supports an ark:

it is very unlikely.

Does the player mean climbing an ark that supports an ark:

it is very unlikely.

Does the player mean putting a held ark on an ark that is in the location:

it is very likely.

Does the player mean putting an ark that is in the location on a held ark:

it is very unlikely.

Does the player mean putting on a held ark:

it is very unlikely.

Does the player mean taking an ark that supports something:

it is very unlikely.

Instead of opening an ark: say "The top of the ark is screwed down tightly."

Instead of turning an ark: say "The ark wouldn't be stable if you set it on end."

The plywood Noah's Ark is an ark in Storage East. The description of the plywood Noah's Ark is "The whole thing is made out of plywood, but smaller planks of wood have been painted on the sides to give the vague impression of a giant, rectangular seafaring vessel. It's two feet tall, two feet deep, and maybe four feet long."

Understand "noah" and "noahs" as Noah's Ark.

The note of the plywood Noah's Ark is "'Patrick the youth leader isn't much of a carpenter. The extent of his abilities is building sturdy wooden cubes. Which is why Noah's Ark doesn't look anything like Noah's Ark.'"

The plywood Ark of the Covenant is an ark in Storage East. The description of the plywood Ark of the Covenant is "This wooden box has been spraypainted gold and detailed with glitter markers in an attempt to convey that this is an object of great value. It's two feet tall, two feet deep, and maybe four feet long."

The note of the plywood Ark of the Covenant is "'When we put together the Ark of the Covenant for that play, we were all excited about opening it up and pretending that our faces were melting off. It was hilarious. Patrick the youth leader told us to stop, because it was sacrilegious. But we didn't stop. So he screwed the lid shut. So the part of the play where they put the Ten Commandments inside the Ark had to be cut. But every other part of that play ended up getting butchered just as much, so.'"

The case labelled handbells is an openable closed container. It is bulky.

The case labelled handbells is on the plywood Ark of the Covenant.

The printed name of the case labelled handbells is "case labelled 'HANDBELLS'".

After reading a command:

remove quotes;

[if the player's command ends in a full stop, delete the full stop]

let comm be indexed text;

let comm be the player's command;

replace the regular expression "\.$" in comm with "";

change the text of the player's command to comm.

Understand "labeled" and "label" as the case labelled handbells.

The description of the case labelled handbells is "The case is made of tough black plastic."

Rule for printing room description details of the case labelled handbells:

do nothing.

The note of the case labelled handbells is "'Here is the deal with the handbells. Marcie Kempulfers is in charge of the bell choir. She has a very strict handbell protocol. The handbells are church property, and she says so frequently as people try to goof off in bell choir practice.[paragraph break]'But Patrick the youth leader is not so uptight, and for this youth service he thought we should do a bell choir number, without any oversight by or permission from Marcie Kempulfers. He decided we should play [apostrophe]Seek Ye First[apostrophe], because he could only force an octave's worth of kids to volunteer, and he thought it was an easy song. And it is an easy song. But we were poorly motivated.[paragraph break]'So the youth service rolls around, and the extremely unofficial youth bell choir has yet to master our song. But we're listed in the program. We have to go out and perform, and when we perform this song we are going to butcher it.[paragraph break]'Then, right before the service starts, Marcie Kempulfers shows up to have words with Patrick the youth leader. The effects of these words were, first of all, we were definitely not going to be performing a non-Kempulfers-supervised handbell piece, ever, and secondly, now Marcie takes the handbells home with her whenever they aren't being used at church.[paragraph break]'I don't know why she doesn't take the case too.'"

After dropping the case labelled handbells:

say "You gingerly set down the handbell case."

Instead of opening or searching the case labelled handbells, say "You open the case, revealing numerous handbell-shaped depressions in the velvet lining. No handbells here.[paragraph break]You close the case."

Instead of entering or climbing the case labelled handbells:

say "The plastic case flexes dangerously under your weight and you think better of climbing on it."

Instead of pushing or pulling or turning the case labelled handbells:

say "If you want to move the handbells case, you'd be better off picking it up and putting it where you want it."

The sturdy cabinet is a stepper in Storage East. The base height of the sturdy cabinet is 3.

The description of the sturdy cabinet is "A bulky, utilitarian cabinet, trapped and inaccessible behind the mammoth amplifier."

The note of the sturdy cabinet is "'The cabinet in the storage room has a bunch of really cheap art supplies inside. Or at least it used to. I haven't seen the inside of it recently. It has too many drawers to make a decent hiding place.'"

Instead of opening the sturdy cabinet, say "The amplifier is blocking the cabinet door, and you've got no hope of moving it."

Instead of closing the sturdy cabinet, say "It's already closed, and it looks like it's going to stay that way."

Instead of inserting something into the sturdy cabinet: try opening the sturdy cabinet.

Instead of taking or pushing or pulling or turning the sturdy cabinet, say "The cabinet is too big to carry and too heavy to push."

The amplifier is a stepper in Storage East. The base height of the amplifier is 2.

Understand "amp" as the amplifier.

The description of the amplifier is "This thing is much too big, and probably much too loud, for this church. That's probably why it's down here collecting dust."

The note of the amplifier is "'There's an amplifier in the east storage room from back when Minnie used to come here.[paragraph break]'I guess I'll put in a separate entry about Minnie, but as far as the amp, all you need to know is, if you break it, nobody will notice or care.'"

Instead of switching on the amplifier, say "It's not plugged in."

Instead of switching off the amplifier, say "The amplifier is already turned off, and it's not plugged in anyway."

Instead of taking or pushing or pulling or turning the amplifier, say "You can barely budge the amp[if taking], much less carry it around[otherwise]; it's much too heavy[end if]."

The wall shelves are a scenery stepper in Storage East. The wall shelves are plural-named. The base height of the wall shelves is 6.

Understand "top" and "top shelf" as the wall shelves.

The description of the wall shelves is "A series of flimsy shelves have been mounted into the wall here. For the most part, their role as an organizational aid has been ignored."

The note of the wall shelves is "'Once, when I was a stupid young thing, I tried to climb up the shelves in the east storage room.[paragraph break]'Actually, I don't think I can write down exactly what happened. Don't try to climb up those shelves, Robin.'"

The note of the lowest shelf is "'Once, when I was a stupid young thing, I tried to climb up the shelves in the east storage room.[paragraph break]'Actually, I don't think I can write down exactly what happened. Don't try to climb up those shelves, Robin.'"

Instead of climbing the wall shelves, say "The shelves wouldn't support your weight."

Instead of climbing the lowest shelf, say "The shelves wouldn't support your weight."

Instead of putting something on the wall shelves:

try putting the noun on the lowest shelf.

Instead of entering when the noun is the wall shelves or the noun is the lowest shelf:

say "The shelves wouldn't support your weight."

The can of goo is an undescribed evidential thing on the wall shelves. Understand "glistening" and "container" as the can of goo.

The description of the can of goo is "It looks a lot like a paint can, but trails of viscous grayish goop are running down the sides. What printing you can see on the label is in the 'avoid contact with eyes, harmful if swallowed' vein."

The photo description of the can of goo is "Trails of glistening grayish goop run down the sides of the can and dribble onto the shelf beneath it."

Rule for printing the name of the can of goo when the player does not have evidence of the can of goo:

let n be the total height of the wall shelves minus 1;

if n is greater than the reach:

say "glistening container";

otherwise:

say "[printed name of the can of goo]".

Instead of smelling the can of goo:

say "You can't smell anything at this distance."

Instead of opening the can of goo:

try touching the can of goo. [to get the "you can't reach" message]

Check photographing the can of goo with:

let n be the total height of the wall shelves minus 1;

if n is greater than the reach:

say "You can't get a decent shot of whatever it is from down here. You'll need to get a bit closer." instead.

Does the player mean photographing the can of goo with:

let n be the total height of the wall shelves minus 1;

if n is greater than the reach:

it is possible;

otherwise:

it is very likely.

Instead of taking the can of goo with the crook:

let the current-stepper be the holder of the noun;

let n be the total height of the current-stepper minus 1;

[say "The current-stepper is [the current-stepper]. Its base height is [the base height of the current-stepper], its total height is [the total height of the current-stepper], and its reachability is [n]. The reach is [the reach].";]

if n is greater than the reach:

say "[The noun] is up on top of [the current-stepper]; even if you could reach it with the crook, the most you could do is knock it off onto the floor and make a huge mess." instead;

otherwise:

say "You can reach the can with the crook, sure, but the most you could do is knock it off onto the floor and make a huge mess. Maybe you should just leave it where it is."

First instead of hooking the can of goo with the crook:

try taking the can of goo with the crook.

Instead of opening the can of goo with the crook:

try taking the can of goo with the crook.

Instead of throwing something at the can of goo:

say "All you could achieve by that is knocking [the can of goo] onto the floor and making a mess."

The lowest shelf is a scenery supporter in Storage East.

Understand "lower" and "low" and "bottom" as the lowest shelf.

The description of the lowest shelf is "It's weird that this shelf [if something is on the lowest shelf]had[otherwise]has[end if] been left empty, considering how much stuff is piled up everywhere else in the room."

Instead of putting a bulky thing on the lowest shelf when a bulky thing (called base) is on the lowest shelf:

say "There's no room for [the noun] on the shelf while [the base] is there."

Instead of putting a bulky thing on something that is on the lowest shelf:

say "The wall shelves don't leave enough space for you to put [the noun] on [the second noun]."

Instead of entering something when the noun is on the lowest shelf:

say "[The noun] is on the shelf, and the shelf would hardly support your weight alone, never mind [the noun] as well."

Chapter - Upstairs

Section - Main Floor Stairway

Main Floor Stairway is a room. Main Floor Stairway is above Basement Stairway.

Main Floor Stairway is backstory-visited.

The description of Main Floor Stairway is "This room forms a sort of nook off the fellowship hall to the south. A wide flight of stairs leads down to the basement. There are doors to the north, northeast and southeast; according to the plaques on them, they open onto the pastor's office, the men's restroom and the ladies['] restroom respectively.[paragraph break]A vast framed poster is hanging on the wall in between the restroom doors, and in the middle of the room, directly facing the poster, is a wooden bench."

The note of Main Floor Stairway is "'There's an important philosophical difference between the top of the main stairway and the bottom of the main stairway. At the top, there's a poster of an eagle, but at the bottom, there's a painting that Gwen made. They're like opposites of each other. Kind of?'"

[north of here is the unopenable door to the pastor's offices. or, I want it to be unopenable (so we don't have to IMPLEMENT A BORING OFFICE) but maybe we need to make it openable just so people won't get mad at us after spending two hours trying to get inside. I DON'T KNOW

K I have an idea: attempting to open the office door gives you a series of any-key-to-continue messages (MY FAVORITE JOKE, ALWAYS FUNNY):

you open the door/the alarm goes off/police come/you are arrested/you are suspended/you don't get into college

then it finally turns out that this is just what went through your mind as you considered breaking into the office.]

The pastor's door is scenery in the Main Floor Stairway.

Understand "pastor" and "office" and "handle" and "plaque" as the pastor's door.

Understand "plaques" and "doors" as the plural of the pastor's door [when the location is Main Floor Stairway]. [*DEL]

The description of the pastor's door is "The door to the north is no more impressive than any other you've seen, but the plaque on it reads, 'Pastor Ivan Shearer.'". [Last name via http://www.namegenerator.biz/last-name-generator.php. I Googled "random surname" and Google obliged. Which is to say, there is nothing meaningful about the name whatsoever.][OH BUT IT'S SO GOOD: 'Shearer' -> shearing sheep -> shepherd -> pastor. IT'S SO GOOD.]

The pastor's door is not comprehended.

The pastor's door has a number called the fear.

The fear of the pastor's door is 0.

Understand "unlock [something]" as opening.

Instead of opening or entering or attacking or pushing or pulling the pastor's door:

if the pastor's door is not comprehended:

try going north;

otherwise if the fear of the pastor's door is 0:

say "You rattle the door handle, gently at first and then harder. Nothing happens.[paragraph break]";

wait for any key;

say "...and then the alarm starts screaming at you.[paragraph break]";

wait for any key;

say "Minutes later, flashing lights and sirens herald the arrival of the police.[paragraph break]";

wait for any key;

say "You are taken away in handcuffs.[paragraph break]";

wait for any key;

say "After Sharon's report to the principal, the school suspends you. The West High [italic type]Warbler[roman type] stands you down from its staff.[paragraph break]";

wait for any key;

say "No college will accept a delinquent like you. You end up finding work as janitor at West High. The teachers tell new students your story as a warning.[paragraph break]";

wait for any key;

say "...and then you are back in the present. You let go of the door handle and back away hastily.";

increment the fear of the pastor's door;

otherwise:

say "No way. Nuh uh. Not happening."

Instead of going north in Main Floor Stairway:

say "The door to the pastor's office is locked.";

now the pastor's door is comprehended.

Instead of knocking on the pastor's door:

say "No one answers. The pastor would be at home or something at this hour."

The note of the pastor's door is "'You used to be able to get into the pastor's office all the time, back when Patrick the youth leader had his own sub-office at one end of the room where he had free candy. But that was a security risk apparently, so they locked up the pastor's office and Patrick the youth leader had to move his office to his truck.'"

The eagle poster is scenery in the Main Floor Stairway.

Understand "vast" and "framed" and "frame" and "print" and "bible" and "verse" as the eagle poster.

The description of the eagle poster is "The poster is a vast glossy print of a bald eagle gliding through a bright blue sky. In a corner of the sky, a Bible verse is printed: 'But they that wait upon the LORD shall renew their strength; they shall mount up with wings as eagles. Isaiah 40:31.'".

The note of the eagle poster is "'The fact that it's a bald eagle in that poster makes it pretty clear that whoever designed that poster wanted that Bible verse to apply to the people of the United States of America somehow. Which makes me wonder, are there any other countries that insist God loves them the most? Because God can only love one country the most. That's what [']the most['] means.'"

Instead of taking the eagle poster:

say "It's really too big to carry around with you."

The wooden bench is an enterable scenery supporter in the Main Floor Stairway.

Understand "heavy" and "timber" and "rustic" and "beams" as the wooden bench.

The description of the wooden bench is "The bench seems to have been made in a deliberately rustic style, with heavy timber beams. It doesn't look very comfortable."

The note of the wooden bench is "'If you really hate yourself, you can sleep on the bench at the top of the stairs, which I think we inherited from some other church that used it as a torture device during the Inquisition.'"

Instead of taking or pushing or pulling or turning the wooden bench:

say "The bench is just as heavy as it looks."

The usual posture of the wooden bench is sitting.

After entering the wooden bench when the chosen posture is sitting:

say "You sit down on the bench and regard the eagle poster thoughtfully."

The wide flight of stairs is a backdrop.

It is in Main Floor Stairway and Basement Stairway.

Understand "stairway" and "main stairway" and "staircase" as the wide flight of stairs.

The description of the wide flight of stairs is "The flight of stairs is wide enough for three or four people to walk side by side on it. The basement must get a lot of traffic sometimes."

The note of the wide flight of stairs is "'The main stairway is also the only stairway in the church that isn't completely awkward or hazardous.'"

Instead of entering or climbing the wide flight of stairs:

if the location is Basement Stairway:

try going up;

otherwise:

try going down.

Section - Restrooms

A restroom door is a kind of door. A restroom door is usually scenery.

Understand "door" and "restroom" and "rest" and "room" and "bathroom" as a restroom door.

Understand "plaques" as the plural of a restroom door [when the location is Main Floor Stairway].

First carry out going when the door gone through is a restroom door:

say "The door swings shut behind you."

Check an actor going (this is the new can't go through closed doors rule):

if the door gone through is not nothing and the door gone through is closed:

if the actor is the player and the door gone through is a restroom door:

continue the action;

issue library message going action number 28 for the door gone through;

silently try the actor opening the door gone through;

if the door gone through is open, continue the action;

stop the action.

The new can't go through closed doors rule is listed instead of the can't go through closed doors rule in the check going rules.

The mandoor is a restroom door.

It is southwest of Mens and northeast of Main Floor Stairway.

The printed name of the mandoor is "men's room door".

Understand "men's" and "man's" and "mens" as the mandoor.

The description of the mandoor is "[if the location is Main Floor Stairway]The plaque on the northeast door says 'MEN[quotation mark], and you can guess where it leads[else]From this side the door looks unremarkable[end if]."

The note of the mandoor is "'If you have time, you should go ahead and take a look in the men's room, since who knows how many opportunities like this you'll have in the future. I won't spoil anything by describing it here.'"

Steeling is a number that varies. Steeling is 0.

Check going in Main Floor Stairway when the door gone through is the mandoor:

if Mens is visited:

continue the action;

otherwise:

if steeling is 2:

say "That's it. Enough with this cowardice.";

continue the action;

otherwise if steeling is 1:

increase steeling by 1;

say "You can put your hand on the handle, but that's as far as you get. You chide yourself for your indecision." instead;

otherwise:

increase steeling by 1;

say "As you approach the door to the men's room, you stop yourself. Isn't this something that a creep would do?" instead.

Instead of opening the mandoor:

if Mens is visited or steeling is greater than 1:

say "[if the location is Main Floor Stairway]You push the door ajar[otherwise]You pull the door open[end if], and it swings closed." instead;

otherwise:

try going northeast instead.

Before saying no or saying yes when the location is Main Floor Stairway and steeling is 1:

[say "The last thing you did was [the last action of the player]!";]

if the last action of the player is going northeast or the last action of the player is opening the mandoor or the last action of the player is entering the mandoor:

if saying no:

say "Okay, maybe not, but it still feels pretty weird." instead;

otherwise if saying yes:

say "It's totally creepy. How could you bring yourself to sneak into a men's bathroom? Even if no one will ever know?" instead.

Mens is a room. The printed name of mens is "Men's Restroom".

Understand "men's" and "man's" and "male" as "[men's]".

Understand "[men's]" and "mensroom" and "restroom" and "bathroom" and "rest" and "rest room" and "[men's] room" as Mens.

The note of Mens is "'If you have time, you should go ahead and take a look in the men's room, since who knows how many opportunities like this you'll have in the future. I won't spoil anything by describing it here.'"

The description of Mens is "[if unvisited]Yes, this is more or less what you expected.[paragraph break][end if]There are some stalls, and some mirrors, and some sinks[if the garbage can is in Mens], and next to those is a garbage can[end if]. The only things you haven't seen before are the urinals[if unvisited]. Hardly worth having an ethical dilemma over[end if]."

Instead of smelling Mens, say "The atmosphere in here is thick with air freshener."

Instead of leaving when the player is in Mens: try going southwest.

The men's room stalls are scenery in Mens. Understand "stall" as the men's room stalls. They are plural-named. The description of the men's room stalls is "They look like restroom stalls you'd see anywhere else."

The note of the men's room stalls is "'I was volunteering at Vacation Bible School,' he begins, but that's as far as you'll let yourself read."

Instead of searching the men's room stalls, say "You give each stall a very quick once-over. Nothing to see here."

Instead of entering the men's room stalls, say "You give each stall a very quick once-over. Nothing to see here."

Instead of opening the men's room stalls, try searching the noun.

The men's room toilets are scenery in Mens. They are plural-named. Understand "toilet" as the men's room toilets. The description of the men's room toilets is "These are standard toilets. No ghosts."

The note of the men's room toilets is "'I was volunteering at Vacation Bible School,' he begins, but that's as far as you'll let yourself read."

Instead of searching the men's room toilets, say "You decide a close examination is unnecessary. Everything is probably just fine in there."

The urinals are scenery in Mens. They are plural-named. Understand "urinal" as the urinals. The description of the urinals is "It's not a concept that you would ever have come up with yourself, but the general principle seems sound."

The note of the urinals is "'The thing about the urinals in the men's room is, there are no divider walls in between them. I don't like it, Robin. I don't like it at all.'"

The men's room sinks are a sink in Mens. They are plural-named. The description of the men's room sinks is "The sinks are typical sinks."

The note of the men's room sinks is "'One thing you won't be able to notice about the men's room: They used to keep cleaning supplies under the sinks. They don't anymore, because little kids go in there and it was a huge health hazard. That's all I've got.'"

The men's room mirrors are a mirror in Mens.

The men's room mirrors are scenery and plural-named.

The note of the men's room mirrors is "'If you have time, you should go ahead and take a look in the men's room, since who knows how many opportunities like this you'll have in the future. I won't spoil anything by describing it here.'"

The men's room garbage can is an undescribed flippable supporter in Mens. Understand "trash" and "bin" and "wastebasket" as the men's room garbage can.

Instead of examining the men's room garbage can, say "It looks like a normal garbage can[if the inner space of the men's room garbage can contains the glowing tissue paper], except something inside is glowing softly[end if]."

The note of the men's room garbage can is "'If you have time, you should go ahead and take a look in the men's room, since who knows how many opportunities like this you'll have in the future. I won't spoil anything by describing it here.'"

Carry out dropping the men's room garbage can in Mens:

now the noun is undescribed.

A glowing tissue paper is a thing.

Understand "crumpled" and "crumpled tissue" and "kleenex" as the glowing tissue paper.

Understand "something" and "thing" and "glow" as the glowing tissue paper.

The description of the glowing tissue paper is "This tissue was used to wipe up an eerie glowing substance, then thrown in a garbage can."

The glowing tissue paper is evidential.

The indefinite article of the glowing tissue paper is "some".

Visibility rule:

if the noun is the glowing tissue paper:

there is sufficient light.

When play begins:

now the glowing tissue paper is in the inner space of the men's room garbage can.

Does the player mean doing something with the glowing tissue paper:

it is likely.

After taking the glowing tissue paper:

say "You pick up the tissue by one corner, using only the very tips of your fingers."

Instead of smelling the glowing tissue paper:

say "The tissue has a flat, stuffy scent that makes you want to sneeze."

The photo description of the glowing tissue paper is "Something about the lighting in the photo makes it hard to tell that the tissue paper was glowing, but the tissue has an unnatural greenish tinge to it."

Ladies is a room. The printed name of ladies is "Ladies['] Restroom".

Understand "ladies'" and "ladies" and "ladie's" and "lady's" and "women's" and "woman's" as "[women's]".

Understand "[women's]" and "restroom" and "rest" and "rest room" and "[women's] room" and "bathroom" as Ladies.

The womandoor is a restroom door. The womandoor is southeast of Main Floor Stairway and northwest of Ladies. The printed name of the womandoor is "ladies['] room door". Understand "ladies" and "ladies'" and "ladie's" and "women's" and "woman's" as the womandoor.

The description of the womandoor is "[if the location is Main Floor Stairway]The plaque on the northeast door says 'LADIES[quotation mark], and you can guess where it leads[else]From this side the door looks unremarkable[end if]."

The note of the womandoor is "'Well, Robin. I actually explored the ladies['] restroom briefly, during a game of Sardines. But then, because of events that transpired, the ladies['] restroom was declared to be off-limits. And shortly after that, because of fairness, the men's restroom was declared to be off-limits as well. For Sardines purposes at least.'"

Instead of querying Casey's notes about the womandoor, try querying the notes about Ladies.

Instead of opening the womandoor, say "[if the location is Main Floor Stairway]You push the door ajar[otherwise]You pull the door open[end if], and it swings closed."

The note of Ladies is "'Well, Robin. I actually explored the ladies['] restroom briefly, during a game of Sardines. But then, because of events that transpired, the ladies['] restroom was declared to be off-limits. And shortly after that, because of fairness, the men's restroom was declared to be off-limits as well. For Sardines purposes at least.'"

Sardines is a familiar thing. Understand "sardine" as sardines. The note of Sardines is "'Sardines is this awesome game we Christian Youth play instead of Romans and Christians now. In Sardines, a person hides somewhere and then everyone else looks for that person and when you find them you have to get in the hiding place and hide with them. It is fantastic. It's a lot less hectic than Romans and Christians.'"

Romans is a familiar thing. Understand "Romans and Christians" and "Christians" as Romans. The note of Romans is "'Romans and Christians is the game we used to play at church. The rules were, you had two Romans, and everyone else was the Christians, and the Christians just ran around the church in the dark while the Romans tried to catch them and take them to the Jail, which was a couch. If there are any other rules then I'm forgetting them.[paragraph break]'The excitement of being actively chased around the church caused a lot of Christians to kinda lose their heads and occasionally break stuff, so we started playing Sardines instead.'"

The description of Ladies is "A restroom in a church is about the same as any other restroom. You have your stalls, your sinks, your mirrors[if the ladies' room garbage can is in Ladies], your garbage can[end if]."

Instead of smelling Ladies, say "The atmosphere in here is thick with air freshener."

Instead of leaving when the player is in Ladies: try going northwest.

The ladies' room stalls are scenery in Ladies. The printed name of the ladies' room stalls is "ladies['] room stalls". Understand "stall" as the ladies' room stalls. They are plural-named. The description of the ladies' room stalls is "They look like restroom stalls you'd see anywhere else."

The note of the ladies' room stalls is "'To be honest Robin I did not get a good look at much of anything in the ladies['] room.'"

Instead of searching the ladies' room stalls, say "You give each stall a very quick once-over. Nothing to see here."

Instead of entering the ladies' room stalls, say "You give each stall a very quick once-over. Nothing to see here."

Instead of opening the ladies' room stalls, try searching the noun.

Instead of querying Casey's notes about the ladies' room stalls, try querying the notes about the ladies' room toilets.

The ladies' room toilets are scenery in Ladies. The printed name of the ladies' room toilets is "ladies['] room toilets". They are plural-named. Understand "toilet" as the ladies' room toilets. The description of the ladies' room toilets is "These are standard toilets. No ghosts."

The note of the ladies' room toilets is "'To be honest Robin I did not get a good look at much of anything in the ladies['] room.'"

Instead of searching the ladies' room toilets, say "You decide a close examination is unnecessary. Everything is probably just fine in there."

The ladies' room mirrors are a mirror in Ladies.

The ladies' room mirrors are scenery and plural-named.

The note of the ladies' room mirrors is "'To be honest Robin I did not get a good look at much of anything in the ladies['] room.'"

The ladies' room garbage can is an undescribed flippable supporter in Ladies. The printed name of the ladies' room garbage can is "ladies['] room garbage can". Understand "trash" and "bin" and "wastebasket" as the ladies' room garbage can.

The note of the ladies' room garbage can is "'To be honest Robin I did not get a good look at much of anything in the ladies['] room.'"

Instead of examining the ladies' room garbage can:

say "The cleaner must have been in recently, because the garbage can is [if something is in inner space of the ladies' room garbage can]almost [end if]empty[if something is in the inner space of the ladies' room garbage can]. All that's in it is [a list of things in the inner space of the ladies' room garbage can][end if]."

Carry out dropping the ladies' room garbage can in Ladies:

now the noun is undescribed.

The ladies' room sinks are a sink in Ladies. They are plural-named. The description of the ladies' room sinks is "The sinks are typical sinks."

The note of the ladies' room sinks is "'To be honest Robin I did not get a good look at much of anything in the ladies['] room.'"

Instead of querying Casey's notes about the ladies' room sinks, try querying the notes about the ladies' room toilets.