The Horrible Pyramid — 7 of 15

Section - Shrine

[Obviously this room is based on the Shrine of the Silver Monkey from Nickelodeon's Legends of the Hidden Temple. Implementing this puzzle in a short amount of time was actually easier than I thought it would be.]

Shrine is a room. "[if prog is 0]This room appears to be a shrine of some kind[otherwise if prog is 1]This room must be a shrine, probably[otherwise if prog is 2]You find yourself in a shrine most likely[otherwise if prog is 3]Here is Apepsikret's completely horrifying and hypnotic shrine to Sobek, the monster god of monster crocodiles, who eats ibises whole, who grins toothily upon those whom he favors upon, whose head is like unto that of a crocodile[end if].[paragraph break]Northeast: Wheel Chamber. Southeast: Graven Chamber. Southwest: Antechamber.". Shrine is northeast of Antechamber.

The spindle is here. The spindle is a supporter. The description of the spindle is "A spindle is a long straight vertical bar kind of thing."

Rule for writing a paragraph about the spindle:

if the number of things supported by the spindle is 0:

say "A long metal spindle is set into a pedestal here.";

otherwise if the number of things supported by the spindle is 3:

say "[if prog is 0]A figurine in the image of the god Sobek is mounted on top of a pedestal here[otherwise if prog is 1]The crocodile guy on the pedestal is merely a model. The real crocodile guy has got to be at least three times bigger than that[otherwise if prog is 2]On the spindle on the pedestal is an image of that famous crocodile-headed man you've heard so much about[otherwise if prog is 3]Sobek's silver statue is sitting on the pedestal, grinning toothily upon you even as I speak[end if].";

otherwise:

say "Mounted on the pedestal's spindle is [a list of thing supported by the spindle]."

Instead of taking the spindle, say "The spindle is built into the top of the pedestal."

The pedestal is scenery in Shrine. The pedestal is a closed container. Understand "chamber" as the pedestal.

Instead of taking the pedestal, say "The pedestal belongs where it is."

Instead of putting something on the pedestal:

try putting the noun on the spindle.

Instead of putting something on something supported by the spindle:

try putting the noun on the spindle.

A thing can be a monkey.

The pair of miniature silver legs is a monkey. The silver legs is in antechamber. The initial appearance of the silver legs is "A pair of miniature silver legs is lying on the floor here." The description of the silver legs is "[if prog is 0]These silver legs, apparently part of a larger figurine, have a long circular hole along the longitudinal axis[otherwise if prog is 1]There's a long hole down the middle of these silver legs[otherwise if prog is 2]These naked male legs have a hole in them, for a very good reason. The reason is so that they can go around a specific spindle[otherwise if prog is 3]The completed image of Sobek is completely complete[end if]."

The miniature silver torso is a monkey. The torso is in Wheelroom. The initial appearance of the silver torso is "A miniature silver torso is lying on the floor here." The description of the silver torso is "[if prog is 0]This silver torso, apparently part of a larger figurine, has a long circular hole along its longitudinal axis[otherwise if prog is 1]There's a long hole down the middle of this silver guy's body[otherwise if prog is 2]This naked chest and set of abs has a hole through where the spine or throat would normally be[otherwise if prog is 3]The completed image of Sobek is completely complete[end if]."

The miniature silver crocodile head is a monkey. Understand "depression" and "sobek" as the crocodile head. The crocodile head is in Canopic Chamber. The initial appearance of the miniature silver crocodile head is "A miniature silver crocodile head is lying on the floor here." The description of the the crocodile head is "[if prog is 0]There's a circular depression in the base of this silver crocodilian's jaw[otherwise if prog is 1]This is a really freaky-looking crocodile head[otherwise if prog is 2]This is either the crocodile head of Sobek, the crocodile-head god of crocodiles, or it's just the head of a regular man-eating crocodile[otherwise if prog is 3]The completed image of Sobek is completely complete[end if]."

Check putting something on the spindle:

If the noun is not a monkey:

say "[The noun] is clearly not meant to be placed there." instead;

otherwise:

if the noun is the pair of miniature silver legs:

continue the action;

otherwise if the noun is the miniature silver torso:

if the pair of miniature silver legs is supported by the spindle:

continue the action;

otherwise:

say "The torso fits around the spindle, but it clearly is meant to have something else underneath it, so you take it back." instead;

otherwise if the noun is the miniature silver crocodile head:

if the miniature silver torso is supported by the spindle:

continue the action;

otherwise:

say "The crocodile head fits around the spindle, but it clearly is meant to have something else underneath it, so you take it back." instead.

After putting something on the spindle:

if the noun is the silver legs:

say "The legs slide [if prog is greater than 1]extremely [end if][if prog is greater than 0]perfectly [end if]smoothly down the spindle and lock into place at its base.";

otherwise if the noun is the silver torso:

say "You push the silver torso down around the spindle, and it fits snugly on top of the silver legs[if prog is greater than 1], just as you always thought it would[end if].";

otherwise if the noun is the crocodile head:

say "The [if prog is 0]sinister [otherwise if prog is 1]creepy [otherwise if prog is 2]grotesque and magnificent [end if]crocodile head clicks into place above the silver torso, completing [if prog is 0]the figure of Sobek, the crocodile-headed god of the ancient Egyptians[otherwise if prog is 1]the image of a man with a crocodile head for a head[otherwise if prog is 2]the image of a crocodile-headed dude that you are both terrified of and horrified by[end if]. Something underneath the spindle creaks[if prog is greater than 0][unicode 8212]or perhaps screams in incredible pain[end if].[paragraph break]A hidden chamber opens in the pedestal, revealing a [if prog is greater than 1]disgustingly lovely [end if]golden crown.";

now the pedestal is open.

Instead of removing something from the spindle:

say "[The noun] is stuck on the spindle."

Instead of taking something that is supported by the spindle:

say "[The noun] is stuck on the spindle."

The golden crown is in the pedestal. The golden crown is wearable.

The description of the golden crown is "[if prog is 0]This golden crown, very similar to that worn by Apepsikret's queen as depicted in that engraving, looks like it would be quite heavy to wear on one's head[unicode 8212]and yet..[otherwise if prog is 1]This is a great golden crown and frankly you couldn't be happier about it[otherwise if prog is 2]You are completely in love with this golden crown, which belongs on your head just as much as any of your millions of beautiful strands of hair[otherwise if prog is 3]It is perfect for you to be wearing this crown, and you are perfect because you are wearing it, and god-king-wizard Apepsikret is pleased[end if]."