Robin & Orchid — 53 of 88

Section - Switching on the lights

[Robin automatically switches lights on when she enters a room and off when she leaves. This is a bit tricky because some rooms can't have their lights switched on at first, but they can later. Plus the hallway should probably be treated as a single room for lighting purposes? Good grief.]

A room can be light-switchable. A room is usually not light-switchable.

The lights-off count is a number that varies. The lights-off count is 0.

Definition: a room is light-switch-offable if it is light-switchable and the lights-off count is less than 6 and the number of non-player people in it is 0.

Definition: a room is light-switch-onable if it is light-switchable and it is not visited and the number of non-player people in it is 0.

Last check going when the location is light-switch-offable or the room gone to is light-switch-onable:

if the room gone to is Hazy Place or the room gone from is Hazy Place:

continue the action;

say "You ";

if the location is light-switch-offable:

say "turn the lights off in [the location]";

increment the lights-off count;

if the room gone to is light-switch-onable:

say " and ";

if the room gone to is light-switch-onable:

say "switch the lights on in the next room.";

otherwise:

say "."

[TODO: Actually, the more I mess about in the game, the less I like the way this currently works. Probably need to rethink it.

Changed the text a bit, so it doesn't trail off at the end. Still not really happy with the overall effect though.]

[Let's maybe just have this light-switching business happen in the basement, and let it be implied upstairs? It'll probably get a bit tedious after a while.

IT DOES GET A BIT TEDIOUS. Implementing this now.]

A light switch is a backdrop. It is in Steeple, Balcony, Back Room, Sanctuary, Narthex, Dining, Main Floor Stairway, Mens, Ladies, Kitchen, Stairs, Boiler, Basement Stairway, Nursery, Youth, Blacklight, Sunday, Hall1, Storage West, and Storage East.

Understand "lights" as the light switch.

The description of the light switch is "The light switch is unobtrusive and looks exactly like every other light switch in the church."

The note of the light switch is "'I don't have much to say about the lights. Sometimes there's a problem and you have to go mess with the fuse box. But in your case it doesn't matter, because you should be leaving the lights off anyway! You're hunting a ghost!'"

Instead of switching off the light switch:

say "You can't take decent photos in the dark."

Instead of switching on the light switch:

say "The lights are already on."

Instead of turning or pushing the light switch:

if in darkness or the location is dimly lit:

try switching on the light switch;

otherwise:

try switching off the light switch.

After deciding the scope of the player when (the location is Storage West or the location is Storage East) and the west basement switch is switched off:

place the light switch in scope.

Instead of switching on the light switch when (the location is Storage West or the location is Storage East) and the west basement switch is switched off:

say "Feeling along the wall near the door, you manage to find the light switch, but nothing happens when you turn it on."

Does the player mean switching on the light switch:

it is very likely.

Does the player mean switching off the light switch:

it is very likely.

Does the player mean querying about the light switch:

it is very likely.

Does the player mean querying vaguely about the light switch:

it is very likely.

Does the player mean doing something with the light switch when chatty behavior:

it is very unlikely.

[Also, some rooms are only dimly lit, which restricts your activities there.]

A room can be dimly lit or brightly lit.

A room is usually brightly lit.

Instead of examining something when the location of the noun is dimly lit:

if the noun is the flickering lights or the noun is the ghostly figure or the noun is the glowing tissue paper or the noun is Orchid or the noun is lit or the noun is Robin or the noun is the stack of photos:

continue the action;

otherwise if the location encloses the lit black sphere:

continue the action;

otherwise:

say "It's too dark here to make out any details."

Instead of querying Casey's notes about something when the location is dimly lit:

say "There isn't enough light for you to read Casey's notes here."

Instead of consulting Casey's notes about when the location is dimly lit:

say "There isn't enough light for you to read Casey's notes here."

After photographing something with the Polaroid when the location is dimly lit:

if the noun is the original subject:

continue the action;

[otherwise we've changed the subject to "darkness"]

say "The camera hums and drops an indistinct photograph into your hand."