"Le butin du Capitaine Verdeterre" by Ryan Veeder


	[TC: Throughout the source, comments with indenting and starting by TC will be "Translation Comments", i.e. comments that I’m making, as per Ryan’s request, about the translation itself, comparing both languages. Enjoy :)]
	[AC: comments on my comments by the author start with AC]

	[TC: Note: I had to translate the names of the objects, because Inform uses them as recognized inputs that reference to them; however I did not translate the name of the rooms, using "the printed name of '....' is '...' instead", because rooms are everywhere in the source code, and I'd have to understand what is a region, and a room, and stuff like that (I don't code in I7). This seemed like the easiest way to do it.]

	[TC: there's a few typos throughout the code; when I could notice them, I used the word 'typo' in a comment, so look for that word to see them. Some of them are actually bugs!]
	[AC: ON THE ISSUE OF TYPOS: This is actually a lot more complicated than it should be. Sorry in advance for going on so long...
	The original competition version of the game was really buggy. For example, when you tried to walk down to a lower deck that was already completely flooded, the message saying "You can't go down there, it's flooded" would display, but then you'd walk down there anyway! I fixed that particular bug in an in-competition release, because it was embarrassing.
	But that was after a guy submitted an unthinkably high score of about $1800—a score that was only possible if you "exploited" that exact bug! I don't think the guy knew he was exploiting a bug, though; he only used it very late in the game, and I think after playing the game so many times to optimize his score he had started to ignore most of the the cosmetic messages about water level.
	I felt really lousy when I finally figured this out, because I wanted to give the guy credit for his efforts, but nobody who played the revised game could ever match that score. That's a terrible thing, to be trying to set a high score on a game when the score at the top of the leaderboards is literally impossible to reach.
	So, the leaderboard at my website has a note about how this is the high score in the old version, and this is the highest score that person, using their strategy, could reach in the current version. It's not elegant, but at least it's fair.
	Then I got an email from a guy who said he could beat the lower of those two scores, in the version where he couldn't exploit the flooded deck bug. But when I checked his solution, I realized he was exploiting yet another bug! I won't say what it is here, but it's pretty ridiculous.
	I was embarrassed again, but then I was weirdly amused. I had wanted the game to capture the feeling of speedrunning in a platformer like Super Metroid, where success depends not only on your button-pressing skills but on your ability to prioritize and optimize, and there's always the possibility that a better solution is out there. A big part of speedrunning in Super Metroid is sequence-breaking: getting the super missiles or whatever before you're supposed to, and using them to traverse areas faster or skip them entirely. I thought that element could never apply to IF, because this medium is so cut-and-dry: It's not like if you type "climb bookcase" a certain way, it'll suddenly work when it's not supposed to, and let you get to the attic faster. IF doesn't have the rough edges a platformer has.
	But apparently it does! You can "sequence break" in Verdeterre by exploiting the bug this guy found, or any number of bugs I don't even know about! I realized I had to leave that bug in, not just so that future players would have the same chances that this high-scorer had, but because I had accidentally succeeded in creating the experience I thought I could never create, of learning a game so well that you're able to out-play its programmer.
	That was a dangerous decision to make, though, because now I had to make decisions about other bugs. It's possible, and actually fairly easy, to get the "THIS SHOULDN'T HAPPEN, SEND A BUG REPORT PLEASE" message to trigger, simply by climbing the rigging. Should I do another release where I fix that, but don't fix the exploitable bug (or bugs)? And what about all these typos?
	I've thought a lot about it, and I keep changing my opinion, but for the forseeable future I've decided to leave things the way they are.]

Use MAX_VERBSPACE of 8192.
	[TC: I don't know why, but it doesn't want to compile without it. Probably because of the French library?]

Section – Note pour vous qui vous plongez dans cette source
	[TC: The pun, "source divers", is hard to translate exactly. The gist of it (relying on both meanings for ‘source’) could translate well to French since "source" also has several meanings in French ("code source" and "water source"). But several reasons make this pun impossible to translate exactly.
	First of all, I don't actually know if I've ever heard any French person refer to a source code just as a source; I think people use "source code". Secondly, we don't use "to dive in" ("plonger dans") as a synonym for "reading (avidly)" or "absorbing yourself into", but "to dive yourself in" ("se plonger dans", the reflexive form of the verb); so here we could either say "vous qui plongez dans" (simple, meaning to physically dive in) or "vous qui vous plongez dans" (reflexive, for the figure of speech); but the problem is then that making that choice weakens the pun (the best puns are series of words that you could interpret either way, but here the two interpretations correspond to two different, although close, sequences of words). Lastly, there's a gender problem: we say "un code source" (masculine since "code" is masculine) but "une source" (feminine) for the water source; the gender is going to be reflected in the pronoun, and I don't think there's a construction of this sentence that would allow us to do away with the pronoun; so again, it's going to be clumsy because we must specify a gender, and thus orient the reader.
	The right choice here, I believe, is to use the feminine pronoun ("cette"), otherwise people will miss the pun completely, and I used the "se plonger dans" because I felt the sentence was more natural. I think it's balanced, this way it might manage to evoke both.]

[Je vous remercie d'être en train de lire ce code source. Quand j'ai commencé à travailler sur ce jeu, j'ai essayé (pendant un moment) d'ajouter autant de commentaires utiles que je pouvais (le truc c'est que j'ai tendance normalement à ne pas prendre la peine de le faire). J'espérais grâce à ça en faire un texte source qui pourrait peut-être se révéler utile à ceux qui ont envie de le regarder de plus près. Cependant, je vous déconseille d'essayer d'en apprendre trop en lisant ce qui suit. Pour chacun des trucs que j'ai pu bricoler ici, il existe probablement plusieurs solutions qui sont meilleures.

"Je ne suis pas un modèle."
- Charles Barkley]

	[TC: I don't think we French speakers use the — to interrupt sentences like English speakers do, it's not as common; I used brackets, you could also use commas, but for some reason they didn't feel the same (brackets interrupt the sentence more than commas). Also, subtle differences you can notice: ", is the thing" would not sound French at all, whereas putting it at the beginning of the sentence feels really French (but maybe more proper and less laid-back than ", is the thing"; the right way to translate "prove to be useful" is "reveal to be useful"; I don't think there's a canonical way to translate "peruse" (which, I think, means "to look really close, slowly, at something" instead of the opposite, but is used as the latter often? If I recall correctly?), so I just used "to look closer at"; reversed the structure of the last sentence because the middle was kinda hard to translate if I wanted to keep it natural (I have to use "for each" instead of "for everything", and the "superior solutions" is a tricky and fragile thing to translate - we can't use "superior" in French, that's weird, so "better", then "mieux", but we don't use it like that, we'd use "meilleur", which actually means "best"... aaah!).]

Section - CREDITS et A PROPOS et SOLUTION

Abouting is an action out of world. Understand "credits" and "auteur" and "a propos" and "info" and "contact" and "remerciements" and "menu" as abouting.
	[TC: added "thanks" and "menu", because that's what I usually put as synonyms for my own games]

Carry out abouting (this is the about rule):
	say "[italic type]{Merci à vous de jouer à [roman type]Le butin du Capitaine Verdeterre.[italic type] Vous jouez actuellement à la première version du jeu, écrite pour participer à l[']édition 2013 de l'Interactive Fiction Competition.[paragraph break]L'auteur souhaite remercier son père; la série des Aubrey-Maturin de Patrick O'Brian; et l'exemplaire, appartenant à son père, du livre de Dean King qui accompagne les romans de Patrick O'Brian, [roman type]A Sea of Words[italic type], dans cet ordre, pour l'inspiration et les informations qu'ils m'ont fourni pendant la création de ce jeu.[paragraph break]De plus l'auteur souhaite remercier les bêta-testeurs, Emily Boegheim, qui m'aida aussi pour la programmation, Colin Djukic, et bien entendu Zach, qui a aidé substantiellement à équilibrer certains éléments du jeu.[paragraph break]Je dois des remerciements spéciaux à Caitlyn Harris, qui a créé la couverture de ce jeu. Vous pouvez admirer son travail à l'adresse [roman type]caitlynharris.com[italic type] et regarder sa boutique sur Etsy.[paragraph break]Enfin, l'auteur souhaite vous remercier encore une fois de jouer à son jeu qui, comme toute expression artistique, n'existe pas véritablement sans être mis à l'épreuve de son public. Si vous voulez envoyer votre Score Final à l'auteur ou simplement le contacter, vous pouvez lui envoyer un email à [roman type]rcveeder@me.com[italic type], ou sinon dire bonjour sur Twitter, où son pseudo est [roman type]@rcveeder[italic type]. Il a hâte que vous entriez en contact avec lui.}[roman type][paragraph break]"


Table of Final Question Options (continued)
final question wording	only if victorious	topic	final response rule	final response activity
"en savoir plus A PROPOS du jeu"	false	"about"	about rule	--



Helping is an action out of world. Understand "aide" and "astuce" and "astuces" and "solution" as helping.

Carry out helping:
	let N be the number of valuable things;
	let M be N plus 2;
	say "[italic type]{Pour des raisons de complétude voici une 'solution' triviale pour ce jeu: [paragraph break]>ALLER VERS LA POUPE[line break]>MONTER[line break]>MONTER[line break]>ALLER VERS LA PROUE[line break]>ALLER VERS LA PROUE[line break]>ENTRER CANOT SAUVETAGE[line break]>OUI[paragraph break]Suivre ce chemin ne récompensera pas le joueur avec une fin très satisfaisante. Il existe une suite de commande qui aura pour résultat que Verdeterre et Tibert acquièreront une fortune maximale. L'auteur ne connaît pas cette suite de commandes.[paragraph break]Cependant, l'auteur espère que des joueurs intelligents et méticuleux raffineront leur manière de jouer jusqu'à ce que le chemin optimal soit découvert. Si vous pensez avoir atteint le 'score[quotation mark] le plus haut, merci d'envoyer un transcript de votre session de jeu à l'auteur, à l'adresse [roman type]rcveeder@me.com[italic type]. Il a hâte que vous entriez en contact avec lui.}[roman type][paragraph break]"

Section - ENNUYEUX

[CETTE SECTION EST ENNUYEUSE]

Include French by Eric Forgeot.  
  Use French Language and serial comma.

The story headline is "Un compte-rendu du naufrage de l[']Incapable".

Release along with cover art and a website and an interpreter and the source text.

The story description is "Porter ce sac, je crois que c'est plutôt votre rôle. Moi, je délègue les tâches."
	[TC: here, I wanted something that sounded good, so I had to change the order of the words. I changed the "You should carry the bag" in something more like "I think carrying the bag is your role, not mine", to emphasize the slightly bossy ("delegator") aspect, and also kinda transfer meaning from the second sentence that I couldn't really translate there (the "i'm more of a", i.e. "i'd rather delegate" or something like that, is kind of awkward to put in the second sentence in French, I find, whereas if I put "I think it's your role" it still emphasizes the "I assign duties and it's all good like this" aspect). I don't know if you see what I mean. I hope it works.]

Include Basic Screen Effects by Emily Short. [Mis à part l'ajout de la fonctionalité "Appuyez sur une touche pour continuer", cette extension ajoute aussi des effets sympas pour la barre de statut.]
Include Directions Nautiques by Samuel Byron. [C'est ça qui fait marcher "proue" et "poupe".]

Use shipboard directions. [Ceci désactive les directions cardinales, mais il reste toujours haut et bas.]

Index map with poupe mapped as east. Index map with proue mapped as west. Index map with up mapped as north. Index map with down mapped as south. [Ceci fait de la carte générée par Inform (la carte que j'ai le droit de voir, mais pas vous) une vue en coupe du bateau, comme cette séquence dans "La Vie Aquatique".]

Section - Quelques verbes mineurs

[Le booléen "going nowhere" est défini ci-dessous. En gros, il arrête la progression du temps pour un petit moment. CETTE PARTIE EST TOUJOURS ENNUYEUSE, HEIN.]

Instead of singing:
	say "'Au clair de la lune, lala, truc truc...' Hmm.";
	now the going nowhere boolean is true.
	[TC: so the original is "Au clair de la lune", which is a French song in an English game, so maybe I should have changed that to an English song in a French game. However, I couldn't find an equivalent of Au Clair De La Lune, i.e. an English "kid"/simple song that would be known to French speakers, and also within the same historical frame (I don't know if there's any set in the game, something vaguely old maybe, so I can't really have them sing Ke$ha. Unless you want me to.)]

Understand "danser" as a mistake ("Mais vous devez vous abstenir ! Vos pas fébriles n'auraient pour conséquence qu'accroître la dégradation de l'intégrité de ce vaisseau, qui n'est plus aussi fier et noble qu'il ne l[']était.").
	[TC: "once-proud" is kinda hard to translate. (English seems more flexible than French, as a general rule.) I translated it as "it's not as proud and noble [noble cause it sounded more like an adjective we'd use for proud, big, beautiful vessels, so I just threw it in there] as it once was.]

Instead of attacking something:
	say "Ca n'est pas le moment de faire du chahut ou se chamailler.";
	now the going nowhere boolean is true.

Instead of kissing something:
	say "Apparemment, vous n'avez pas regardé de quoi vos dents ont l'air depuis un petit moment.";
	now the going nowhere boolean is true.

Instead of jumping:
	say "Vous ne devriez pas sauter sur place sur un navire qui coule. Ca porte la poisse.";
	now the going nowhere boolean is true.
	
Understand "sauter du bateau" as a mistake ("Vous ne devriez pas penser à des choses comme ça. Vous seriez réduits en morceaux par les récifs, ou les requins, et après le capitaine n'aurait plus aucune partie de vous à pendre pour avoir déserté.").

Leaving is an action applying to nothing. Understand "abandonner navire" as leaving.

Instead of leaving:
	if the canot de sauvetage is in the location:
		try entering the canot de sauvetage;
	otherwise:
		now the going nowhere boolean is true;
		say "C'est à ça que sert un canot de sauvetage."

Instead of tasting:
	say "Pas la peine. Après votre petit déjeuner de ce matin, tout a goût d'algues bouillies.";
	now the going nowhere boolean is true.

Instead of smelling:
	say "Du sel."
	
Instead of smelling something:
	say "Vous ne sentez rien de particulier."

Instead of thinking:
	say "Le Capitaine Verdeterre dit toujours que c'est lui qui réfléchit, pas vous.";
	now the going nowhere boolean is true.
	[TC: "leave the thinking to him" is hard to translate, because in French we have the same word for "leave" and "let", and thus the corresponding sentence structure would mean more "let him think", which is not right. So I said "he's the one who thinks, not you".]

Instead of waking up:
	say "C'est vrai que c'est trop beau pour être vrai, n'est-ce pas ?";
	now the going nowhere boolean is true.
	
Instead of sleeping:
	say "Ca n'est pas le moment ! Vous dormirez quand vous serez mort, comme dit toujours le Capitaine.";
	now the going nowhere boolean is true.

Understand "prier" as a mistake ("A ce que je vois, il n'y a pas d'athées pendant un naufrage.").

Understand "utiliser [text]" as a mistake ("[italic type]{C'est certes regrettable, mais ce divertissement interactif n'est pas capable de faire une supposition, aussi basique qu'elle puisse être, sur le sens que vous voulez mettre derrière le mot 'utiliser'. Avec nos excuses les plus plates, nous vous demandons humblement de reformuler votre requête en utilisant un verbe plus spécifique.}[roman type]").

Instead of pushing something:
	say "C'est bien là où c'est.";
	now the going nowhere boolean is true.

Instead of pulling something:
	say "C'est bien là où c'est.";
	now the going nowhere boolean is true;

Instead of turning something:
	say "[italic type]{On demande poliment que vous respectiez l'orientation de [the noun].}[roman type][paragraph break]";
	now the going nowhere boolean is true.

Before taking something which is carried by the player:
	say "Vous l'avez déjà.";
	now the going nowhere boolean is true.

Before inserting something which is not carried by the player into something:
	if the noun is in the second noun, say "C'est déjà là-dedans." instead;
	say "Vous prenez d'abord [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

Before putting something which is not carried by the player on something:
	if the noun is on the second noun, say "C'est déjà dessus." instead;
	say "Vous prenez d'abord [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

Before wearing something which is not carried by the player:
	if the player is wearing the noun, say "Vous portez déjà cela." instead;
	say "Vous prenez d'abord [the noun].[line break]";
	silently try taking the noun;
	if the player is not holding the noun, stop the action.

Thanking is an action applying to nothing. Understand "super" or "ok" or "okay" or "genial" or "extra" or "bien" or "youpi" or "hourra" or "merci" or "merci beaucoup" as thanking.

Carry out thanking:
	say "[italic type]{De rien.}[roman type][paragraph break]";
	now the going nowhere boolean is true;

Expressing displeasure is an action applying to nothing. Understand "zut" or "crotte" or "saperlotte" or "mince" or "merde" or "saperlipopette" or "oh" or "oh non" or "roh" or "ta gueule" or "tais toi" or "argh" or "arf" as expressing displeasure.

Instead of swearing mildly, try expressing displeasure.

Instead of swearing obscenely, try expressing displeasure.

Carry out expressing displeasure:
	say "[italic type]{Veuillez nous excuser pour les désagréments encourus.}[roman type][paragraph break]";
	now the going nowhere boolean is true;

Instead of saying sorry:
	now the going nowhere boolean is true;
	say "[italic type]{J'accepte vos excuses.}[roman type][paragraph break]"

Understand "escaliers" as a mistake ("Vous ne pouvez pas vous déplacer dans cette direction de là où vous êtes. [italic type]{Les directions disponibles sont données dans la barre de status ci-dessus.}[roman type]") [Ceci est sous-optimal.]

Understand "laver" as a mistake ("C'est bizarre. Où sont donc passées les serpillères pour laver le pont ?").
	[TC: it's a pun, right? I didn't really understand what Q-tips were doing in such a game, but I understand it's both a mop you use to mop the boat's deck, and the lowest echelon of sailors. In French, this would be "mousse", which is "foam" (presumably for the foam they leave on the deck? I have no idea). Translating this pun,  I think, is impossible. My solution: 'where are the "mousses" who usually make the deck foam?', which is kinda ugly... I'll delete the attempt at a pun if you want me to.]
	[AC: The intention behind the joke about 'where are the swabs?' is just that the equipment for swabbing the deck is mysteriously missing, because I didn't feel like implementing it. I guess it's less of a joke and more of an attempt to discourage you from trying to clean anything. I think a straight translation would be fine here.]

Understand "laver [text]" as a mistake ("C'est bizarre. Où sont donc passées les serpillères pour laver le pont ?").

Understand "lever [text]" as a mistake ("Ca ne sert à rien de lever quoi que ce soit maintenant.").

Understand "nager" as a mistake ("Vous ne savez pas comment.").

Understand "nager [text]" as a mistake ("Vous ne savez pas nager.").

Understand "retourner [something]" as turning.

Section -  L'action de comptage

[J'ai écrit une blague pour quand vous comptez quelque chose, mais je me suis ensuite aperçu que compter n'est pas un verbe présent par défaut dans Inform ! POURQUOI PAS, telle est ma question. Bon, j'ai un peu de temps libre en ce moment, alors je vais essayer.]

Counting is an action applying to one thing. Understand "compter [something]" and "énumérer [something]" and "calculer [something]" and "dénombrer [something]" as counting.

An object has some text called the countingtext. [Ca pourrait être 'le nombre', mais je suis presque sûr que ça rendrait les choses plus confuses.]

Instead of counting:
	If the countingtext of the noun is "":
		say "[The noun] n'est là qu'en un exemplaire.";
	[TC: hard to find a gender-neutral way to say this in French, hopefully the result isn't too ugly.]
		now the going nowhere boolean is true;
	otherwise:
		say "[the countingtext of the noun]."
		
[A présent je peux donner un countingtext spécial pour tout objet que je décide pluriel, et ne pas me préoccuper de tout autre objet présent en un seul exemplaire. Peut-être qu'il y aura des cas limites à la noix, mais de toute façon qui va s'amuser à compter des objets ?]
	[TC: "a few stupid corner cases" - did you know that a translation of "stupid" that kinda works in that case is the (a bit slangy) "à la noix"? It means something like "nut-like" or "with nuts" or something like that. Wiktionary says the expression was created by a famous writer/songwriter of the early 1900s, based on the connotation that nuts weren't worth much (and by association, the object to which "à la noix" is attached too). I did not know that. Yay translating!]

Volume - Les systèmes et ce genre de trucs

Part - Une jolie barre de statut, adaptée de celle dans Bronze

[Ici, "adaptée" veut dire "volée". Mais je doute qu'Emily en prenne ombrage. Je l'ai dépouillée un petit peu, et j'ai changé la perspective pour que ça soit une vue en coupe au lieu d'une vue de haut en bas. J'espère que ça permettra aux gens de visualiser l'espace de jeu comme était la vue en coupe d'un bateau, comme dans cette séquence du film La Vie Aquatique.]


Table of Fancy Status
left	central	right
" [location]"	""	"[top rose]"
" "	""	"[middle rose]"
" Trésors: [number of valuable things enclosed by the player]"	""	"[bottom rose]"

To say top rose:
	say "     ";
	let place be the room up from the location;
	if place is a room, say "HAUT         "; otherwise say "     ".

To say middle rose:
	let place be the room proue from the location;
	if place is a room, say "PROUE "; otherwise say "     ";
	say "+";
	let place be the room poupe from the location;
	if place is a room, say " POUPE"; otherwise say "    ".

To say bottom rose:
	say "    ";
	let place be the room down from the location;
	if place is a room, say "BAS     "; otherwise say "      ".

Rule for constructing the status line:
	if Aready is true:
		fill status bar with Table of Fancy Status;
	otherwise:
		say ""
['Aready' est une valeur de vérité qui changera juste après que la scène d'exposition soit finie et que le jeu commence ; sinon, le joli statut apparaîtrait par-dessus le texte d'introduction, et je ne veux pas que ça arrive.]

Part - Trésors et score à la fin du jeu

Section - les bases du système

Use no scoring. [Bien sûr, il y a un "score", mais je préfère le faire A MA FACON]

An object can be valuable.

An object has a number called worth. The worth of an object is usually 0. [Même les objets sans valeur ont une variable "valeur", ce qui est important car certains objets commencent par ne pas avoir de valeur mais peuvent en obtenir plus tard.]

An object has some text called appraisal. [Nous verrons que ce texte apparaît quand on fait la liste de l'inventaire final, à la fin du jeu.]




A thing can be sacked. A thing is usually not sacked. [Ca a l'air d'être une règle débile, mais je pense que ça rend les choses plus faciles pour le joueur. La raison d'être du sac, c'est d'éviter d'avoir l'image mentale de Tibert portant plus de 20 bibelots dans ses bras en marchant (et on ne veut pas faire perdre des tours au joueur en le forçant à mettre les objets dans le sac), donc on veut que les objets intéressants aillent directement dans le sac. Mais on ne veut pas non plus imposer des restrictions embêtantes sur la façon d'interagir avec des objets tout ça parce qu'ils sont dans le sac. Avec l'attribut 'sacked', on met les items dans le sac au départ, mais après ça ils peuvent bouger comme ils veulent.

J'ai essayé des trucs honteusement nuls avant de trouver cette solution.]

After taking something valuable:
	if the noun is not sacked:
		say "Vous mettez [the noun] dans le sac.";
		silently try inserting the noun into the sac;
		now the noun is sacked;
	otherwise:
		say "Ok."


Check inserting something valuable into something:
	if the second noun is the sac volumineux:
		continue the action;
	otherwise if the second noun is the canot de sauvetage:
		say "Peut-être que vous devriez d'abord penser à votre propre sûreté.";
	otherwise:
		say "Si vous laissez quelque chose ici, vous courez le risque de ne plus jamais le retrouver." instead.

Check putting something valuable on something:
	say "Si vous laissez des objets traîner, vous courez le risque de complètement oublier leur existence." instead.

Check dropping something valuable:
	say "Si vous laissez des objets traîner, vous courez le risque de complètement oublier leur existence." instead.



Section - Quand le jeu finit

The total haul is a number that varies. The total haul is 0.

Instead of entering the canot de sauvetage:
	say "Etes-vous sûr de vouloir abandonner le navire ? [bracket]o/n[close bracket][paragraph break]> ";
	if the player consents:
		now Aready is false;
		now the pâté gris musqué is valuable;
		if the pistolet à silex is contained by the sac volumineux:
			now the pistolet à silex is valuable;
		say "Vous prenez les jambes à votre cou.[paragraph break]***[paragraph break]";
		wait for any key;
		if the number of valuable things enclosed by the player is 0:
			say "'Bon,' dit le Capitaine Verdeterre en se frottant les pattes. 'Voyons ce que nous avons là.'[paragraph break]Vous ouvrez le sac pour que le capitaine puisse y farfouiller, et vous trouvez : [a list of things contained by the sac volumineux].[paragraph break]Le Capitaine Verdeterre lève les yeux vers vous. Les flammes de l'Enfer brûlent dans ses yeux.[paragraph break]'Mes bras sont trop courts pour tenir les rames,' siffle-t-il, 'alors c'est toi qui rame. Mais quand nous arriverons sur la terre ferme...'[paragraph break]Il prend une grande respiration. Vous saisissez les rames.[paragraph break]'...Quand nous arriverons sur la terre ferme, je vais sincèrement, sérieusement, littéralement te  tuer.'[paragraph break]Vous hochez la tête et continuez à ramer pendant que derrière vous, l['][italic type]Incapable[roman type] est englouti par les vagues.";
			end the story saying "{Vous aurez plus de chance la prochaine fois.}";
		otherwise if the number of valuable things enclosed by the player is 1:
			let the loot be a random valuable thing enclosed by the player;
			let N be the worth of the loot;
			say "'Alors, qu'est-on arrivé à grappiller?' demande le Capitaine Verdeterre. Vous sortez [the loot] et lui montrez.[paragraph break]'C'est tout ? Ouah, tu as fait encore pire que ce que je pensais. Voyons voir.'[paragraph break]Il inspecte [the loot] pendant un moment, tout en fronçant les sourcils d'un air concentré.[paragraph break]'[if N is greater than 150]En fait, ça pourrait avoir de la valeur. Tu aurais pu mieux faire, mais bon. Allez, d'accord[otherwise]Ouais, ça ne vaut rien. On va mourir de faim[end if].'[paragraph break]Vous continuez à ramer pendant que derrière vous, l['][italic type]Incapable[roman type] est englouti par les vagues.";
			end the story saying "{Vous aurez plus de chance la prochaine fois.}";
		otherwise:
			say "Le retour à la civilisation était long, mais vous avez tous deux survécu, et il fallut alors entreprendre la longue tâche de liquidation de vos possessions. A présent, après avoir traité avec de nombreux acheteurs louches, des pigeons et quelques véritables hommes d'affaire, vous faites la liste de vos trésors inestimables et de combien ils se sont avérés valoir :[paragraph break]";
			repeat with item running through valuable things enclosed by the player:
				say "[the appraisal of the item][line break]";
				increase the total haul by the worth of the item;
			say "[line break]...Pour un total de [the total haul] dollars espagnol[if the total haul is 1][otherwise]s[end if].[paragraph break]";
			let N be the total haul divided by 16;
			let O be the remainder after dividing the total haul by 16;
			let P be O divided by 2;
			say "La part du second est d[if N is 1]'un dollar espagnol[otherwise]e [N] dollars espagnols[end if][if P is 1] et un réal[otherwise if P is greater than 1] et [P] réals[end if].[paragraph break]***[paragraph break]";
			wait for any key;
			if the total haul is less than 300:
				say "Le Capitaine Verdeterre regarde ses calculs d'un oeil de reproche. 'Ca n'est pas beaucoup d'argent', observe-t-il.[paragraph break]Il lève les yeux vers vous. 'C'est vraiment un tout petit peu d'argent. Ce qui, sans vouloir t'offenser, est à peu près ce à quoi je m'attendais. Mais, quand même. Ca va nous prendre du temps pour retomber sur nos pieds.'[paragraph break]Il trottine vers la fenêtre et considère la ville sous ses pieds. 'J'ai besoin que tu sortes et que tu ailles recruter des matelots. Je serai ici, en train de concocter un plan pour nous trouver un nouveau navire. Tu devrais recruter n'importe qui, mais essaie tout de même de nous trouver au moins un bon matelot. Je vais avoir besoin d'un nouveau second.'[paragraph break]Il vous regarde droit dans les yeux, pour être sûr que vous ayez bien compris. 'Alors, peut-être qu'il faut que tu te mettes au travail ?'";
				end the story saying "{Vous aurez plus de chance la prochaine fois.}";
			otherwise if the total haul is less than 600:
				say "Le Capitaine Verdeterre a le menton posé sur sa patte, et ses yeux sont entrouverts, en pleine réflexion.[paragraph break]'Je pense...'[paragraph break]Au dehors, la ville est silencieuse, et vous n'entendez que le faible bruitde la pluie qui tombe sur les fenêtres.[paragraph break]'Je pense que ça ira. Oui. On ne va pas mourir de faim.'[paragraph break]Enfin, vous pouvez resprirer. Verdeterre ouvre ses yeux et vous sourit.[paragraph break]'Ne t'en fais pas. Tu as fait du mieux que tu pouvais, n'est-ce pas ? J'ai l'impression que c'est le mieux que tu pouvais faire. Alors détends-toi ! Prends donc une chaise !'[paragraph break]Il n'y a qu'une seule chaise dans l'appartement, par contre, et le Capitaine Verdeterre y est assis dessus, alors vous hochez la tête poliment et restez debout pendant qu'il se recroqueville sur lui-même et s'endort.";
				end the story saying "{Félicitations pour ce succès.}";
			otherwise if the total haul is less than [le score maximal (parmi les bêta-testeurs) à l'heure de l'écriture de ce texte]818:
				say "Vous et le Capitaine avez tout deux fait une folie et acheté des nouveaux manteaux, et tous les deux vous attirez les regards lorsque vous marchez dans la rue.[paragraph break]'Franchement, je pense qu'on peut prendre des vacances,' dit Verdeterre. 'On a assez d'argent pour vivre pendant un moment, et quelque chose se présentera avant que l'on n'en ait plus. De nouvelles opportunités se présentent constamment à moi.'[paragraph break]Il vous regarde d'un air approbateur. 'Comme toi. Je n'étais pas forcé de t'engager, mais je l'ai fait, et apparemment ça a plutôt bien marché.' Il sourit. 'Je doute que tu aurais pu faire mieux,' dit-il, 'vraiment, je suis sincère.'";
				end the story saying "{Félicitations pour ce succès.}";
			otherwise:
				say "Le Capitaine Verdeterre ferme les yeux et soupire d'aise, bruyamment, tout en se roulant dans sa pile de pièces. 'On l'a fait,' soupire-t-il. 'Ils disaient qu'on ne pourrait pas le faire, mais on leur a bien montré. On l'a complètement fait.'[paragraph break]'C'est qui, eux ?' demandez-vous.[paragraph break]'La ferme,' répond Verdeterre sèchement. Et puis ses yeux s'ouvrent, et il accourt vers vous avec une expression que vous n'avez pas l'habitude de voir.[paragraph break]'Je suis désolé,' dit-il. 'Je n'aurais pas dû te crier dessus comme ça. Je te dois tout ça. Enfin, je te dois beaucoup de tout ça. Mais je ne t'ai jamais remercié.'[paragraph break]Il pose sa patte sur votre main. 'Merci, Tibert. Merci d'avoir rejoint mon équipage. Merci de ne pas m'avoir abandonné comme tous les autres enflures que j'avais engagé. Et merci de m'avoir rendu si incroyablement riche.'[paragraph break]Vous ne savez pas quoi dire. Verdeterre se retourne et regarde son argent à nouveau.[paragraph break]'Ouais. Oui,' dit-il. 'Je vais m'acheter un ours polaire.'";
				end the story saying "{Félicitations ! Votre score est un nouveau record !}";
	otherwise:
		say "Finissez, alors."
		
[

Section - Peut-être un score maximal sauvegardé pour vous

File of Leaderboard is called "yourhighscore".

When play begins:
	if the File of Leaderboard exists:
		read File of Leaderboard into the Table of Leaders;

When play ends:
	choose row 1 in the Table of Leaders;
	if the total haul is greater than scored amount entry:
		now the scored amount entry is the total haul;
	show leaderboard;
	write the File of Leaderboard from the Table of Leaders.

To show leaderboard:
	sort the Table of Leaders in reverse scored amount order;
	say "Tableau des scores : [paragraph break]";
	say fixed letter spacing;
	repeat through Table of Leaders:
		if scored amount entry is greater than 0:
			say "  [name entry]";
			let N be 25 minus the number of characters in name entry; [ici on veut que les scores forment une colonne claire et propre, en utilisant des espaces]
			if N is less than 1, now N is 1;
			say N spaces;
			say "[scored amount entry][line break]";
	say variable letter spacing.

To say (N - a number) spaces:
	repeat with index running from 1 to N:
		say " ".

Table of Leaders
scored amount
0

]








Part - Comment faire pour que le bateau soit toujours en train de couler

Section - déterminer si le bateau doit couler ce tour-ci

[J'ai dû essayer beaucoup de méthodes différentes pour empêcher la séquence où le bateau coule de se déclencher quand le joueur allait dans une mauvaise direction. Au final j'ai eu recours à un booléen "going nowhere" (n'aller nulle part), même si c'était vraiment inélégant.

Par contre, maintenant, je l'aime bien ! Je l'aime bien parce que, à mesure que je commençai à coder du contenu plus spécifique et à trouver des exceptions, je me suis aperçu que je pouvais désigner n'importe quelle action comme une "action gratuite" en les faisant activer le booléen "going nowhere". Ceci s'appelle la "généralisabilité" dans le monde des programmeurs cools et c'est considéré comme très désirable.]

The going nowhere boolean is a truth state variable. The going nowhere boolean is false.

Instead of going nowhere:
	now the going nowhere boolean is true;
	say "Vous ne pouvez pas vous déplacer dans cette direction depuis ici. [italic type]{Les directions disponibles sont affichées dans la barre de statut ci-dessus.}[roman type][paragraph break]".

Instead of going babord:
	say "Bouger vers le côté gauche [if the location is in zeus]de la hune[otherwise]du pont[end if] n'a pour effet que de faire tanguer le navire d'une façon inquiétante[if the nautical vocabulary notes boolean is true][italic type]. {Note de vocabulaire nautique: 'babord' désigne le côté gauche du bateau.}[roman type][paragraph break][otherwise].[end if]";
	now the going nowhere boolean is true;
	
Instead of going tribord:
	say "Bouger vers le côté droit [if the location is in zeus]de la hune[otherwise]du pont[end if] n'a pour effet que de faire tanguer le navire d'une façon inquiétante[if the nautical vocabulary notes boolean is true][italic type]. {Note de vocabulaire nautique: 'tribord' désigne le côté droit du bateau.[roman type][paragraph break][otherwise].[end if]";
	now the going nowhere boolean is true.

Every turn (this is the shipwreck deciding rule):
	if the current action is looking or examining or taking inventory:
		rule succeeds;
	if the going nowhere boolean is true:
		now the going nowhere boolean is false;
		rule succeeds;
	otherwise:
		follow the shipwrecking rules.

Shipwrecking rules is a rulebook.

Section - Niveau relatif et absolu d'eau

[Quand vous êtes à un niveau du bateau, le fait de pouvoir ou non interagir avec des objets, ou respirer, dépend de si le niveau de l'eau a atteint ce niveau et à quel point il est eau. Je peux utiliser le 'niveau relatif d'eau' plus tard quand je dois m'occuper de décider si un objet est perdu dans l'eau.]

[Vous remarquerez plus tard que je ne fais référence qu'au niveau relatif d'eau. C'est peut-être la mauvaise façon d'approcher les choses, même si dans la majorité des cas il n'y a pas de grande différence. Enfin bref.]

The water level is a number that varies. The water level is 0.

The relative water level is a number that varies. The relative water level is 0.

A shipwrecking rule (this is the constantly rising water rule):
	increase the water level by 1;
	if the water level is greater than 12:
		let N be the remainder after dividing the water level by 13;
		now the relative water level is N;
	otherwise:
		let N be the water level;
		now the relative water level is N;
			

Section - Parfois Vous Mourrez Car Il Y A Trop D'Eau

The currently sinking deck is a region that varies.
	
When play begins:
	now the currently sinking deck is hold;
	now the eau is in hold.

A region can be abovewater or underwater. A region is usually abovewater.

A shipwrecking rule (this is the decks go underwater rule):
	if the relative water level is 0:
		now the currently sinking deck is underwater;
		if the currently sinking deck is overdecks:
			now the currently sinking deck is zeus;
			now the eau is in zeus;
		otherwise if the currently sinking deck is maindeck:
			now the currently sinking deck is overdecks;
			now the eau is in overdecks;
		otherwise if the currently sinking deck is lowerdeck:
			now the currently sinking deck is maindeck;
			now the eau is in maindeck;
		otherwise if the currently sinking deck is hold:
			now the currently sinking deck is lowerdeck;
			now the eau is in lowerdeck.

[CECI est très verbeux et aurait dû être fait avec un tableau, mais je n'arrivais pas à faire marcher le tableau, alors c'est comme ça à la place. Un peu plus tard je me suis rendu compte que je pourrais peut-être le faire avec une relation. Mais cette façon de faire marche, alors, c'est bon.]

Before going to a room (called destination) (this is the avoid flooded or nearly flooded rooms rule):
	if the destination is in the currently sinking deck:
		if the relative water level is greater than 10:
			if the location is in the currently sinking deck:
				continue the action;
			otherwise:
				say "Il est trop tard pour revenir en bas maintenant. Le pont est presque complètement inondé.";
				reject the player's command;
				now the going nowhere boolean is true;
	otherwise if the destination is in an underwater region:
		say "Il est trop tard pour revenir en bas maintenant. Le pont au dessous est complètement inondé.";
		now the going nowhere boolean is true;
		reject the player's command.

The avoid flooded or nearly flooded rooms rule is listed first in the shipwrecking rules.

A shipwrecking rule (this is the you die of drowning rule):
	if the player is in a room in an underwater region:
		say "Vous ne pouvez plus retenir votre respiration plus longtemps, et maintenant l'eau s'introduit dans votre bouche et vos narines. Vous parvenez à lutter quelques instants, mais ça n'est pas la peine[if capitaine verdeterre is in the location].[paragraph break]Par contre, on dirait que le Capitaine est un nageur plutôt bon, et il s'éloigne en brasse sans vous[end if].";
		end the game saying "Vous vous êtes noyé."

Section - Donner les indices que vous êtes en train de couler

A shipwrecking rule (This is the clue delivery rule):
	let N be the relative water level plus 1;
	if the currently sinking deck is Maindeck:
		if the location is in overdecks or the location is in zeus:
			choose row N in the Table of Remote Maindeck Clues;
			say "[clue entry][paragraph break]";
		otherwise if the location is in maindeck:
			choose row N in the Table of Maindeck Clues;
			say "[clue entry][paragraph break]";			
	otherwise if the location is in the currently sinking deck:
		if the currently sinking deck is overdecks:
			choose row N in the Table of Overdecks Clues;
			say "[clue entry][paragraph break]";
		otherwise if the currently sinking deck is zeus:
			choose row N in the Table of Zeus Clues;
			say "[clue entry][paragraph break]";
		otherwise if the currently sinking deck is lowerdeck or the currently sinking deck is hold:
			choose row N in the Table of Belowdecks Clues;
			say "[clue entry][paragraph break]";
	otherwise if the currently sinking deck is overdecks:
		if the location is in zeus:
			choose row N in the Table of Remote Overdecks Clues;
			say "[clue entry][paragraph break]";

[Il y a probablement une façon plus gracieuse de faire ça, qui utilise un seul tableau - ou en tout cas moins de six tableaux. J'ai choisi cette méthode simplement pour rendre les textes d'indices plus faciles à lire et à modifier dans l'éditeur Inform.]	

Table of Remote Maindeck Clues
clue
"Vous remarques que l'eau commence juste à déborder sur le pont principal."
"L'eau continue à s'élever sur le pont principal."
"Le pont principal continue à couler."
"Il doit y avoir à peu près trente centimètres d'eau sur le pont principal maintenant."
"Le pont au dessous est toujours en train de couler."
"Maintenant le pont principal est sous environ un mètre d'eau."
"La mer continue de submerger le pont principal, se rapprochant de vous."
"Bientôt il y aura trop d'eau sur le pont principal pour que vous puissiez y marcher dessus."
"Le pont principal doit être sous un peu moins de deux mètres d'eau maintenant."
"Vous n'avez bientôt plus une chance de pouvoir revenir sur le pont principal."
"Les flots continuent à submerger le pont principal."
"Le niveau de l'eau a presque atteint le niveau des châteaux avant."
"Le pont principal est irrémédiablement perdu, et l'eau commence à monter sur le château avant et la plage arrière..."
	[TC: nautical terms galore! My only experience with nautical terms is an old map of a Caravel that I somehow have imprinted in my brain since age 9. So that was tricky! "Fo'c'sle" is easily translated by "château avant"; as for "quarterdeck", the correct translation seems to be "plage arrière"; the main deck is a "pont principal", but also "pont supérieur", which can be confused with the upper decks (and 'upper decks' don't seem to have a nice translation); thus I use 'pont principal'.]

Table of Maindeck Clues
clue
"L'eau roule sur le pont et atteint rapidement vos chevilles."
"Maintenant l'eau atteint vos tibias."
"Vos genoux sont maintenant sous l'eau."
"L'eau monte à vos cuisses."
"Maintenant l'eau atteint vos hanches."
"Les flots montants arrivent à votre taille."
"L'eau vous arrive à la poitrine."
"Les vagues vous recouvrent les épaules."
"L'eau atteint votre menton. Vous avez du mal à garder les pieds au sol."
"L'eau est dans votre bouche maintenant[if a random chance of one in three succeeds]. C'est salé[end if]."
"Vous avez du mal à garder votre tête hors de l'eau."
"Vous avez du mal à voir où vous allez, car vous avez les yeux fermés pour éviter l'eau salée dans vos yeux. Il vous faut aller plus haut."
"L'eau recouvre votre tête. Qu'est-ce qui vous plairait pour la dernière action de votre vie ?"
	[TC: is there a typo in "what would your like"? I translated it as "what would be your pleasure for...", which I think has the equivalent meaning regardless of whether there's a typo or not.]
	[AC: it is a typo.]

Table of Remote Overdecks Clues
clue
"Vous remarquez que les flots ont commencé à recouvrir la plage arrière et le château avant. Il n'y a plus aucune chance que vous puissiez retourner sur le pont principal à présent."
"L'eau continue à monter en contrebas, sur le château avant et la plage arrière."
"Le navire continue de couler."
"Il doit y avoir environ trente centimètres d'eau sur le château avant et la plage arrière à présent."
"Le château avant en dessous de vous est en train de couler."
"Maintenant la plage arrière est sous environ un mètre d'eau."
"La mer continue de submerger le château avant, se rapprochant de vous."
"Il vous vient à l'esprit que vous allez mourir ici."
"La plage arrière doit être sous un peu moins de deux mètres d'eau à présent."
"Le château avant est presque recouvert."
"Les flots continuent de monter."
"L'eau qui monte atteint presque le niveau de la hune."
"Le château avant et la plage arrière sont irrémédiablement perdus maintenant, et l'eau commence à monter sur les planches de la hune..."
	[TC: "the upper decks" cannot be easily translated, so I switched between the fo'c'sle and the quarterdeck.]

Table of Overdecks Clues
clue
"L'eau recouvre le sommet [if the location is fo'c'sle]du château avant[otherwise]de la plage arrière[end if] et vous arrive aux chevilles. Vous allez mourir ici."
"L'eau roule sur le pont et atteint rapidement vos chevilles."
"Maintenant l'eau atteint vos tibias."
"Vos genoux sont maintenant sous l'eau."
"L'eau monte à vos cuisses."
"Maintenant l'eau atteint vos hanches."
"Les flots montants arrivent à votre taille."
"L'eau vous arrive à la poitrine."
"Les vagues vous recouvrent les épaules."
"L'eau atteint votre menton. Vous avez du mal à garder les pieds au sol."
"L'eau est dans votre bouche maintenant[if a random chance of one in three succeeds]. C'est salé[end if]."
"Vous avez du mal à garder votre tête hors de l'eau."
"Vous avez du mal à voir où vous allez, car vous avez les yeux fermés pour éviter l'eau salée dans vos yeux. Il vous faut aller plus haut."
"L'eau recouvre votre tête. Qu'est-ce qui vous plairait pour la dernière action de votre vie ?"

Table of Zeus Clues
clue
"L'eau commence à recouvrir votre petite plateforme. Vous allez mourir ici."
"A présent l'eau vous arrive aux tibias."
"A présent l'eau vous arrive aux genoux."
"A présent l'eau vous arrive aux cuisses."
"A présent l'eau vous arrive à la hanche."
"A présent l'eau vous arrive à la taille."
"Je pensais que vous auriez abandonné ou recommencé depuis le temps. L'eau vous arrive à la poitrine."
"Epaules. La commande pour recommencer le jeu, c'est 'RECOMMENCER', au fait."
"Menton. Continuez d'essayer, j'imagine !"
"L'eau est dans votre bouche maintenant. Elle a goût de mer."
"Vous avez du mal à garder votre tête au-dessus de l'eau."
"Vous avez du mal à voir où vous allez, car vous avez les yeux fermés pour éviter l'eau salée dans vos yeux. Malheureusement, on ne peut pas vraiment aller quelque part depuis ici."
"L'eau finit par recouvrir votre tête. Vous avez peut-être le temps de faire une dernière chose avant de vous noyer..."

Table of Belowdecks Clues
clue
"L'eau montante a atteint le niveau de vos chevilles."
"Maintenant, l'eau clapote au niveau de vos tibias."
"Vos genoux sont recouverts par les vagues montantes."
"Maintenant l'eau est au niveau de vos cuisses."
"Vous grimacez en voyant l'eau monter au niveau de vos hanches."
"L'eau vous arrive à la taille."
"Maintenant l'eau vous arrive à la poitrine."
"Vous étirez votre coup alors que l'eau recouvre vos épaules."
"L'eau atteint votre menton. Vous avez du mal à garder les pieds au sol."
"L'eau est dans votre bouche maintenant[if a random chance of one in three succeeds]. C'est salé[end if]."
"Vous avez du mal à garder votre tête hors de l'eau."
"Vous avez du mal à voir où vous allez, car vous avez les yeux fermés pour éviter l'eau salée dans vos yeux. Il vous faut aller plus haut."
"L'eau finit par recouvrir votre tête. Vous avez peut-être le temps de faire une dernière chose avant de vous noyer..."


Section - Abandonné par le Capitaine

Amérique is a room. [Ceci est un hack sordide dont on a besoin pour empêcher le capitaine de revenir à vos côtés juste après être parti. Vous, le lecteur de ce code source, pouvez sans doute trouver une solution plus élégante. Quelques éléments de cette solution idiote peuvent être vus un peu plus loin, dans la règle qui fait que le Capitaine vous suit.]

A shipwrecking rule (this is the Captain abandons you rule):
	if the location is top:
		if the location is in the currently sinking deck:
			if the relative water level is 1:
				say "'Quelle déception,' dit le Capitaine Verdeterre tout en s'éloignant de vous en nageant.[paragraph break]Si seulement vous saviez nager.";
				now Capitaine Verdeterre is in Amérique;
	otherwise if the location is fo'c'sle or the location is quarterdeck:
		if the location is in the currently sinking deck:
			if the relative water level is 1:
				say "'Quelle déception,' dit le Capitaine Verdeterre tout en s'éloignant de vous en nageant.[paragraph break]Si seulement vous saviez nager.";
				now Capitaine Verdeterre is in Amérique;
	otherwise if the location is capstanroom:
		if the location is in the currently sinking deck:
			if the relative water level is 12:
				if the current action is not going:
					say "'Ok, coule avec le bateau alors,' dit le Capitaine. 'Mais je prends le sac avec moi.'[paragraph break]IL arrache le sac de vos mains, embarque dans le canot de sauvetage et part sans vous.";
					remove the sac from play;
					now Capitaine Verdeterre is in Amérique;
					remove the canot de sauvetage from play.

Section - Comment vous empêcher d'interagir avec les objets alors qu'ils sont sous l'eau

An object has a number called height. The height of an object is usually 1. The height of a person is usually 20.

An object has some text called the sinking message.

Definition: a thing is sinking if it is in a room in the currently sinking deck. [Cette définition ne veut pas exactement dire ça ; par 'sinking' (en train de couler), ce qu'on veut dire en réalité c'est 'risque de couler'.]

A shipwrecking rule (this is the items washed away rule):
	repeat with item running through sinking things:
		if the item is scenery:
			do nothing;
		otherwise if the item is not enclosed by a person and the item is not enclosed by an object and the item is not supported by an object:
			if the height of the item is less than the relative water level:
				if the item is visible:
					if the sinking message of the item is "":
						say "Les eaux montantes engloutissent [the item].[paragraph break]";
					otherwise:
						say "[the sinking message of the item][paragraph break]";
				remove the item from play.

Check dropping something (this is the insurance against losing objects rule):
	if the location is in the currently sinking deck:
		now the going nowhere boolean is true;
		say "Avec toute cette eau qui tourbillonne autour de vous, il n'y a nulle part où mettre quoi que ce soit en lieu sûr." instead.

Before dropping something:
	if the noun is enclosed by the sac:
		silently try taking the noun.

Section - Où diable vais-je donc mettre cette règle
	[TC: in French, the most correct translation of "what the hell" is "que diable", meaning "what in the devil" or something like that. But we don't have anything milder than that I'm afraid - even this is old-fashioned and 'weak' by modern speech standards, and there's no equivalent to "gosh", "heck" and "darn" (ie phonetic approximations to cover blasphemy - oh, Wikipedia tells me you guys call it minced oaths) that I know of in French. Maybe we had less puritanism?]
	[TC: actually, I just remembered that there is one such phonetic approximation in French: the old "sacrebleu" and "parbleu", which are very old-timey (Middle-Age-y) expressions of surprise, a deformation of "Sacré Dieu!" (Holy God!) and "Par Dieu!" (By God!). Although what's interesting is that "bleu" (blue) replaces "Dieu", and so linguists aren't sure if this is the right etymology; maybe it came from curse words directed at the aristocracy, who is said "to have a blue blood" and whose associated color is often blue.]

This is the reject commands with multiple objects rule:
	let objs be the multiple object list;
	if the number of entries in objs is greater than 1:
		alter the multiple object list to {};
		say "[italic type]{Pour s'assurer de l'urgence de votre situation, on vous demande de vous abstenir de manipuler plus d'un objet à la fois. Nous regrettons sincèrement tout désagrément que cette règle pourrait vous causer.}[roman type][paragraph break]" instead.

The reject commands with multiple objects rule is listed before the generate action rule in the turn sequence rules.

[Cette règle était bien plus stupide que ça avant que Emily Boegheim ne la trouve pour moi.]





Part - Notes sur le Vocabulaire Nautique

[Règles pour autoriser ou interdire du texte facultatif adapté de 'numbers on'/'numbers off' dans le Inform ATTACK de Gijsbers. Les notes en elles-mêmes apparaissent dans les descriptions des salles et des objets selon la syntaxe:

[if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: }[roman type][end if]

— ce qui fait beaucoup de textes à insérer dans un bloc de texte sur 2, mais c'est pour ça que je l'écris ici, que je puisse le copier-coller partout ailleurs.]

The Nautical Vocabulary Notes Boolean is a truth state variable. The Nautical Vocabulary Notes Boolean is false.

The Nautical Vocabulary Notes Chastity Boolean is a truth state variable. The Nautical Vocabulary Notes Chastity Boolean is true.

Enabling the Nautical Vocabulary Notes is an action out of world. Understand "Activer notes de vocabulaire nautique" and "Activer notes de vocabulaire" and "Activer notes vocabulaire" and "Activer notes vocabulaire nautique" and "Activer notes" and "Notes on" and "Notes de vocabulaire on" and "Notes vocabulaire on" and "Notes vocabulaire nautique on" and "Notes de vocabulaire nautique on" and "Autoriser notes de vocabulaire nautique" and "Autoriser notes de vocabulaire" and "Autoriser notes vocabulaire" and "Autoriser notes vocabulaire nautique" and "Autoriser notes" as enabling the Nautical Vocabulary Notes.
Carry out Enabling the Nautical Vocabulary Notes (This is the Enabling Nautical Vocabulary Notes Rule):
	now the Nautical Vocabulary Notes Boolean is true;
	now the Nautical Vocabulary Notes Chastity Boolean is false;
	say "[italic type]{Les notes de vocabulaire nautique sont maintenant activées. Elles peuvent être désactivées par la commande 'DESACTIVER NOTES DE VOCABULAIRE NAUTIQUE' quand vous le voulez.}[roman type][line break]".
	[TC: mo' articles, mo' possibilities - you want to keep a flexible parser, so you have to include the versions both with and without articles.]
	[TC: actually, this might be useless - I don't know how the I7 parser treats the 'de' article, maybe in that case it'd delete it and we wouldn't have to worry about it. Oh well.]

Disabling the Nautical Vocabulary Notes is an action out of world. Understand "Désactiver notes de vocabulaire nautique" and "Désactiver notes de vocabulaire" and "Désactiver notes vocabulaire" and "Désactiver notes vocabulaire nautique" and "Désactiver notes" and "Notes off" and "Notes de vocabulaire off" and "Notes vocabulaire off" and "Notes vocabulaire nautique off" and "Notes de vocabulaire nautique off" and "Interdire notes de vocabulaire nautique" and "Interdire notes de vocabulaire" and "Interdire notes vocabulaire" and "Interdire notes vocabulaire nautique" and "Interdire notes" as  Disabling the Nautical Vocabulary Notes.
Carry out Disabling the Nautical Vocabulary Notes (This is the Disabling Nautical Vocabulary Notes Rule):
	now the Nautical Vocabulary Notes Boolean is false;
	say "[italic type]{Les notes de vocabulaire nautique ont été désactivées. Elles peuvent être activées par la commande 'ACTIVER NOTES DE VOCABULAIRE NAUTIQUE' quand vous le voulez.}[roman type][line break]".

An every turn rule (this is the Nautical Vocabulary Notes Introduction Rule):
	If the turn count is 2:
		say "[italic type]{Ce jeu contient des notes de vocabulaire nautique pour vous édifier. Si vous voulez activer les notes de vocabulaire nautique, veuillez entrer la commande 'ACTIVER NOTES DE VOCABULAIRE NAUTIQUE'. Merci.}[roman type][line break]"
		
An every turn rule (this is the Nautical Vocabulary Notes Reminder Rule):
	If the turn count is 36:
		if the Nautical Vocabulary Notes Chastity Boolean is true:
			say "[italic type]{Un rappel amical: des ressources substantielles ont été investies dans la recherche et l'implémentation des notes de vocabulaire nautique pour ce jeu. Si vous voulez activer les notes de vocabulaire nautique, veuillez entrer la commande 'ACTIVER NOTES DE VOCABULAIRE NAUTIQUE'. Merci beaucoup.}[roman type][line break]"



Part - Votre Noble Capitaine

Capitaine Verdeterre is a man. [façon de parler.]
Capitaine Verdeterre is in forehold.
Capitaine Verdeterre can be transparent. Capitaine Verdeterre is transparent. [Comme ça on pourra voir ce qu'il est en train de porter.] 
Understand "rat" as Capitaine Verdeterre.

The description of Capitaine Verdeterre is "Le Capitaine Verdeterre dégage un air imposant, avec son chapeau à plume et sa veste fringante. Il y a tellement de raisons de l'admirer : son génie tactique, son caractère intrépide, sa confiance en lui-même [unicode 8212] et sa capacité à inspirer la confiance des autres en lui.[paragraph break]Il est bien plus petit que vous, parce que c'est un rat, mais à vos yeux, c'est un géant."
	[TC: "you can't literally look up to him" is a pun, and an untranslatable one too. Agh! So I need a turn of sentence that will combine the fact that he is awesome and the fact that he's short. After some brainstorming, I think that calling him a giant (in French) works: you could call someone like that if it's a man with achievements so big it "makes him big", or their achievements "dwarf you" so to speak.]

Capitaine Verdeterre wears a red jacket. Understand "fringante" and "veste fringante" and "manteau" as the red jacket. The description of the jacket is "Bien sûr, une veste pour rats doit avoir un trou dans le dos pour sa queue, mais la veste de Verdeterre arbore également une rangée de petits boutons en or qui en font quelque chose qui lui donne un vrai air de capitaine."

Some tiny gold buttons are part of the red jacket. Understand "bouton" as the buttons. The description of the tiny gold buttons is "Avec ces boutons sur sa veste, impossible de rater Verdeterre ; mais il était déjà impossible de le rater !"

The countingtext of the tiny gold buttons is "On dirait qu'il y en a cinq."
	[TC: there was a typo here, the period needs to be before the quotation marks.]

Capitaine Verdeterre wears a plumed hat. Understand "plume" and "emplumé" and "plumes" as the plumed hat. The description of the plumed hat is "Le capitaine a déjà expliqué plusieurs fois que cette plume sur son chapeau appartenait à un albatros, qu'il tua de ses propres mains."

Capitaine Verdeterre carries a cutlass. Understand "épée" as the cutlass. The description of the cutlass is "Le Capitaine Verdeterre est très fier de porter un 'vrai' coutelas (la plupart des individus de son rang se voient forcés d'improviser de tels accessoires avec ce qu'ils peuvent)."

The tail is part of Capitaine Verdeterre. The description of the tail is "Verdeterre est nerveux, ce qui se comprend au vu de la situation, et il bouge sa queue dans tous les sens, si bien qu'on dirait qu'elle a sa propre vie, et qu'elle est en colère. On dirait un gros ver de terre. C'est d'ailleurs pour ça qu'il s'appelle Verdeterre. Parce que sa queue ressemble à un ver de terre. D'où le nom."
	[TC: what is a subtle pun in English becomes completely obvious in French, so I didn't know what I should do. One way is to translate it like that, losing all subtlety ; another way, which I like better and I think is in line with the tone of rest of the text, is to be like "it looks like... well... an earthworm" (almost being ashamed of making the obvious pun). I went for the second solution, feel free to let me know which one you want.]
	[AC: Man, that earthworm joke. Good grief. I think if I had been writing it in French originally, I would have tried something like: "...It reminds you of a big, angry ver de terre. That's why his name is 'Verdeterre', because his tail resembles a ver de terre." If you think that would play, you could use that, but otherwise we can keep your version. (Really, If I had been writing it in French, I probably would have named the captain something else...)]


Before doing something other than counting or examining with something enclosed by Capitaine Verdeterre:
	say "Le capitaine n'est pas d'humeur à ce qu'on l'asticote, ni maintenant, ni à aucun autre moment." instead.




The initial appearance of Capitaine Verdeterre is "[Captain Appearance].".

To say captain appearance:
	if the current action is looking:
		if the turn count is 1:
			say "[one of]'Bon, allez,' dit le Capitaine Verdeterre. 'Rassemblons tout ce qui peut avoir une quelconque valeur et mettons-le dans ce sac.' Il désigne un sac près de vous, que vous ramassez[or]Le Capitaine vous regarde avec impatience[stopping]";
		otherwise:
			say "[one of]Le capitaine vous regarde avec impatience[or]Le capitaine considère la situation d'un oeil grave[or]Le capitaine caresse sa queue tout en réfléchissant[as decreasingly likely outcomes]";
	otherwise if the current action is going:
		if the location is the currently sinking deck and the relative water level is greater than 1:
			say "[one of]Le capitaine vous suit en nageant[or]Le capitaine nage en face de vous, et frappe l'eau impatiemment[as decreasingly likely outcomes]";
		otherwise if the location is in Zeus:
			say "[one of]Le capitaine escalade les cordages devant vous avec agilité[or]Le capitaine grimpe les cordages derrière vous[as decreasingly likely outcomes]";
		otherwise:
			say "[one of]Le capitaine trotte derrière vous[or]Le capitaine se précipite devant vous pour faire le point sur la situation[or]Le capitaine court devant vous, puisque venir ici était son idée[as decreasingly likely outcomes]";
	otherwise:
		say "COMMENT EN EST-ON ARRIVE LA. CA N'AURAIT PAS DU ARRIVER. SIGNALEZ LE BUG S'IL VOUS PLAIT."

[Voici la règle, à laquelle on faisait allusion plus haut, qui a besoin de la présence de l'"Amérique". (Cuba apparaîtra encore un peu plus loin.) Je crois que retirer le capitaine du jeu ne marchait pas. Alors, quand on a besoin que le capitaine abandonne le joueur, à la place on l'envoie en Amérique, et il ne peut pas se sortir de ce continent:]

Every turn (this is the Captain Follows Rule):
	if the location of Capitaine Verdeterre is not the location of the player:
		if the location of Capitaine Verdeterre is Amérique or the location of Capitaine Verdeterre is Cuba:
			rule succeeds;
		otherwise:
			let the way be the best route from the location of Capitaine Verdeterre to the location of the player;
			silently try Capitaine Verdeterre going the way;
			if capitaine verdeterre is in the location:
				say "[Captain Appearance].";

Instead of asking capitaine verdeterre about something:
	say "Le capitaine vous intime le silence. 'Peut-être que tu ferais mieux de garder le bavardage pour quand on sera sur la terre ferme, tu ne crois pas ?'".
	
Instead of telling capitaine verdeterre about something:
	say "Le capitaine vous intime le silence. 'Peut-être que tu ferais mieux de garder le bavardage pour quand on sera sur la terre ferme, tu ne crois pas ?'".
	
Instead of answering capitaine verdeterre that something:
	say "Le capitaine vous intime le silence. 'Peut-être que tu ferais mieux de garder le bavardage pour quand on sera sur la terre ferme, tu ne crois pas ?'".

Persuasion rule for asking capitaine verdeterre to try doing something:
	say "[one of]Votre capitaine, peu habitué à recevoir des ordres de ses subordonnés, se contente de hocher la tête d'un air absent[or]Verdeterre n'a pas l'air de prêter attention à ce que vous dites, mais vous pensez l'avoir vu lever les yeux au ciel[stopping].";
	persuasion fails.

Instead of shooting Capitaine Verdeterre:
	say "[one of]Vous ne pourriez pas. Que feriez-vous sans lui ?[or]Vous ne pourriez pas. Que feriez-vous sans lui ?[paragraph break]En plus, vos ordres sont de protéger sa vie avant la vôtre.[stopping]";
	now the going nowhere boolean is true.

Volume - Le Scenario


When play begins:
	Say "[fixed letter spacing]   APPUYEZ SUR UNE TOUCHE       POUR CONTINUER        APPUYEZ SUR UNE TOUCHE[line break]";
	say "[fixed letter spacing]       POUR CONTINUER       APPUYEZ SUR UNE TOUCHE        POUR CONTINUER[paragraph break][paragraph break]";
	say "[variable letter spacing]Vous ne pouvez vous empêcher de penser que tout ceci aurait pu être évité.[paragraph break]'Je sais ce que tu es en train de penser, garçon. Et tu as raison, tout ça est de ta faute. Mais tu ne peux pas vraiment t'en vouloir non plus.'[paragraph break]Le capitaine fait claquer sa langue d'un air meurtri. 'Tu as fait de ton mieux, et ça n[']était pas assez bien. Tout ce qu'on peut faire maintenant, c'est faire du mieux qu'on peut.'[paragraph break]Il s'autorise un moment de silence. Puis il vous fixe avec un petit oeil noir:[paragraph break]'Tu penses pas que tu devrais te mettre au travail ?'[paragraph break][paragraph break]";
	say "[fixed letter spacing]       POUR CONTINUER      APPUYEZ SUR UNE TOUCHE        POUR CONTINUER[line break]";
	say "[fixed letter spacing]   APPUYEZ SUR UNE TOUCHE      POUR CONTINUER        APPUYEZ SUR UNE TOUCHE[paragraph break][variable letter spacing]";
	wait for any key;
	now Aready is true.
	
Aready is a truth state that varies. Aready is false.

Part - Tout Sur Le Joueur

Instead of examining yourself, say "Vous êtes Tibert Dusachet, et de facto le second du Capitaine Verdeterre à bord de ce bateau, l['][italic type]Incapable[roman type], qui était auparavant encore capable de flotter. Pendant votre service sous les ordres de Verdeterre, vous avez vu des douzaines de vos camarades marins arriver et partir, mais pour la plupart c[']était partir. Vous êtes le dernier restant.".

Instead of shooting the player, say "Oh, vous ne devriez pas. Le Capitaine Verdeterre s'énerverait vraiment."

Section - Le Sac Volumineux

The player carries a sac volumineux. The sac is an open transparent container. Understand "gros" as the sac volumineux.

Before dropping the sac volumineux:
	say "Vous ne pouvez pas vous débarasser du sac. [If the sac contains something valuable]Le capitaine vous tuerait, littéralement, si vous laissiez tomber un de ses trésors[otherwise]Vous avez pour ordres de le remplir de trésors[end if].";
	reject the player's command.
	
Before inserting the sac volumineux into the sac volumineux:
	say "Ce serait un exercice de topologie amusant. [italic type]{Note de vocabulaire mathématique: la topologie est l'étude des propriétés spatiales qui sont conservées par des déformations continues.}[roman type][paragraph break]";
	reject the player's command.

Before inserting the sac volumineux into something:
	say "Vous ne pouvez pas vous débarasser du sac. [If the sac contains something valuable]Le capitaine vous tuerait, littéralement, si vous laissiez tomber un de ses trésors[otherwise]Vous avez pour ordres de le remplir de trésors[end if].";
	reject the player's command.
	
Before putting the sac volumineux on something:
	say "Vous ne pouvez pas vous débarasser du sac. [If the sac contains something valuable]Le capitaine vous tuerait, littéralement, si vous laissiez tomber un de ses trésors[otherwise]Vous avez pour ordres de le remplir de trésors[end if].";
	reject the player's command.

Instead of shooting the sac volumineux:
	say "Mauvaise idée ! Les sacs comme celui-ci marchent mieux quand ils n'ont pas de gros trous.";
	now the going nowhere boolean is true.

Section - Le Pistolet

[Le protagoniste de mon jeu Taco Fiction avait un pistolet avec aucune balle dedans qu'il ou elle pouvait utiliser uniquement pour intimider les gens. Le principe de ce jeu c'est de faire des choix irréversibles, alors Tibert a un pistolet avec une seule balle. A mon avis, zéro et une seule sont les nombres de balles les plus intéressants.

Il y a certaines choses que je veux déclencher quelle que soit la cible que vous avez choisie, mais bien sûr la plupart des cibles réagiront de façon unique. Les règles générales pour l'utilisation du pistolet sont rassemblées ici, et l'information pour chaque objet demandera une règle 'after shooting' qui décrit les conséquences particulières de l'action.]

The player carries a pistolet à silex. Understand "fusil" as the pistolet à silex.

The description of the pistolet is "Ceci, votre fidèle pistolet, appartient toujours techniquement au capitaine. Il dit parfois qu'il vous l'a donné, et parfois qu'il vous l'a prêté."

The worth of the pistolet is 23. The appraisal of the pistolet is "Un pistolet à silex tout cabossé qui vaut 23 dollars..."

Shooting is an action applying to one thing. Understand "tirer sur [something]" and "ouvrir le feu sur [something]" as shooting.

Shooting with is an action applying to two things. Understand "tirer sur [something] avec [something preferably held]" as shooting with. Understand "ouvrir le feu sur [something] avec [something preferably held]" as shooting with (with nouns reversed). Understand "tirer avec [something preferably held] sur [something]" as shooting with (with nouns reversed). 

Check shooting with:
	if the second noun is the pistolet à silex:
		try shooting the noun instead;
	otherwise:
		now the going nowhere boolean is true;
		say "[The second noun] n'est pas un objet que vous pouvez utiliser pour tirer sur quelque chose." instead.
		
Bullets is a number that varies. Bullets is 1.

Bullettarget is a text that varies.

Check shooting (this is the only one bullet rule):
	if bullets is 0:
		say "Vous avez utilisé votre seule balle quand vous avez [bullettarget]." instead;
	unless the player carries the pistolet:
		say "D'abord il vous faut prendre ce pistolet.";
		silently try taking the pistolet;
		unless the player carries the pistolet:
			stop the action;
	if bullets is 1:
		now bullets is 0;
		now bullettarget is "tiré sur [the noun]";
		continue the action.


Instead of dropping the pistolet, say "Vous ne pouvez pas juste laisser votre pistolet là."

Instead of inserting the pistolet into something:
	if the second noun is the sac volumineux:
		continue the action;
	otherwise:
		say "Vous feriez mieux de le garder."

Instead of putting the pistolet on something, say "Vous feriez mieux de le garder."

Instead of shooting the pistolet, say "Le pistolet ne peut tirer que sur des objets distincts de lui-même."


['tiré sur nom' marchera très bien dans la plupart des situations, mais je peux le changer en 'essayé de tirer sur le capitaine" ou autre si je veux en faisait une règle "after shooting".]
		
[Ce truc de 'pointer' a été principalement repris de Taco Fiction. Ca ne fait rien de bien intéressant dans ce jeu mais c'est marrant de pouvoir le faire.]

Pointing is an action applying to one thing. Understand "viser [something]" as pointing. Understand "pointer [something]" as pointing.

Carry out pointing:
	say "Vous pointez [the noun] vers le centre de rien en particulier."
	
Pointing at is an action applying to two things. Understand "viser avec [something preferably held] [something]" as pointing at. Understand "pointer [something preferably held] à [something]" as pointing at. Understand "viser [something] avec [something preferably held]" as pointing at (with nouns reversed). Understand "pointer à [something] avec [something preferably held]" as pointing at (with nouns reversed).

Carry out pointing at:
	say "Vous pointez [the noun] droit vers [the second noun].";
	if the second noun is valuable:
		if Capitaine Verdeterre is in the location:
			say "'Attends !' s'écrie le Capitaine. 'N'allons pas trop vite, hein ? D'accord ?'"

Check pointing at:
	if the player carries the noun:
		continue the action;
	otherwise:
		say "Vous n'avez pas [the noun] sur vous." instead;
		now the going nowhere boolean is true.

Check pointing at:
	if the noun is the pistolet à silex:
		if the second noun is the player:
			say "Vous essayez de pointer le pistolet vers vous-même, mais il s'avère que ça n'est pas très facile à faire, ce pistolet est tellement long... Vous vous sentez un peu bête d'essayer." instead.

Check pointing at:
	if the noun is the second noun:
		say "Je ne vois pas comment ça serait possible." instead.


Part - Des Trucs Qui Sont Partout

The eau is a backdrop. The eau is female. The description of the eau is "L'eau qui s'écoule autour de vous est trouble, pleine de crasse venant du puisard [if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: Le 'puisard' est la partie interne la plus basse de la coque d'un bateau, sous la cale. } [roman type][end if]et des ponts, qui n'ont as été lavés par un mousse depuis des mois.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un 'mousse' est un marin de grade le plus bas, qui se charge usuellement des corvées.}[roman type][end if]"
	[TC: the 'swab'/'mousse' thing again...]

The countingtext of the eau is "'Eau' est en français un 'nom indénombrable', et de ce fait (au contraire des 'noms dénombrables') ne peut pas être comptée."
	[TC: typo here: missing the last period]

Instead of taking the eau:
	say "[if the eau is in the location]Il y en a plein autour de vous, mais quand bien même, c'est difficile d'en garder dans vos mains[otherwise]Elle est encore assez loin pour que vous ne puissiez la toucher[end if].";
	now the going nowhere boolean is true.

After shooting the eau:
	say "Vous tirez votre seule balle dans l'eau, ce qui ralentit considérablement le projectile. Qui coule.";
	now bullettarget is "tiré dans l'eau".

Instead of drinking the eau:
	say "Votre but a toujours été d'éviter de boire de l'eau de mer non stérilisée pendant autant de temps que possible.";
	now the going nowhere boolean is true.

After deciding the scope of the player when the location is in overdecks or the location is in zeus:
	if the eau is in maindeck:
		place the eau in scope;


The bateau is a backdrop. The bateau is everywhere. Understand "navire" and "incapable" and "planches" and "lattes" and "latte" and "planche" and "pont" and "coque" and "sol" and "mur" and "cloison" and "bastingage" and "cloisons" and "bastingages" as the bateau. The description of the bateau is "A certains endroits, les planches sont toujours solides, et elles vous font vous demander : 'Combien de temps cette vieille carne peut encore durer ?' Et le reste du bateau répond : 'Pas longtemps.'"
	[TC: no idea what 'old girl' in that context means - it must be a way to refer to a ship, but we don't have such 'affectionate slang' for boats I think. So I used the equivalent of 'old girl' for horses, thinking it might carry the same sentiment - hopefully it works!]

After shooting the bateau:
	say "Vous tirez votre dernière balle dans les planches du bateau qui vous a servi si bien. Qu'est-ce que ça change, un trou de plus ou de moins ?";
	now bullettarget is "fait un trou de plus dans l['][italic type]Incapable[roman type]"
	
Instead of taking the bateau:
	say "Ce bateau est allé aussi loin qu'il le pouvait.";
	now the going nowhere boolean is true.


Part - Cale

Hold is a region. Forehold and Afthold are in Hold.

Section - Cale Avant

Forehold is a room. The player is in Forehold. The description of Forehold is "C'est la partie la plus avant de la cale, là où est le trou béant que le récif a fait dans la coque du bateau. [if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: La 'cale' est la partie basse du bateau où l'on entrepose le cargo. La 'coque' est le corps du bateau.} [roman type][end if]L'eau y entre à une vitesse alarmante.[paragraph break]Le reste de la cale (et les escaliers vers les ponts supérieurs) est vers la poupe. [if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: 'Poupe' veut dire vers l'arrière du bateau. Un 'pont' est un étage.}[roman type][end if]".
	[TC: as far as I know there is no 'nautical' equivalent of fore, i.e. I think we just say 'front' (avant) and 'back' (arrière) for all the parts of the boat.]

The printed name of Forehold is "Cale avant". 

The gros trou is scenery in forehold. Understand "brèche" as the gros trou. The description of the gros trou is "Vous auriez pensé que la coque était trop solide pour être autant endommagée, mais en même temps c'est vrai que vous êtes rentré dans ce récif de plein fouet.".

After shooting the gros trou:
	say "Vous tirez dans la brèche, qui ne réagit pas. Le Capitaine Verdeterre secoue la tête d'un air dépité."


The crâne de gorille is here. The crâne de gorille is valuable.

The worth of the crâne de gorille is 70. The appraisal of the crâne de gorille is "Le crâne d'un gorille africain, vendu 70 dollars espagnols à un pigeon qui possédait déjà le squelette incomplet d'un orang-outang...".

The height of the crâne de gorille is 9. The sinking message of the crâne de gorille is "Le crâne du gorille semble vous regarder d'un air accusateur alors qu'il disparaît dans l'eau trouble.".
	[TC: which murk are we talking about? Might be a figure of speech here that I don't understand. But a synonym for sinking in French is 'sombrer', which just means to sink but sounds like 'somber', 'dark' - since 'murk' seems to be a word for a dark mist, I'll leave it like that.]
	[AC: The "murk" that the gorilla skull sinks into is just the water, which is dark/murky because it's so dirty.]

The initial appearance of the crâne de gorille is "Un crâne de gorille à l'air perturbé est suspendu à un crochet sur le mur."

The description of the crâne de gorille is "Un objet horrible, avec des crocs proéminents et irréguliers, et une boîte crânienne dont on dirait qu'elle a été mise à l'envers. Pas étonnant qu'il fut toujours aussi énervé."

Before taking the crâne de gorille the first time, say "Le capitaine sourit au crâne. 'Ce bon vieux Charlie ! Il avait tellement d'énergie. Si je pouvais, je crois que je lui tirerais dessus encore une fois.[quotation mark][paragraph break]"
	[TC: 'spirited' here as 'smart' or 'well-spoken' ? I used well-spoken, I hope it's right]
	[AC: "Spirited" describes the Charlie only in the sense of having a lot of energy. (In Verdeterre universe, it's only humans and rats who can talk.)]

After shooting the crâne de gorille:
	say "Vous tirez sur le crâne, qui explose en morceaux et disparaît pour toujours.[paragraph break]'Non ! Oh, Charlie !' s'écrie le capitaine. Il vous regarde, incrédule. 'Pourquoi as-tu fait ça ?''";
	remove the crâne de gorille from play;




The gobelet en étain is here. The gobelet is valuable. Understand "calice" or "coupe" as the gobelet.

The worth of the gobelet is 11. The appraisal of the gobelet is "Un calice de communion volé d'une pauvre église, quelque part, qui vaut 11 dollars..."

The height of the gobelet is 3. The sinking message of the gobelet is "Le gobelet est perdu pour toujours dans les eaux tourbillonantes."

The initial appearance of the gobelet is "Dans un coin de la pièce se trouve un gobelet en étain."

The description of the gobelet is "Enfin, c'est sans doute de l[']étain. Mais vous n'êtes pas un expert."

Before taking the gobelet the first time, say "'Celui-ci, bien sûr,' dit le capitaine. 'Les gens seront prêts à payer une grosse somme pour des calices précieux comme celui-là.'[paragraph break]"

After shooting the gobelet en étain:
	say "Vous visez le gobelet avec application, mais c'est une petite cible, et votre tir ne laisse qu'une éraflure que personne à part vous et le capitaine ne remarquera."




The faux livre is here. The printed name of the faux livre is "livre épais". Understand "épais" or "livre épais" as the faux livre. The faux livre is a closed openable container.

The height of the livre is 2. The sinking message of the livre is "Le livre coule et disparaît."

Understand "lire [the faux livre]" as opening.

The initial appearance of the faux livre is "Un livre épais est posé près de vous."

The description of the livre is "[if the bracelet is in Amérique]Il n'y a pas de titre sur la couverture ou sur la reliure. Ce livre a l'air profondément inintéressant[otherwise]Un livre qui a l'air ennuyeux, avec un trou creusé à l'intérieur. Malin[end if]."

After taking the livre the first time:
	say "Vous prenez le livre.[paragraph break]'Oh, repose ça,' dit Verdeterre. 'On cherche des [italic type]trésors,[roman type] pas des [italic type]livres moisis.[roman type][quotation mark][paragraph break]"

Before opening the faux livre the first time:
	If the faux livre is not held:
		try taking the faux livre;
	Now the bracelet is in the faux livre.
	
After opening the faux livre the first time:
	say "Vous ouvez le livre. Un trou a été creusé dans les pages, et il y a un bracelet en acier à l'intérieur.[paragraph break]'Eh bien, voyez-vous ça,' dit Verdeterre.";
	now the printed name of the faux livre is "faux livre".
	
After shooting the faux livre:
	say "Vous réduisez le livre en morceaux.";
	remove the livre from play;
	if the bracelet is in Amérique:
		say "[line break]Tout ce qui reste est un bracelet en acier trempé que quelqu'un avait apparemment caché à l'intérieur du livre.";
		now the bracelet is in the location;
	otherwise if the bracelet is inside the faux livre:
		say "[line break]Par contre, le bracelet en acier à l'intérieur a survécu sans égratignures."


The bracelet en acier is valuable. The bracelet en acier is wearable. The bracelet is in Amérique.

The worth of the bracelet is 53. The appraisal of the bracelet is "Un bracelet en acier trempé, apparemment conçu par des Russes, vendu 53 dollars..."

The height of the bracelet is 1. The sinking message of the bracelet is "Le délicat bracelet est vite emporté par le courant."

The description of the bracelet is "Le bracelet est formé de petits liens en acier trempé. Il y a un joli petit dessin sur le fermoir. Ravissant."
	[TC: very fetching? ooh is that where 'that's so fetch' comes from?]

Check inserting something into the faux livre:
	if the noun is the bracelet:
		continue the action;
	otherwise:
		now the going nowhere boolean is true;
		say "La seule chose qui rentre dans ce faux livre est ce bracelet." instead.

After shooting the bracelet:
	say "Vous visez avec précaution, et assurez votre main avec l'autre, mais votre tir ne fait que rebondir sur le bracelet et se perd on ne sait où. Le bracelet n'a rien."


Section - Cale Arrière

Afthold is poupe of Forehold. The printed name of Afthold is "Cale arrière". the description of Afthold is "La majorité de ce qui est dans la cale est du ballast, mais il y a quelques objets intéressants. [if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: Le 'ballast' fait référence à tout ce qui est gardé dans la cale pour aider à stabiliser le navire.} [roman type][end if]Le reste de la cale est vers la proue, et les escaliers mènent au pont inférieur."

The ballast is scenery in afthold. The description of the ballast is "Des cailloux, des sacs de sable et de gravier, des trucs comme ça."

Instead of doing something other than examining with the ballast:
	say "Pas le temps de s'occuper du ballast. Le ballast a fait son boulot.";
	now the going nowhere boolean is true.



The coffre-fort en fer is here. The coffre-fort is locked. Understand "fort" or "coffre" or "coffre fort" or "boîte" as the coffre-fort. 

Does the player mean unlocking the coffre-fort en fer with the clé en fer: it is very likely.

The initial appearance of the coffre-fort en fer is "[if the relative water level is less than 8]A peu près au milieu de la cale arrière se trouve un coffre-fort en fer[otherwise]Malgré la hauteur de l'eau, vous pouvez atteindre de justesse le coffre-fort en fer[end if]."

The description of the coffre-fort en fer is "En plus de ses côtés et son couvercle en fer, le coffre-fort est maintenu au sol avec toutes sortes de boucles compliquées."

Some boucles compliquées are part of the coffre-fort en fer. The description of the boucles compliquées is "La plupart de ces boucles sont sans doute juste là pour la décoration, mais il est difficile de dire lesquelles."

The countingtext of the boucles is "Il doit y en avoir au moins une douzaine"

Instead of taking the coffre-fort:
	say "Il faudrait deux costauds pour bouger cette boîte, et vous ne comptez pas, car le haut de votre corps est plutôt faible.";
	now the going nowhere boolean is true.

Check opening the coffre-fort en fer:
	if the coffre-fort is locked:
		say "Vous agrippez le couvercle du coffre-fort, mais il est bien fermé et résiste.[first time][line break]'Oh, mince,' dit Verdeterre. 'J'ai oublié où j'ai mis la clé. Me connaissant, elle est probablement très bien cachée. Mais je ne me souviens pas non plus de ce qu'il y avait à l'intérieur, donc ça n'est pas une grande perte non plus.'[only]" instead.
		
The height of the coffre-fort en fer is 16. The sinking message of the coffre-fort en fer is "Le coffre-fort finit par couler, hors de votre vue."

Instead of shooting the boucles, try shooting the coffre-fort.

After shooting the coffre-fort:
	say "Vous tirez sur le coffre-fort. Votre balle, la seule balle que vous aviez, rebondit sans faire aucun mal au coffre, et disparaît."

After opening the coffre-fort:
	say "Vous ouvez le coffre-fort, révélant [a list of things contained by the coffre-fort]. [first time]Le regard du capitaine s'éclaire. 'Je me souviens maintenant ! Prends donc cette bouteille avant qu'elle ne coule !'[only]"




The bouteille de Prévenge is in the coffre-fort. The bouteille de Prévenge is valuable. The bouteille de Prévenge is female. The printed name of the bouteille de Prévenge is "bouteille en verre verte". Understand "bouteille verte" or "verte" or "verre" or "bouteille en verre verte" or "bouteille en vert" or "vin" as the bouteille de Prévenge.

The description of the bouteille de Prévenge is "La bouteille est remplie de liquide sombre, et sur l'étiquette est écrit 'Prévenge[quotation mark], même si vous ne le savez pas (vous ne savez pas lire)."

After examining the bouteille de Prévenge the first time:
	now the printed name of the bouteille de Prévenge is "bouteille de Prévenge".

The worth of the bouteille de Prévenge is 220. The appraisal of the bouteille de Prévenge is "Une bouteille d'un vin apparemment très rare venant de la région peu connue de Prévenge, vendue 220 dollars..."

The height of the bouteille de Prévenge is 2. The sinking message of the bouteille de Prévenge is "La bouteille de vin est emportée par le courant."

After shooting the bouteille de Prévenge:
	say "'Non !' crie le capitaine, et il saute entre vous et la bouteille. Votre cerveau réalise avec horreur que vous devez arrêter cela.[paragraph break]Mais il est trop tard, car votre doigt a déjà appuyé sur la détente. Le pistolet tire, la balle part [unicode 8212] à travers le corps du Capitaine Verdeterre, à travers [the bouteille de Prévenge]. Le vin et le sang se mélangent [if the location is in the currently sinking deck]avec l'eau qui monte rapidement[otherwise]sur les planches[end if].[paragraph break]Ses derniers mots sont: 'Tu es complètement inutile.'";
	end the game saying "Vous ne pouvez rien y faire."




The vase ornementé is here. The vase ornementé is valuable.

The initial appearance of the vase ornementé is "Un vase ornementé se trouve non loin de vous."

The description of the vase ornementé is "La céramique blanche est peinte avec un motif de feuilles et de vignes bleues. Le vase a l'air très fragile.[first time][paragraph break]'C'est chinois,' vous explique le capitaine. 'Les types à qui nous l'avons volé étaient espagnols, mais je suis sûr que les types à qui [italic type]eux[roman type] l'ont volé étaient chinois.'[only]"

The height of the vase ornementé is 5. The sinking message of the vase ornementé is "Le vase est emporté par les vagues et est perdu pour toujours."

The worth of the vase ornementé is 9. The appraisal of the vase ornementé is "Une pâle imitation d'un vase 'chinois', laissé pour 9 dollars..."

Instead of inserting something into the vase:
	say "Vaut mieux pas. Vous ne voulez rien casser.";
	now the going nowhere boolean is true;

Instead of searching the vase:
	say "C'est bien sombre à l'intérieur.";
	now the going nowhere boolean is true;
	
Before taking the vase ornementé the first time:
	say "Le capitaine couine avec approbation. 'C'est bon, ça. Ca nous nourrira pendant une semaine.'"

After shooting the vase ornementé:
	say "Vous tirez sur le vase, qui éclate en mille morceaux. Votre capitaine frappe son petit front avec sa petite patte.";
	remove the vase ornementé from play.
	


The boule de cristal is here. The boule de cristal is valuable. The boule de cristal is female.

The initial appearance of the boule de cristal is "Une boule de cristal est en train de rouler par terre."

The description of the boule de cristal is "Le cristal est clair et brillant. Verdeterre et la voyante étaient un temps partenaires en affaires."

The height of the boule de cristal is 2. The sinking message of the boule de cristal is "La boule de cristal disparaît sous les vagues."

The worth of the boule de cristal is 60. The appraisal of the boule de cristal is "Une boule de cristal sans imperfections, qui vaut 60 dollars..."

Before taking the boule de cristal the first time, say "'Bien vu. Les pigeons superstitieux adorent ce genre de fariboles.' ricane Verdeterre."

Instead of searching the boule de cristal:
	say "La boule scintille, et les mots de la voyante ressurgissent dans votre esprit : [italic type]mort par l'eau[roman type]...";
	now the going nowhere boolean is true.

After shooting the boule de cristal, say "Vous visez et tirez, et votre balle (votre seule balle) rebondit sur la boule de cristal sans lui faire le moindre mal."


Part - Pont Inférieur the region

Lowerdeck is a region. Lower Deck and Galley and Miscellaneous are in Lowerdeck.

Section - Pont Inférieur la salle

Lower Deck is above Afthold.

The description of Lower Deck is "Le pont inférieur est bien plus accueillant que la cale[if the pâté gris musqué is not handled], et d'ailleurs sent plutôt bon[end if]. La cambuse est vers la proue, et la salle des cartes est vers la poupe. Des escaliers descendent vers la cale ou montent vers le pont principal."
	[TC: Because of the whole 'no equivalent of fore and aft', I don't need to be more precise. Also, 'fore' and 'aft' are used in the hold if I'm correct; wouldn't it make more sense to have the definitions at this moment instead?]
The printed name of Lower Deck is "Pont Inférieur".

Before smelling lower deck:
	if the pâté gris musqué is not handled:
		say "L'odeur semble venir de cette caisse." instead.


The portrait du capitaine is here. The portrait du capitaine is valuable. Understand "peinture" or "cadre" as the portrait.

The initial appearance of the portrait du capitaine is "Un portrait de votre capitaine est accroché à l'un des murs."

The description of the portrait du capitaine is "Le cadre est large d'environ cinquante centimètres, et la représentation de Verdeterre est un peu plus grande que le capitaine lui-même. Peinte à l'huile d'une façon plus ou moins maîtrisée, le portrait parvient à transmettre le courage et l'ingéniosité que Verdeterre a du mal à projeter en personne."

The height of the portrait du capitaine is 7. The sinking message of the portrait du capitaine is "L'eau emporte le portrait de votre noble capitaine, qui couine pitoyablement en le voyant disparaître."

The worth of the portrait du capitaine is 0. The appraisal of the portrait du capitaine is "Un portrait du Capitaine Verdeterre, à qui personne n'attache aucune valeur, mis à part le Capitaine Verdeterre, et qui se révéla donc impossible à vendre..."

Before taking the portrait du capitaine the first time, say "Verdeterre soupire. 'Ca sera dommage de devoir vendre un article qui a tant de valeur sentimentale et esthétique,' dit-il, 'mais c'est vrai que la situation est désespérée.'"

Before shooting the portrait du capitaine, say "Vous visez le portrait, mais vous n'arrivez pas à aller jusqu'à appuyer sur la détente. Il a l'air si noble."



The poupée en bois is here. The poupée en bois is valuable.

The initial appearance of the poupée en bois is "Une poupée en bois gît sur le sol."

The description of the poupée en bois is "C'est une petite fille en bois, avec des joues roses et des jambes filiformes. Elle n'a pas un seul vêtement sur elle."

The height of the poupée en bois is 2. The sinking message of the poupée en bois is "La petite poupée en bois s'éloigne en flottant."

The worth of the poupée en bois is 36. The appraisal of the poupée en bois is "Un poupée hollandaise en bois qui, après quelques modifications et une couche de peinture, fut vendue comme étant une 'idole de fertilité africaine' pour 36 dollars..."
	[TC: funnily enough, we don't appear to know what Dutch peg dolls are, and I didn't find a specific term for it, if it exists]

Before taking the poupée en bois the first time, say "'Tu sais quoi,' dit Verdeterre, 'cette poupée me donne une idée. Il vaudrait mieux la prendre avec nous.'"

After shooting the poupée en bois:
	say "Avec votre seule balle vous réduisez la poupée en morceaux.";
	remove the poupée en bois from play.




The caisse odorante is here. The caisse odorante is female. The caisse odorante is open. Understand "trou" as the caisse.

The initial appearance of the caisse odorante is "Il y a une grande caisse en bois ici, parce qu'il n'y avait pas la place de la mettre ailleurs."

Instead of taking the caisse odorante, say "'Laisse ça là !' aboie Verdeterre. 'Il n'y a pas la place pour des grandes boîtes dans le canot de sauvetage.'"

The description of the caisse odorante is "C'est une grande caisse, utilisée pour transporter différentes sortes de cargo[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: 'Cargo' fait référence à toute marchandise transportée sur un bateau.}[roman type][end if][if the caisse is shot]. Il y a un trou sur un de ses côtés, là où vous lui avez tiré dessus[end if]."

Instead of opening the caisse, say "Vous ne voyez le couvercle de la caisse nulle part."

Instead of closing the caisse, say "Vous ne voyez le couvercle de la caisse nulle part."

The height of the caisse odorante is 6. The sinking message of the caisse is "La caisse disparaît sous les eaux[if the pâté gris musqué is not handled], et la puanteur commence à s'estomper[end if]."

Before smelling the caisse:
	if the pâté gris musqué is not handled:
		say "Oui, c'est bien de cette caisse que vient cette odeur. L'odeur est un peu sucrée, en fait." instead;
	otherwise:
		say "La caisse sent encore comme cet espèce de pâte." instead.

The caisse can be shot. The caisse is not shot.

After shooting the caisse:
	say "Vous faites un trou irrégulier dans le côté de la caisse, et vous venez de gaspiller votre seule balle.";
	now the caisse is shot.
	
Understand "s'asseoir sur [the caisse]" as climbing.

Instead of climbing the caisse:
	say "Vous ne pouvez pas vraiment vous asseoir sur la caisse car son couvercle n'est pas là.";
	now the going nowhere boolean is true.

Instead of entering the caisse, say "'Sors de là !' aboie le capitaine, avant même que vous ne soyez vraiment à l'intérieur. 'On a un canot de sauvetage qui marche très bien en haut.'"


The pâté gris musqué is in the caisse odorante. Understand "ambre gris" or "ambre" or "gris" or "ambregris" as the pâté gris musqué. Understand "pâte grise musquée" or "pâte grise" or "pâté gris" or "pâté gris musqué" as the pâté gris musqué.

The description of the pâté gris musqué is "C'est gris et irrégulier, comme un caillou. Ca pourrait presque être un caillou, mais ça sent plus fort que tous les cailloux que vous avez jamais vus."

Instead of touching the pâté gris musqué, say "On dirait de l'argile gras. C'est vraiment bizarre. C'est dégoûtant."

Before smelling the pâté gris musqué:
	say "Non, l'odeur n'est pas mauvaise du tout. En fait, cette odeur est la meilleure que vous ayez senti depuis que vous avez embarqué. Dommage que ça soit un gros pâté graisseux, et pas un bon repas chaud, ou une femme." instead.

The height of the pâté gris musqué is 2. The sinking message of the pâté gris musqué is "L'espèce de pâté qui sent bon est emporté par le courant et s'éloigne en flottant."

The worth of the pâté gris musqué is 179. The appraisal of the pâté gris musqué is "Un pâté gris à l'odeur musquée, identifié plus tard comme étant un morceau rare d'ambre gris, évalué à [worth of the pâté gris musqué] dollars..."

Before taking the pâté gris musqué the first time, say "Le Capitaine Verdeterre fronce son nez. 'Que diable est cette chose ? Je n'aime pas trop de quoi ça a l'air.'"

After taking the pâté gris musqué the first time, say "Vous le gardez quand même."

After shooting the pâté gris musqué:
	say "Vous tirez votre seule balle dans la pâte grise, et un morceau s'envole. Une fumée noire et à l'odeur musquée sort de ce qui reste du pâté gris";
	now the description of the pâté gris musqué is "C'est gris et irrégulier, comme un caillou. Ca pourrait presque être un caillou, mais ça sent plus fort que tous les cailloux que vous avez jamais vus. C'est maintenant plus petit que ce que c[']était avant que vous ne tiriez dessus.";
	now the worth of the pâté gris musqué is 87;
	now the fumée is part of the pâté gris musqué;
	the fumée returns in 3 turns from now.
	
The fumée is in Amérique. The fumée is female.

Before smelling the fumée:
	say "Ca sent comme cette pâte grise, plus fort et plus musqué." instead.
	
Instead of taking the fumée:
	say "Impossible. C'est de la fumée.";
	now the going nowhere boolean is true.

At the time when the fumée returns:
	if the fumée is enclosed by the location:
		say "La fumée à l'odeur musquée se dissipe.";
	now the fumée is in Amérique.
	

Section - Cambuse

Galley is devant of Lower Deck. The description of Galley is "[if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: La 'cambuse' est la salle du bateau où l'on prépare la nourriture.}[roman type][paragraph break][end if]Cette salle était auparavant le domaine de Blaise, le cuisinier du bateau. Désormais, les placards sont vides, et la salle à l'état délabré coule rapidement."
The printed name of Galley is "Cambuse".


The morceau de biscuit is here. The initial appearance of the biscuit is "Sur le dessus d'un des placards se trouve un morceau de biscuit de mer."

Understand "morceau de biscuit de mer" or "biscuit" or "biscuit de mer" or "dur" or "galette" or "cracker" or "pain" or "biscuit de marin" as the biscuit.

The description of the biscuit is "C'est un objet vaguement rectangulaire avec plusieurs trous percés à travers [unicode 8212] léger, mais très dur au toucher.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un biscuit de mer est une petite galette dure que les marins mangent très souvent.}[roman type][end if]"
	[TC: Since the French for that is "sea biscuit", no need to explain it's a biscuit, so I just added a little bit of information to make it actually useful.]

Before attacking the biscuit:
	if the biscuit is not held:
		say "Vous commencez par le prendre.[line break]";
		silently try taking the noun;
		if the player is not holding the noun, stop the action.

Instead of attacking the biscuit, say "[one of]Avec un peu d'effort vous arrivez à casser le biscuit en deux. Ah, il n'y a pas de charançons à l'intérieur ![or]Le biscuit a déjà été cassé assez de fois.[stopping]"

The biscuit is edible. [A peine.] After eating the biscuit, say "Avant d'attaquer le biscuit, vous regardez votre capitaine. Il vous fait signe en hochant la tête, et vous engloutissez le biscuit entier."

The height of the biscuit is 4. The sinking message of the biscuit is "Les flots emportent le biscuit, qui disparaît."

After shooting the biscuit:
	say "Vous tirez la seule balle que vous avez à la seule nourriture que vous avez. Le biscuit est réduit en petits morceaux.";
	remove the biscuit from play.



The vieux violon is here. The violon is valuable. The printed name of the vieux violon is "violon".

The initial appearance of the violon is "Un vieux violon est accroché au mur."

The description of the violon is "Cet instrument usé appartenait à Blaise, avant la [one of]mutinerie. La tentative de [or][stopping]mutinerie."

The height of the violon is 8. The sinking message of the violon is "Les vagues montantes décrochent le violon du mur, et celui-ci s'éloigne en flottant."

The worth of the violon is 50. The appraisal of the violon is "Un violon relativement solide mais qui n'a rien de remarquable, vendu 50 dollars..."

Before taking the violon the first time, say "'C[']était bien gentil de la part de Blaise de laisser ça derrière lui,' ricane Verdeterre."

After shooting the violon:
	say "Votre pistolet crie quelque chose très fort, et le violon explose en un nuage de sciure et d'échardes sans plus aucune forme.";
	remove the violon from play.
	[TC: didn't really know what 'anonymous splinters' refered to here, is it a specific turn of phrase or is it another way of saying 'pieces of wood with no particular shape' or something?]



The placard is scenery in Galley. Understand "placards" or "étagère" or "étagères" as the placard.

The description of the placard is "Les placards sont tous ouverts et vides[if the placard is closed], sauf celui qui est toujours fermé[otherwise if the placard contains something], sauf celui dont vous avez défoncé la porte[otherwise][end if]."

[The height of the placard is 3. The sinking message of the placard is "The water has risen over the cabinets."] [Le placard ne peut pas couler parce que c'est du 'scenery'! (ie fait partie du paysage). Je ne sais pas trop comment régler ça, ou même si quelqu'un remarquera.]

The placard is closed.

Check opening the placard:
	if the placard is closed:
		say "La porte du placard ne bougera pas. Elle est fermée à clé.[first time][paragraph break]Verdeterre lève les yeux au ciel. 'Ouais, je sais pas du tout où est la clé. Oublie ça.'[only]" instead;
	otherwise:
		now the going nowhere boolean is true;
		say "Vous avez déjà réglé le problème." instead.
		
Check closing the placard:
	if the placard is closed:
		now the going nowhere boolean is true;
		say "Le placard est déjà fermé." instead;
	otherwise:
		say "Vous refermez la porte, mais elle se ré-ouvre avec nonchalance." instead.

After shooting the placard:
	say "'Bonne idée !' s'écrie Verdeterre en se sortant de la trajectoire. Vous détruisez le cadenas, et la porte du placard s'ouvre brusquement.";
	now the placard is open.


The placard contains a assiette en porcelaine. The assiette en porcelaine is valuable.

The description of the assiette is "Cette délicate assiette représente une grue, peinte sobrement et mise en valeur subtilement avec du vernis rose et bleu. A votre humble avis, cette assiette est sensationnelle."

The grue peinte is part of the assiette. The grue peinte is female. The description of the grue peinte is "La grue peinte regarde par dessus son épaule avec un air de dire 'il devait sûrement s'adresser à quelqu'un d'autre' avec son bec."

The vernis are part of the assiette. Understand "vernis" or "vernis bleus" or "vernis bleu" or "vernis roses" or "vernis rose" as the the vernis. The description of the vernis is "Le vernis dépeint un étang calme au crépuscule. Pendant un instant, la sérénité que la scène dégage vous transporte loin de cette terrible, terrible situation dans laquelle vous êtes."

The countingtext of the vernis is "Vous avez beau regarder l'assiette, vous n'êtes pas vraiment sûr de combien de types de vernis ont été utilisés"

The height of the assiette is 2. The sinking message of the assiette is "L'assiette en porcelaine se perd dans l'eau trouble."

The worth of the assiette is 160. The appraisal of the assiette is "Une assiette de porcelaine japonaise précieuse, vendue à un amateur de hérons pour 160 dollars..."

Before taking the assiette the first time, say "'D'où est-ce que ça sort ?' marmonne Verdeterre. 'Tu crois que Blaise nous cachait des choses?'"

After shooting the assiette, say "Vous tirez sur l'assiette, mais ce jeu emploie des techniques de cloisonnement pour vous orienter vers un nombre limité d'options, et celle ci n'est pas permise, alors rien ne se passe, j'imagine."
	[TC: no equivalent for 'gating' in French; I'll go for 'cloisonner'!]




The placard contains a pile d'argenterie. The pile d'argenterie is valuable. The pile d'argenterie is female.

The countingtext of the argenterie is "Dix fourchettes, autant de couteaux et de cuillères. Ca fait trente pièces d'argenterie. Oups : le dernier à en recevoir autant n'a pas été si chanceux que ça"
	[TC: I'm assuming it's a subtle Jesus pun? It's slightly harder to translate, because the only way 'pieces' makes sense in that context is if you say 'pieces of silverware', not 'pieces of silver'; the 'is this lucky?' seemed to be too subtle to a French ear (we don't really associate 30 pieces of silver to unluckiness, I think - or did I just misunderstood the reference?), so I slightly rewrote it as 'the last guy to have those wasn't really lucky'.]

The description of the argenterie is "Un assortiment dépareillé de fourchettes, cuillères et couteaux brillants."

Some fourchettes are part of the argenterie. The fourchettes are female. Understand "fourchette" as the fourchettes. The description of the fourchettes is "Chaque fourchette a une image d'un rat portant un chapeau à plumes gravée dessus."

The countingtext of the fourchettes is "Il y a dix fourchettes"

Some cuillères are part of the argenterie. The cuillères are female. Understand "cuillère" as the cuillères. The description of the cuillères is "Chaque cuillère a une image d'un rat portant un tricorne gravée dessus."

The countingtext of the cuillères is "Il y a dix cuillères"

Some couteaux are part of the argenterie. Understand "couteau" as the couteaux. The description of the couteaux is "Chaque couteau a une image d'un rat portant un chapeau de dragons gravée dessus."

The countingtext of the couteaux is "Il y a dix couteaux"

Before taking something that is part of the argenterie:
	say "Votre capitaine vous arrête. 'Tibert. Nous n'avons pas le temps de réorganiser le butin. Garde ça pour quand on sera dans un bateau qui ne coule pas.'"

The height of the pile d'argenterie is 2. The sinking message of the pile d'argenterie is "Les vagues qui montent recouvrent l'argenterie."

The worth of the argenterie is 90. The appraisal of the argenterie is "Un assortiment incomplet d'argenterie de Germain, le fameux orfèvre français, qui vaut 90 dollars..."
	[TC: what do you mean by Verlaine silver? Like, it belonged to the French poet?]
	[AC: I think I spent a very short period of time trying to find a French silversmith established before 1809 (or whenever this game takes place???) and "Verlaine" popped up on Google. In short, I have no idea. We should change it to "Labrande silver" instead.]
	[TC: I appreciate the offer :) I'm afraid there are no famous French silversmiths, so in any case the reference is going to be obscure. To try to keep the spirit intact, I'm going to use the Germain name, a family of XVIIIth century silversmiths who worked for the kings, but still explain who they are a bit.]

Before taking the argenterie the first time, say "Verdeterre hoche la tête avec approbation en vous regardant avoir du mal à ramasser chaque fourchette et couteau et cuillère. Ca ne serait pas très professionnel de sa part de vous aider à faire quoi que ce soit."

After shooting the pile d'argenterie, say "'Danse ! Danse !' criez-vous à l'argenterie, en tirant à ses pieds tout en riant comme un fou. 'Plus vite !'"
	[TC: I'm assuming what you had in mind was cowboys shooting towards the feet of enemies to make them jump out, thus making it look like they dance? I get the reference, but I don't really know how to convey the reference while sticking to the text. Am I missing something?]


Section - Divers

Miscellaneous is arrière of Lower Deck. The description of Miscellaneous is "C[']était au départ la salle des cartes, mais ensuite c'est devenu une sorte de remise pour stocker divers objets, et ensuite les déserteurs en tout genre ont quasiment vidé cette pièce."
The printed name of Miscellaneous is "Remise".

The boîte des drapeaux is here. The boîte des drapeaux is female. The boîte des drapeaux is a closed openable container. Understand "boîte" and "boîte à drapeaux" as the boîte des drapeaux. The printed name of the boîte des drapeaux is "boîte des drapeaux".

The initial appearance of the boîte des drapeaux is "La boîte à drapeaux est posée non loin."

The description of the boîte des drapeaux is "La boîte à drapeaux contient, enfin contenait, tous les drapeaux dont un bateau pirate pourrait avoir besoin. Au fil de vos nombreux voyages, beaucoup de ces drapeaux furent réduits en morceaux, sous le coup de la colère ou pour faire une bonne blague.[paragraph break][if the boîte des drapeaux is open]La boîte contient [a list of things contained by the boîte des drapeaux][otherwise]Pour l'heure, la boîte est fermée[end if]."

The height of the boîte des drapeaux is 5. The sinking message of the boîte des drapeaux is "La boîte à drapeaux est recouverte par l'eau."

Instead of taking the boîte des drapeaux, say "Vous ne parvenez pas à soulever la boîte à drapeaux, car on l'a solidement attachée par terre. En y repensant, ça n'était pas une très bonne idée."

After shooting the boîte des drapeaux, say "Vous tirez sur la boîte à drapeaux, mais elle est trop robuste et aucune réaction ne se produit."

Check searching the boîte des drapeaux:
	if the boîte des drapeaux is closed:
		try opening the boîte des drapeaux instead.



A signal is a kind of thing. 

Instead of examining a signal:
	try taking the noun;
	follow the shipwrecking rules.

Does the player mean taking a signal: it is very likely.

Instead of shooting a signal:
	say "Vous ne pouvez vous résoudre à gaspiller votre seule balle sur un drapeau à la noix.";
	now the going nowhere boolean is true.

The drapeau à rayons is a signal. The drapeau à rayons is in the boîte des drapeaux. The printed name of the drapeau à rayons is "drapeau rouge et jaune". Understand "rouge" or "jaune" or "rouge et jaune" or "drapeau rouge et jaune" or "drapeau rouge" or "drapeau jaune" or "drapeau" or "drapeaux" as the drapeau à rayons.

The drapeau rayé is a signal. Understand "rayure" or "rayures" or "drapeaux" as the drapeau rayé.

The drapeau à croix rouge is a signal. Understand "drapeaux" as the drapeau à croix rouge.

Instead of taking the drapeau à rayons the first time:
	now the boîte des drapeaux contains a drapeau rayé;
	remove the drapeau à rayons from play;
	say "Vous sortez le drapeau hors de la boîte et le déroulez : le motif représenté est une croix jaune sur fond rouge. 'C'est le drapeau de quoi ?' demandez-vous à votre capitaine.[paragraph break]'J'en sais rien. Le Danemark, je crois ? Bref, il ne nous sert à rien. Jette-le.'[paragraph break]Vous hochez la tête, et jetez le drapeau quelque part, hors de votre chemin.[paragraph break]Le drapeau en dessous a des rayures."
	
Instead of taking the drapeau rayé the first time:
	now the boîte des drapeaux contains a drapeau à croix rouge;
	remove the drapeau rayé from play;
	say "Vous dépliez le drapeau à rayures pour voir tout le motif. Il y a une rayure bleue, une blanche, une rouge, une blanche et une bleue.[paragraph break]'C'est le drapeau russe,' explique Verdeterre. 'Tu le tiens à l'envers.'[paragraph break]C'est juste un drapeau russe, de toute façon, alors vous vous en débarassez. Le drapeau suivant dans la boîte a un X rouge dessus."
	
Instead of taking the drapeau à croix rouge the first time:
	now the boîte des drapeaux contains the tapisserie de Saint Incertus;
	remove the drapeau à croix rouge from play;
	say "Ce drapeau a un motif en X rouge sur fond blanc. 'C'est le drapeau suisse,' dit Verdeterre, mais il s'arrête et se reprend: 'Non, attends. Le drapeau suisse c'est une croix blanche sur fond rouge. Alors celui-là, je suppose que c'est pour... la marine suisse.'[paragraph break]Le capitaine a l'air un peu énervé contre lui-même, alors vous vous débarrassez du drapeau qui le contrarie.[paragraph break]Au fond de la boîte à drapeaux, vous trouvez une tapisserie ancienne."
	


The tapisserie de Saint Incertus is valuable. The tapisserie de Saint Incertus is female. Understand "tapisserie ancienne" as the tapisserie.

Check examining the tapisserie:
	if the tapisserie is enclosed by the player:
		continue the action;
	otherwise:
		try taking the tapisserie instead.
		
Before taking the tapisserie the first time:
	say "Vous sortez la tapisserie et vous la dépliez. [The description of the tapisserie][paragraph break]'Hé, c'est le Martyre de Saint Incertus !' dit Verdeterre. 'C'est le saint patron des poursuivis, je crois. Dommage que ça ne soit pas le saint patron des naufrages. Il vaudrait mieux qu'on prenne cette tapisserie.'[paragraph break]Vous la pliez avec soin. 'Pourquoi fut-il martyrisé ?' demandez-vous.[paragraph break]'Eh bien, il y a quelques différences dans les règles entre l'Eglise Catholique des Humains et l'Eglise Catholique des Rats [unicode 8212] par exemple, selon l'Eglise humaine, tu n'as pas le droit de te déclarer un saint. C'est considéré comme présomptueux. Mais après tout ça nous a fait une belle tapisserie.'";
	continue the action.

The description of the tapisserie is "Elle représente un rat en robe cléricale allongé sur son dos, son ventre transpercé par la lance d'un paladin humain. Les doigts du rat sont levés soit en signe de bénédiction pieuse, soit tordus par la douleur."

The height of the tapisserie is 1. The sinking message of the tapisserie is "Au moment où l'eau touche la tapisserie ancienne, elle commence à se désagréger."

The worth of the tapisserie is 160. The appraisal of the tapisserie is "Une tapisserie remarquablement bien conservée représentant Saint Incertus l'Audacieux, valant 160 dollars pour les moines de son ordre..."

Check shooting the tapisserie:
	If Capitaine Verdeterre is in the location:
		say "'Attends !' crie Verdeterre. 'C'est une sainte relique, gamin ! Je te défends d'y toucher.'" instead;
		
After shooting the tapisserie:
	say "Vous tirez sur la tapisserie ancienne, et elle n'est plus d'une collection de toiles d'araignées. Verdeterre a l'air peiné.";
	remove the tapisserie from play.



The table des cartes is a supporter in Miscellaneous. The table des cartes is female. The initial appearance of the table des cartes is "Au centre de la salle se trouve la table des cartes[if something is supported by the table des cartes]; sur cette table se trouve [a list of things supported by the table des cartes][end if]."

The description of the table des cartes is "Au lieu d'une vraie carte, des vagues diagrammes ont été gravés sur la surface de la table. Ils ne veulent rien dire pour vous, mais pour Verdeterre ils sont des guides sans pareils pour naviguer l'océan."

The diagrammes vagues are part of the table des cartes. Understand "diagrammes" or "cartes" or "vague diagramme" or "diagramme vague" as the diagrammes vagues. The description of the diagrammes is "Vous plissez les yeux en regardant les diagrammes[first time]. 'Où sommes-nous exactement ?' demandez-vous.[paragraph break]'Je crois que je t'ai déjà dit d'arrêter de demander,' dit le capitaine[only]."

The countingtext of the diagrammes vagues is "Vous êtes incapable de compter les diagrammes, car vous ne pouvez pas dire où l'un finit et l'autre commence, ou vice-versa"

The height of the table des cartes is 7. The sinking message of the table des cartes is "La table des cartes résiste plutôt bien, mais finit par être renversée par les vagues."

Instead of taking the table des cartes:
	say "La table des cartes est trop grosse pour que vous puissiez la transporter.";
	now the going nowhere boolean is true.

Instead of shooting the diagrammes vagues, try shooting the table des cartes.

After shooting the table des cartes, say "Vous tirez votre seule balle dans la table, détruisant de fait la carte d'on ne sait quelle île, ou mer, ou condition météorologique.[paragraph break]Verdeterre lève les yeux vers vous avec intérêt, mais seulement pour un petit moment."



On the table des cartes is a sextant. The sextant is valuable.

The description of the sextant is "Les mots vous manquent pour décrire cet objet, même juste pour vous-même. C'est un bout de métal qui ressemble vaguement à une part de tarte. Beaucoup de miroirs, de lentilles et de cadrants y sont attachés.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un sextant est un outil qui sert à calculer sa latitude quand on est en mer.}[roman type][end if]"

Understand "calculer [text]" as a mistake ("Ce genre de choses vous dépasse.").

Understand "naviguer [text]" as a mistake ("Ce genre de choses vous dépasse.").

Understand "naviguer" as a mistake ("Ce genre de choses vous dépasse.").

The accoutrements are part of the sextant. Understand "miroirs" or "lentille" or "lentilles" or "cadrant" or "cadrants" as the accoutrements.

The countingtext of the accoutrements is "Vous faites du mieux que vous pouvez pour compter toutes les choses qui dépassent du sextant, mais votre cerveau n'est pas à la hauteur de la tâche"

Instead of doing anything other than examining with the accoutrements:
	say "Vous n'avez pas les capacités de manipuler les équipements du sextant d'une quelconque façon.";
	now the going nowhere boolean is true.

Instead of examining the accoutrements, try examining the sextant.

The height of the sextant is 1. The sinking message of the sextant is "Le sextant coule."

The worth of the sextant is 48. The appraisal of the sextant is "Un sextant cassé, dont la réparation coûté 20 dollars, avant d'être vendu 68 dollars, pour un profit total de 48 dollars..."

Instead of attacking the sextant the first time:
	say "Vous donnez un bon coup sur le sextant, et quelque chose sur sa surface se remet à sa place en claquant.";
	now the worth of the sextant is 68;
	now the appraisal of the sextant is "Un sextant en bon état de fonctionnement, vendu 68 dollars..."
	
Before taking the sextant the first time, say "'Je déteste ces trucs,' dit le capitaine. 'Personne n'en construira un assez petit pour que nous puissions l'utiliser.'"

Instead of shooting the accoutrements, try shooting the sextant.

After shooting the sextant, say "Vous tirez sur le sextant, mais la balle passe par le trou du milieu et ne touche même pas le sextant."




The tonneau is here. The tonneau is a supporter. Understand "baril" as the tonneau.

The initial appearance of the tonneau is "Il y a un tonneau dans le coin de la pièce."

The description of the tonneau is "Le baril a peut-être contenu de la nourriture ou à boire il y a un moment. Présentement, il est posé à l'envers."
	[TC: typo: how about making 'keg' a synonym of 'barrel' ;) ]

Instead of opening the tonneau:
	say "Présentement, il est posé à l'envers.";
	now the going nowhere boolean is true.

The height of the tonneau is 4. The sinking message of the tonneau is "Les vagues soulèvent le tonneau du sol, et il s'éloigne en tournant."

Instead of taking the tonneau:
	say "Le tonneau est trop gros pour être transporté.";
	now the going nowhere boolean is true.

After shooting the tonneau, say "Vous tirez et faites un trou dans le tonneau, mais aucun grog ne s'écoule.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Du 'grog', c'est du rhum coupé avec de l'eau.}[roman type][end if]"


The lampe à huile is valuable. The lampe à huile is female.

Instead of searching the tonneau, try looking under the noun.

Instead of turning the tonneau, try looking under the noun.

Instead of looking under the tonneau the first time:
	if the currently sinking deck is lowerdeck:
		if the relative water level is less than 3:
			say "En regardant sous le tonneau, vous trouvez une lampe à l'air ancien.";
			now the lampe à huile is in the location;
			try taking the lampe à huile;
		otherwise:
			remove the tonneau from play;
			say "Vous échouez à retourner le tonneau alors que l'eau est si haute, et il roule sur les vagues montantes en s'éloignant de vous." instead;
	otherwise:
		say "En regardant sous le tonneau, vous trouvez une lampe à l'air ancien.";
		now the lampe à huile is in the location;
		try taking the lampe à huile.

After taking the lampe à huile the first time:
	silently try inserting the lampe à huile into the sac;
	say "'Ca doit sûrement valoir quelque chose !' selon le capitaine, alors vous la jetez dans le sac.";
		
Instead of looking under the tonneau:
	say "Verdeterre vous crie dessus, encore une fois : 'On a déjà regardé sous ce tonneau, gamin !'"
		
The description of the lampe à huile is "Cette antiquité sordide n'a sûrement pas été utilisée depuis des années. Il n'y a aucune huile dedans, vous en êtes certain."

Instead of searching the lampe à huile, try examining the noun.

Instead of rubbing the lampe, say "Vous sentez que frotter la lampe est la bonne chose à faire, mais apparemment ça ne sert à rien."

The height of the lampe is 1. The sinking message of the lampe is "La lampe glisse sous la surface de l'eau."

The worth of the lampe is 6. The appraisal of the lampe is "Une lampe à huile sans valeur, vendue à une troupe de théâtre pour 6 dollars..."

After shooting the lampe, say "Vous tirez sur la lampe, mais même à bout portant il est possible de rater une cible comme celle-ci. Apparemment."




Part - pont principal the region

Maindeck is a region. Main Deck and Capstanroom and Crew Quarters and Mainmastroom and Captain's Quarters are in Maindeck.


Section - Plusieurs Arrière-plans Visibles Depuis Les Ponts Supérieurs

The plat-bord is a backdrop. Understand "rail" or "barrière" or "plat-bord" or "bord" as the plat-bord. The plat-bord is in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck. The description of the plat-bord is "Le plat-bord a toujours été plutôt robuste, et continuera sans doute à l'être tant que vous en aurez besoin.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Le 'plat-bord' est la ceinture horizontale en bois qui recouvre les bords du navires sur les ponts sans murs.}[roman type][end if]"

After shooting the plat-bord, say "Vous faites un autre trou dans un plat-bord qui a enduré des attaques similaires au fil des ans."


The mer is a backdrop. The mer is female. Understand "mers" or "océan" or "océans" or "vagues" or "eau" or "eaux" or "profonde" or "mousse" or "boisson" as the mer. The mer is in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top.
	[TC: "main" as synonym? Why?]
	[AC: "The main" is an archaic term for the ocean that exists in modern English only in the phrase "Pirates of the Spanish Main", which shows up on Google as a cool-looking board game but is also just a phrase about pirates that everyone remembers. Is there an equivalent French archaism?]
	[TC: Unfortunately, no - the game 'Pirates of the Spanish Main' was translated as 'Pirates of the New World' ('Nouveau monde' being the phrase everyone was using in the XVth century when talking about America). This one will have to be lost in translation!]

The description of the mer is "Elle s'étend à l'infini : une étendue bleue ininterrompue, pas même par une île. Qui aurait pensé que quelque chose de si ennuyeux pouvait être si mortel ?"

The countingtext of the mer is "Il y a une mer ici, mais vous savez en réalité qu'il y en a d'autres ailleurs"

Instead of taking the mer:
	say "Il n'y a pas de sac assez gros pour cela.";
	now the going nowhere boolean is true.

Instead of drinking the mer:
	say "Votre but a toujours été d'éviter de boire de l'eau de mer non stérilisée pendant autant de temps que possible.";
	now the going nowhere boolean is true.

Does the player mean examining the mer: it is very likely.

Does the player mean drinking the mer: it is very likely.

Does the player mean taking the mer: it is very likely.

Rule for clarifying the parser's choice of the mer:
	   do nothing.

After shooting the mer:
	say "Vous tirez votre seule balle dans les profondeurs de la mer, et vous sentez un sentiment de vengeance aussi dramatique qu'inutile vous emplir.";
	now bullettarget is "tiré dans les profondeurs salées".


The gréément is a backdrop. The gréément is in fo'c'sle and capstanroom and top and mainmastroom and main deck and quarterdeck. Understand "cordes" and "cordages" and "lignes" and "hauban" as the gréément. The description of the gréément is "Pour un marin expérimenté, se déplacer sur le réseau labyrinthique du gréément du bateau est aussi simple que marcher dans la rue, et pour vous c'est à peine plus difficile. Vous vous êtes entraîné.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Le 'gréément' fait référence aux lignes ou cordages utilisés sur un bateau. Le 'gréément dormant' soutient les mâts et le bout-dehors; le 'gréément courant' est  l'ensemble des cordages utilisés pour manipuler les voiles.}[roman type][end if]"

[Understand "scramble up [something]" as climbing.]
	[TC: no synonym in French except 'climb with precipitation'...]

Instead of climbing the gréément:
	if the location is Top:
		say "Vous vous dépêchez de redescendre sur le pont principal.";
		try going down;
	otherwise:
		say "Vous grimpez le gréément jusqu'à la hune.";
		now the player is in Top;
		try looking.
		
After shooting the gréément, say "Votre balle passe entre plusieurs trous dans les cordages, puis vous la perdez de vue."



The mâts are a backdrop. The mâts are in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top. Understand "mât de misaine" and "mât" and "misaine" and "artimon" and "mât d'artimon" and "d'artimon" and "grand mât" and "grand" as the mâts.
	[TC: fun fact: 'mât de misaine' is 'foremast', not 'mizzenmast', which is 'mât d'artimon'!]
	[TC: typo ? do you not have 'main mast' as a synonym for masts?]
	[TC: fun fact: 'mast' is another of those words that's evolved from the French ('mât') but has an extra 's' compared to French, because at some point we got rid of lots of 's' and replaced them with accents instead. In fact, if you want to speak 'old French', one of the most recognizable features is to add 's' in the middle of words that have accents. Another example of such a word is 'student' (French: 'étudiant'), derived from the old French 'estudiant'.]

The description of the mâts is "Il y a un mât près de la proue du bateau, et un mât près de la poupe du bateau, et un mât au milieu[if the nautical vocabulary notes boolean is true]. [italic type]{Note de vocabulaire nautique: Il s'agit respectivement du 'mât de misaine', du 'mât d'artimon' et du 'grand mât'.}[roman type][otherwise].[end if]"

Instead of climbing the mâts, try climbing the gréément.

After shooting the mâts, say "Vous visez l'un des mâts et tirez, mais ça ne fait pas grand-chose."

The countingtext of the mâts is "Il y a trois mâts"




The espars are a backdrop. Understand "espar" or "vergue" or "vergues" or "bôme" or "bômes" or "balestron" or "balestrons" or "livarde" or "livardes" as the espars. The espars are in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top. Understand "espar" as the espars. The description of the espars is "Autant que vous sachiez, 'espar' veut juste dire 'un gros poteau[quotation mark][if the nautical vocabulary notes boolean is true]. [italic type]{Note de vocabulaire nautique: En gros, oui. Il y en a de différents types, comme les beauprés, les mâts, les vergues, les bômes et les balestrons (aussi appelés livardes).}[roman type][otherwise].[end if]"

After shooting the espars, say "Votre seule balle laisse un trou fumant dans l'un des espars."

The countingtext of the espars is "Vous n'êtes pas sûr de ce qui compte comme étant un 'espar[quotation mark] et ce qui ne compte pas, c'est donc une perte de temps"



The voiles are a backdrop. The voiles are female. Understand "voile" as the voiles. The voiles are in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top. The description of the voiles is "Il y a tellement de types de voiles différents. Vous espérez que vous ne les apprendrez jamais tous par coeur[if the nautical vocabulary notes boolean is true]. [italic type]{Note de vocabulaire nautique: Des exemples de types de voiles sont la grand-voile, le grand hunier, le perroquet, le perroquet garni, le petit hunier, le perroquet volant, la voile d'artimon, la perruche, la voile à livarde, la bonnette maillée, la bonnette maillée des huniers, le foc, et la brigantine.}[roman type][otherwise].[end if]"

After shooting the voiles, say "Vous tirez et faites un petit trou dans l'une des voiles.[paragraph break]'Joli tir !' dit Verdeterre, faisant gentiment comme si c[']était celle que vous visiez."

The countingtext of the voiles is "Vous perdez des instants précieux à essayer de compter les voiles"



The ciel is a backdrop. The ciel is in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top. The description of the ciel is "Le ciel est bleu et énorme. Il vous suit partout."
	[TC: typo here: you copied/pasted 'the spars are in...', meaning the sky is nowhere!]

Instead of doing something other than examining or counting with the ciel, say "Allons, pas trop de fantasie."


The soleil is a backdrop. The soleil is in Main Deck and Capstanroom and Mainmastroom and Fo'c'sle and Quarterdeck and Top. The description of the soleil is "Vous décidez de ne pas regarder le soleil, car on vous a dit de ne pas le faire et ça vous fait mal aux yeux quand vous le faites."

Instead of doing something other than examining or counting with the soleil, say "Allons, pas trop de fantasie."


Section - pont principal the room

Main deck is above Lower Deck. The description of Main deck is "[if unvisited]Ah, enfin à l'air libre. [end if]La mer s'étend dans toutes les directions. Il n'y a pas de terre à l'horizon.[paragraph break]Vous vous en occuperez plus tard. Vers la proue, vous pouvez voir le grand mât, vers la poupe ce sont les quartiers du capitaine, au-dessus de vous se trouve la plage arrière, et en dessous, le pont inférieur."
The printed name of Main Deck is "Pont Principal".

Instead of going inside in Main deck, try going poupe.


The mouchoir en soie is here. "Un mouchoir en soie est accroché sur la cloison vers la poupe."
	[TC: no need for a nautical vocabulary note here, 'cloison' is used in both ships and houses.]

The mouchoir en soie is valuable. [Understand "hanky" or "hankie" as the handkerchief.]
	[TC: 'mouchoir' being short, we don't have common abbreviations]

The mouchoir en soie can be tied. The mouchoir en soie is tied.

Check taking the mouchoir en soie:
	if the mouchoir is tied:
		say "Vous tirez sur le mouchoir, mais il reste coincé dans le mur ; il est attaché depuis l'autre côté du mur." instead.
		
The description of the mouchoir en soie is "Le jour où vous et vos camarades vous êtes engagés avec le Capitaine Verdeterre, il vous a dit que le dernier membre d'équipage vivant de l['][italic type]Incapable[roman type] gagnerait ce joli mouchoir, pour vous encourager à ne pas vous faire tuer[first time]. Tiens, d'ailleurs : le reste de l[']équipage a déserté ! C'est maintenant votre mouchoir, vous l'avez bien mérité[only]."

After taking the mouchoir the first time:
	say "Le capitaine vous sourit en vous voyant prendre le mouchoir. 'Eh bien, mon garçon, j'ai fait une promesse et je tiens mes promesses. Le mouchoir est à toi.'[paragraph break]Vous frottez la soie entre vos doigts, et afin de montrer votre gratitude vous faites la remarque que c'est une récompense de grande valeur.[paragraph break]Le capitaine hoche la tête. 'Tu as raison. D'ailleurs, c'est peut-être de trop grande valeur. Ouais, tu ferais mieux de le mettre avec le reste des trésors pour qu'on le vende plus tard. Bonne idée.'[paragraph break]Vous mettez le mouchoir en soie dans le sac."
	
The height of the mouchoir en soie is 4. The sinking message of the mouchoir en soie is "Le mouchoir en soie disparaît sous l'eau."

The worth of the mouchoir is 10. The appraisal of the mouchoir is "Une écharpe en soie, vendue 10 dollars..."

After shooting the mouchoir:
	say "Vous tirez votre seule balle dans le mouchoir, ce qui le réduit en morceaux.";
	remove the mouchoir from play;
	remove the épingle from play.



The médaillon en argent is here. "Il y a un médaillon sur le pont." The médaillon is wearable. The médaillon is valuable.

Instead of touching the médaillon, say "Le médaillon est froid. Froid comme une promesse qui n'a pas été tenue."

The description of the médaillon is "Un médaillon en forme de coeur monté sur une chaîne fragile. Le médaillon est fermé."

The chaîne en argent is part of the médaillon. The description of the chaîne is "Cette petite chaîne en argent doit avoir été travaillée par des mains toutes petites."

The height of the médaillon is 1. The sinking message of the médaillon is "Le médaillon en argent disparaît sous la surface de l'eau."

The worth of the médaillon is 15. The appraisal of the médaillon is "Un médaillon en argent, vendu à un jeune homme épris d'amour et désespéré pour 15 dollars..."

Instead of shooting the chaîne en argent, try shooting the médaillon.

After shooting the médaillon:
	say "Votre balle heurte le médaillon, et les deux objets ainsi collés forment un seul morceau de métal qui, même si la forme est intéressante, a l'air d'un bout de ferraille sans valeur avec lequel vous ne pouvez pas faire grand-chose à part le jeter. Donc vous le jetez.";
	remove the médaillon from play.
	
Before taking the médaillon the first time:
	say "'Ooh, un bijou ! Bien vu, Tibert !' dit le capitaine."

Instead of opening the médaillon:
	say "Verdeterre vous regarde avec intérêt essayer d'ouvrir le petit fermoir du médaillon, et quand enfin vous y parvenez, il demande 'C'est une image de qui ?'[paragraph break]La petite peinture représente un rat de bonne allure. Gravé à l'intérieur du médaillon, vous pouvez voir le nom 'Etienne[quotation mark]. Vous tournez l'intérieur du médaillon vers Verdeterre pour qu'il le voie.[paragraph break]'Oh, ah oui, je la connais. Fais-moi voir ça,' dit-il en prenant le médaillon de vos mains. Il lance son bras au-dessus de sa tête et jette le médaillon aussi loin qu'il le peut.[paragraph break]'Ok, ça, c'est fait. Allons-y.' Vous décidez qu'il vaut mieux ne pas poser de questions.";
	remove the médaillon from play.

Section - Mainmast

Mainmastroom is devant of Main Deck. The printed name of Mainmastroom is "Grand mât". The description of mainmastroom is "Le grand mât est planté dans le pont devant vous, près du centre du bateau. C'est un peu comme le nombril du bateau. Si vous continuez vers la proue, vous arrivez vers le cabestan ; derrière vous, il y a les escaliers menant au pont inférieur, et au sommet du mât devant vous, c'est la hune."

The mainmast is scenery in mainmastroom. The description of the mainmast is "Le grand mât est le mât le plus grand et le plus important du navire[if the poignard is not handled]. Quelqu'un y a planté un poignard[end if]."

The poignard courbe is here. "Un poignard à l'air exotique est plantée dans le mât." Understand "poignée" and "manche" and "lame" and "pointe" and "janbiya" and "poignard exotique" and "exotique" and "poignard à l'air exotique" as the poignard courbe. The description of the poignard is "La poignée est finement ciselée, et la lame est courbée jusqu'à la pointe."

Before taking the poignard the first time:
	say "Vous tirez sur le manche du poignard, mais il reste enfoncé dans le mât.[paragraph break]'Hé, c[']était celui de Saad, non ?' demande Verdeterre. 'Qu'est-ce qu'il est devenu ?'[paragraph break]'Il me semble que vous lui avez dit que vous alliez le tuer, alors il s'est enfuit', dites-vous.[paragraph break]Il fronce les sourcils. 'Mince, je crois que t'as raison. Ouah. J'aurais dû être plus gentil.'" instead.
	
Check taking the poignard courbe:
	If the poignard is not handled:
		if a random chance of 2 in 3 succeeds:
			say "[one of]Le capitaine soupire en vous voyant tirer sur le manche. 'Ca ne bouge pas', dit-il[or]Le poignard reste coincé. Verdeterre lève les yeux au ciel[or]Vous avez beau tirer, le poignard ne bouge pas. 'Laisse ça tranquille, veux-tu ?' s'écrie Verdeterre[then at random]." instead;
		otherwise if a random chance of 2 in 3 succeeds:
			say "[one of]Vous tirez de toutes vos forces, mais ça ne change rien[or]Vous tirez sur le poignard, et on dirait qu'il [unicode 8212] est-ce qu'il a bougé ? Non, on ne dirait pas[or]Vous échouez à tirer le poignard du mât. Le capitaine se racle la gorge bruyamment[then at random]." instead;
		otherwise if a random chance of 1 in 2 succeeds:
			say "Vous tirez encore. Vous y êtes presque. Vous sentez la détermination du poignard faiblir." instead;
		otherwise:
			say "Avec un dernier grand effort, vous tirez le poignard du mât. 'Ok, super ; mets-le dans le sac.' dit Verdeterre.";
			now the poignard is handled;
			continue the action;
	otherwise:
		continue the action.

	




The poignard is valuable. The worth of the poignard is 276. The appraisal of the poignard is "Un [italic type]janbiya[roman type] du Yémen, avec une poignée en corne de rhinocéros, qui vaut 276 dollars..."

The height of the poignard is 8. The sinking message of the poignard is "La lame du poignard brille une dernière fois avant de disparaître sous l'eau trouble."

After shooting the poignard:
	say "Votre balle heurte la lame du poignard et y fait un gros trou dedans.";
	now the worth of the poignard is 135;
	now the description of the poignard is "Eh bien, c[']était un poignard très joli avant  que vous lui tiriez dessus.";
	now the appraisal of the poignard is "Un [italic type]janbiya[roman type] du Yémen, avec une lame endommagée et malheureusement irréparabe, qui vaut seulement 35 dollars..."
	[TC: typo: 35 or 135 here ?!]



The miroir de poche is here. "Un miroir de poche est posé par terre." 

The description of the miroir de poche is "Le miroir en lui-même est un objet élégant, avec un cadre aux lignes gracieuses et une surface polie. Le type dans le reflet, par contre, a connu des jours meilleurs."

Before taking the miroir the first time, say "Vous prenez le miroir, et Verdeterre vous fait signe de le mettre devant lui. Il se regarde dans le miroir pour vérifier que son chapeau est bien incliné sur le côté, pour lui donner un air intrépide. Il hoche la tête, satisfait."

The miroir de poche is valuable. The worth of the miroir de poche is 12. The appraisal of the miroir de poche is "Un miroir de poche sans grande valeur, vendu pour 12 dollars à un homme qui pensait que son âme était coincée à l'intérieur..."

The height of the miroir de poche is 1. The sinking message of the miroir de poche is "Le miroir disparaît sous les vagues."

After shooting the miroir de poche:
	say "Votre seule balle brise le miroir en mille morceaux, et vous avez instantanément le sentiment que c[']était une mauvaise idée.";
	remove the miroir de poche from play.


Section - Cabestan

Capstanroom is avant of Mainmastroom. The printed name of Capstanroom is "Cabestan".

The description of capstanroom is "Le cabestan se trouve à cette extrémité du pont.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un 'cabestan' est un mécanisme cylindrique utilisé pour soulever des objets lourds et augmenter la tension dans les cordages en les enroulant autour de son tambour.}[roman type][end if] Les quartiers de l[']équipage sont devant vous, et le grand mât est derrière vous, en direction de la pouple. En haut de quelques marches, c'est le château avant."

Instead of going inside in Capstanroom, try going proue.
	[TC: typo: do you mean 'instead of going inside in Capstanroom ?]


The cabestan is scenery in capstanroom. The description of the cabestan is "Il y a toujours un bâton enfoncé sur le cabestan, et un cordage est attaché autour [unicode 8212] même si vous ne savez pas ce qui peut y être encore attaché ."

The bâton is part of the cabestan. Understand "levier" as the bâton. Instead of pushing the bâton, try turning the cabestan. Instead of pulling the bâton, try turning the cabestan. Instead of turning the bâton, try turning the cabestan. Instead of shooting the bâton, try shooting the cabestan.

The description of the bâton is "Le bâton sert de levier pour vous permettre de faire tourner le cabestan." 

Instead of taking the bâton:
	say "Vous n'avez pas vraiment besoin de ce gros bout de bois.";
	now the going nowhere boolean is true.

The câble is part of the cabestan. The description of the câble is "L'autre extrémité du câble est quelque part dans le gréément, mais vous n'arrivez pas vraiment à voir où. Il y a un mécanisme caché quelque part dans le cabestan pour l'empêcher de se dérouler complètement."

After shooting the câble, say "Vous tirez votre seule balle vers le câble, mais vous ratez votre cible de loin, et votre balle finit dans la mer."

Instead of taking the câble:
	say "Vous ne pouvez pas prendre le câble ; il est enroulé autour du cabestan.";
	now the going nowhere boolean is true.

Instead of pulling the câble, try turning the cabestan. Instead of pushing the câble, try turning the cabestan. Instead of turning the câble, try turning the cabestan.

After examining the cabestan the first time, say "Verdeterre y grimpe dessus et vous instruit sans que vous lui ayez demandé quoi que ce soit : 'Tu vois, 'cabestan' vient d'un mot nordique ancien qui veut dire 'appartenant au capitaine'. Parce que ça appartient au capitaine. C'est pour ça que ça s'appelle un cabestan.'[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Ca n'est pas vrai.}[roman type][end if]"
	[TC: the anagram doesn't even remotely work in French ('cabestan' 'capitaine'), so I'll just have him pretend it's the etymology.]

Instead of taking the cabestan:
	say "Le cabestan est bien trop gros pour être pris, et il fait partie intégrante du pont.";
	now the going nowhere boolean is true.

Instead of pushing the cabestan, try turning the noun.

Instead of pulling the cabestan, try turning the noun.

Instead of turning the cabestan the first time:
	say "Vous vous collez au bâton et le poussez avec force. Rien ne se passe.[paragraph break]'C'est le mauvais sens', suggère le capitaine.[paragraph break]Vous sautillez de l'autre côté, et vous essayez de tourner le cabestan dans l'autre sens. Le tambour tourne, le câble se tend, et un peigne tombe du gréément.";
	if the currently sinking deck is maindeck:
		say "[line break]Il atterrit dans l'eau dans un petit clapotement et disparaît.";
	otherwise:
		now the peigne is in the location.
	
Instead of turning the cabestan, say "Vous poussez le cabestan un peu plus loin, mais rien d'autre ne tombe."

Before examining the cabestan:
	if the location is in the currently sinking deck:
		if the relative water level is greater than 6:
			now the going nowhere boolean is true;
			say "Vous ne pouvez pas vraiment voir le cabestan avec une telle hauteur d'eau." instead.

Before doing something other than examining with the cabestan:
	if the location is in the currently sinking deck:
		if the relative water level is greater than 6:
			now the going nowhere boolean is true;
			say "Vous ne pouvez pas vraiment voir le cabestan avec une telle hauteur d'eau." instead.

After shooting the cabestan, say "Vous tirez votre seule balle sur le cabestan, mais les dégâts que cela fait sont négligeables.".



The peigne is valuable. Understand "dent" or "dents" or "motif" or "motif floral" as the peigne. 

The initial appearance of the peigne is "Un peigne est par terre, sur le pont."

The description of the peigne is "C'est un peigne fin pour dames, avec un motif floral sur le dessus. Les dents se courbent avec grâce vers l'extrémité.".

Before taking the peigne the first time, say "Vous vous accroupissez pour prendre le peigne.[paragraph break]'Oh, je m'en souviens,' dit Verdeterre. 'Il a fallu que je m'en serve pour réparer...'[paragraph break]Il regarde en l'air, vers le gréément, l'air incertain. '... quelque chose d'important. Du coup, c'est sans doute une bonne chose qu'on s'en aille bientôt.'"

The height of the peigne is 1. The sinking message of the peigne is "Le peigne coule."

The worth of the peigne is 36. The appraisal of the peigne is "Un peigne joli mais pas si extraordinaire que ça, vendu on ne sait trop comment pour 36 dollars...".

After shooting the peigne:
	say "Vous tirez sur le peigne. Vous le réduisez en morceaux.[paragraph break]'Adieu, peigne,' chuchotez-vous, et Verdeterre lève les yeux au ciel.";
	remove the peigne from play.





The canot de sauvetage is here. The height of the canot de sauvetage is 15. The canot de sauvetage is an enterable container. Understand "canot" or "barque" as the canot de sauvetage.

The initial appearance of the canot de sauvetage is "[if the currently sinking deck is maindeck and the relative water level is greater than 3]Le canot de sauvetage est toujours relié aux bossoirs, et est aussi en train de flotter sur l'eau qui monte[otherwise]Votre canot de sauvetage est ici, suspendu par les bossoirs[end if]."

The description of the canot de sauvetage is "C'est un canot de sauvetage plutôt grand, avec bien assez de place pour le capitaine, son équipage et leur butin.".

Instead of shooting the canot de sauvetage the first time:
	say "Vous visez le canot de sauvetage. Le capitaine Verdeterre monte sur le dessus de votre arme et vous regarde droit dans les yeux.[paragraph break]'Si tu penses que tu peux faire un trou dans notre seule chance de survivre à ce désastre, tu devrais penser à ce que je te ferai après.'[paragraph break]Il saute de votre arme, et vous la baissez."
	
Instead of shooting the canot de sauvetage:
	say "C'est sans doute une mauvaise idée.";
	now the going nowhere boolean is true.

The bossoirs are scenery in capstanroom. Understand "bossoir" or "poulie" or "poulies" as the bossoirs. The height of the bossoirs is 15. The description of the bossoirs is "Les bossoirs pendent sur le côté du bateau, et un canot de sauvetage y est suspendu.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un 'bossoir' est une structure qui utilise des poulies pour monter ou descendre un bateau du côté du navire.}[roman type][end if]".

The countingtext of the bossoirs is "Il y a deux bossoirs, un pour chaque côté du canot de sauvetage"

Instead of taking the bossoirs:
	say "Les bossoirs sont attachés au pont.";
	now the going nowhere boolean is true.

Instead of shooting the bossoirs:
	say "Vous imaginez que quelque chose de terrible se passerait si vous faisiez ça.";
	now the going nowhere boolean is true.

Section - Quartiers de l'Equipage

Crew Quarters is avant of Capstanroom. The description of Crew Quarters is "Les quartiers de l[']équipage n'ont pas vocation à être accueillants ou confortablement meublés. Des hamacs sont accrochés au mur. La sortie est vers la poupe."
The printed name of Crew Quarters is "Quartiers de l[']équipage".

Instead of going outside in crew quarters, try going poupe.

The cithare is here. "Une vieille cithare est posée dans le coin." Understand "vieille cithare" and "corde" and "cordes" and "vieille" as the cithare. The cithare is valuable.

The description of the cithare is "C'est un de ces instruments ridicules avec trop de cordes à jouer en même temps. Vous ne vous souvenez pas avoir vu quelqu'un à bord en jouer, sûrement parce que c'est impossible."

Understand "jouer [the cithare]" as a mistake ("Vous grattez quelques notes. C'est loin d'être de la musique à vos oreilles.")

Before taking the cithare the first time, say "Vous désignez la cithare, et le capitaine dit 'Ouais, d'accord. Elle est désaccordée, par contre.'[paragraph break]Vous soulevez l'instrument. 'Comment savez-vous ça ?'[paragraph break]'Je n'en sais rien, mais ça m'a l'air logique, non ?'"

The height of the cithare is 2. The sinking message of the cithare is "La cithare s'éloigne en flottant."

The worth of the cithare is 40. The appraisal of the cithare is "Une cithare, d'origine inconnue, vendue 40 dollars à un fanatique de musique..."

After shooting the cithare:
	say "Vous tirez sur la cithare, et elle explode en un fracas de morceaux de bois et de cordes qui s'échappent dans tous les sens.";
	remove the cithare from play.



Some hamacs are here. The hamacs are scenery. Understand "hamac" as the hamacs.

The description of the hamacs is "C'est dur de se mettre à l'aise dans un de ces hamacs, mais regardons les choses du bon côté : ça fait un moment que vous n'avez pas été forcé de partager votre chambre avec quelqu'un d'autre !"

The countingtext of the hamacs is "Vous les regardez pendant un moment et comptez. Il y a...[paragraph break]Il y a beaucoup de hamacs"

Instead of entering the hamacs:
	say "Vaut mieux pas. Le capitaine ne sera probablement totalement pas d'accord.";
	now the going nowhere boolean is true.

The height of the hamacs is 15. The sinking message of the hamacs is "Les hamacs coulent, en quelque sorte."

Instead of taking the hamacs, say "[one of]Avant que vous n'ayez le temps de décrocher un hamac, Verdeterre fait claquer sa langue.[paragraph break]'Ne t'embête pas. On te trouvera bien quelque chose pour dormir. Ou du moins t'abriter. Laisse-moi m'en occuper,' dit-il[or]Avant que vous n'ayez le temps de décrocher un hamac, Verdeterre fait claquer sa langue[stopping]."

After shooting the hamacs, say "Vous tirez et faites un trou dans un des hamacs, mais ça ne change pas grand-chose ; tous les hamacs ici sont déjà plein de trous."

Instead of searching the hamacs the first time:
	say "En fouinant dans les hamacs de vos anciens camarades, vous trouvez un objet lourd : un échiquier.[paragraph break]'Hé, ça vient d'où, ça ?' demande Verdeterre.[paragraph break]'C[']était dans un des hamacs,' répondez-vous.[paragraph break]'Non, je veux dire avant ça.'[paragraph break]'Oh. Je sais pas. Désolé.'[paragraph break]'C'est pas grave,' dit Verdeterre.";
	now the échiquier is in the location;
	try taking the échiquier.
	
Instead of searching the hamacs:
	say "Verdeterre vous détourne des hamacs. 'Je crois qu'on a déjà regardé là-dedans.'"
	


The échiquier is valuable. Understand "échéquier" and "échecs" and "plateau" and "plateau d'échecs" as the échiquier.

The description of the échiquier is "Il semblerait que ça pourrait être un type d'échiquier de grande valeur. En tout cas c'est assez lourd pour en avoir l'air. Et assez brillant."

Instead of opening the échiquier, say "Vous regardez de plus près les côtés de cet échiquier. C'est peut-être possible d'atteindre l'intérieur de ce truc, mais vous ne voyez pas comment."

The height of the échiquier is 1. The sinking message of the échiquier is "L[']échiquier coule."

The worth of the échiquier is 28. The appraisal of the échiquier is "Un échiquier d'ivoir valant 28 dollars..."

After shooting the échiquier:
	say "Vous jetez l[']échiquier en l'air et tirez dessus pendant sa chute. Les débris volent partout dans la pièce.";
	remove the échiquier from play.

Section - Quartiers du Capitaine

Captain's Quarters is arrière of Main Deck. The description of Captain's Quarters is "C'est ici que le capitaine dort, là où il mange, là où il réfléchit très fort. La plupart de ces actions sont faites depuis le lit. Une étagère est fixée au mur, réservée aux objets préférés du capitaine."
The printed name of Captain's Quarters is "Quartiers du Capitaine".

Instead of going outside in Captain's Quarters, try going proue.

The épingle is in captain's quarters. "Une épingle dépasse de la cloison devant vous, celle où est accroché le mouchoir dehors." Understand "mouchoir" or "mouchoir de soie" as the épingle.

The description of the épingle is "L[']épingle transperce deux coins du mouchoir, ce qui fait qu'il est impossible de retirer le mouchoir depuis l'autre côté de la cloison."

Instead of pulling the épingle, try taking the noun. Instead of pushing the épingle, try taking the noun.

Instead of taking the épingle:
	say "Vous tirez l[']épingle du mouchoir, et elle retombe entre les planches. A présent, vous devriez pouvoir ramasser le mouchoir de l'autre côté du mur.";
	remove the épingle from play;
	now the mouchoir is not tied.
	
Instead of shooting the épingle:
	say "Vous visez l[']épingle. Verdeterre se racle la gorge[paragraph break]'Tibert, si tu veux récupérer le mouchoir, sers-toi de tes mains. Retire l[']épingle. Pas la peine d'être si dramatique pour n'importe quoi.'"
	


The lit du capitaine is scenery in Captain's Quarters. The description of the lit du capitaine is "Le capitaine a le privilège de pouvoir dormir dans un lit pour humains, plutôt qu'un lit à taille de rat, ou un hamac. C'est également un joli lit."

Instead of climbing the lit, try entering the noun.

Instead of entering the lit, say "Verdeterre saute entre vous et le lit. 'Qu'est-ce que t'es en train de faire ?' siffle-t-il entre ses dents. 'Il faut qu'on aille ramasser des richesses !'"

The height of the lit du capitaine is 4. The sinking message of the lit du capitaine is "Le lit du capitaine chavire."

After shooting the lit du capitaine:
	say "Vous faites un trou dans le lit du capitaine. Verdeterre n'a pas l'air trop fâché.[paragraph break]'C'est pas comme si j'allais encore m'en servir,' dit-il.";
	now the description of the lit du capitaine is "Il avait l'air bien plus tentant avant que vous ne fassiez ce gros trou dedans."



The oreiller en soie is on the lit du capitaine. The oreiller en soie is valuable.

The description of the oreiller en soie is "L'oreiller est très doux, et il a des jolis petits pompons [unicode 8212] le Capitaine Verdeterre ne mérite rien de moins. Franchement, il est assez gros pour qu'il puisse faire office de lit pour le capitaine à lui tout seul."

Some pompons argentés are part of the oreiller en soie. Instead of shooting the pompons, try shooting the oreiller. The description of the pompons is "Les pompons sont de couleur argentée. C'est tellement royal."

The countingtext of the pompons argentés is "Il y a quatre pompons, un à chaque coin (c'est un oreiller rectangulaire)"

Instead of shooting the pompons argentés, try shooting the oreiller en soie.

Before taking the oreiller en soie the first time, say "Vous prenez l'oreiller.[paragraph break]'Oh non. Ce petit truc va me manquer,' dit Verdeterre. 'Je n'ai jamais vu m'endormir sans lui. Mais fautes de merles, on mange des grives !'"
	[TC: 'it needs to must when the devil drives' means you have to settle for less while facing adversity, right? The corresponding French expression would be 'when lacking thrush, you eat robins'.]
	[AC: On "it needs to must...", the "joke" is that Verdeterre is remembering the expression "needs must, when the devil drives" incorrectly, because it's a fairly obscure saying. I think you could convey this aspect of the original by switching "thrush" and "robins" around, if that makes Verdeterre sound appropriately dim-witted.]

The height of the oreiller en soie is 2. The sinking message of the oreiller en soie is "L'oreiller en soie s'éloigne en flottant."

The worth of the oreiller en soie is 0. The appraisal of the oreiller en soie is "Un oreiller en soie que le Capitaine Verdeterre ne put se résoudre à vendre, et sur lequel il dort maintenant la majorité du temps..."

After shooting the oreiller en soie:
	say "Votre balle réduit l'oreiller en morceaux. Le capitaine jure en votre direction.";
	remove the oreiller en soie from play.
	


Instead of turning the lit du capitaine, try looking under the noun.

Instead of looking under the lit du capitaine the first time:
	if the currently sinking deck is maindeck:
		if the relative water level is less than 2:
			say "Vous vous accroupissez pour regarder sous le lit du capitaine, et y trouvez une coquille arrondie, plus grosse que votre main.[paragraph break]'C'est un nautile,' explique Verdeterre. 'Il faudrait que tu en voies un un jour qui a toujours sa partie molle à l'intérieur. Laisse-moi te dire que c'est une vision qui t'empêche de dormir la nuit. Bref, essayons de le vendre.'";
			now the coquille de nautile is in the location;
			try taking the coquille de nautile;
		otherwise:
			remove the lit du capitaine from play;
			say "Vous êtes incapable de vraiment voir ce qu'il y a sous le lit, et vous n'y arrivez qu'après l'avoir retourné." instead;
	otherwise:
		say "Vous vous accroupissez pour regarder sous le lit du capitaine, et y trouvez une coquille arrondie, plus grosse que votre main.[paragraph break]'C'est un nautile,' explique Verdeterre. 'Il faudrait que tu en voies un un jour qui a toujours sa partie molle à l'intérieur. Laisse-moi te dire que c'est une vision qui t'empêche de dormir la nuit. Bref, essayons de le vendre.'";
		now the coquille de nautile is in the location;
		try taking the coquille de nautile;
		
Instead of looking under the lit du capitaine:
	say "Verdeterre vous crie dessus, encore une fois : 'On a déjà regardé sous ça, garçon !'"

The coquille de nautile is valuable. The coquille de nautile is female.

The description of the coquille de nautile is "Dehors, il est blanc avec des rayures marron; l'intérieur est recouvert d'une texture brillante, comme une perle. La chose en entier se courbe sur elle-même avec une grâce céleste. Contempler cette coquille est une expérience transcendante."

The height of the coquille de nautile is 2. The sinking message of the coquille de nautile is "La coquille de nautile flotte pendant un court instant, mais s'enfonce très vite dans l'eau."

The worth of the coquille de nautile is 49. The appraisal of the coquille de nautile is "Une coquille de nautile qui est un peu rayée, vendue à un dandy britannique pour 49 dollars..."

After shooting the coquille de nautile:
	say "Vous tirez sur la coquille de nautile, et elle éclate en morceaux. Le capitaine jure en votre direction.";
	remove the coquille de nautile from play.
	


The étagère is scenery in Captain's Quarters. The étagère is female. The description of the étagère is "Le capitaine a fait mettre cette étagère pour exposer ses possessions préférées parmi celles qu'il était capable de retrouver."

The height of the étagère is 8. The sinking message of the étagère is "L[']étagère tombe du mur et s'éloigne en flottant."

Instead of shooting the étagère:
	say "Vous pouvez sans doute trouver quelque chose de mieux à détruire de la sorte.";
	now the going nowhere boolean is true.



The médaille en or is on the étagère. The médaille en or is valuable. Understand "médaille" or "médaille en or" or "lion" or "lion en colère" or "lion énervé" or "énervé" or "en colère" as the médaille.

The description of the médaille is "La médaille brille tellement fort que vous ne doutez pas que c'est de l'or. On y a gravé l'image d'un lion en colère."

Before taking the médaille the first time, say "Vous regardez le médaillon une fois de plus et demandez à Verdeterre, 'Qu'avez-vous fait pour qu'on vous décerne ça ?'[paragraph break]'Je l'ai volé.'"

The height of the médaille is 1. The sinking message of the médaille is "Le médaillon coule."

The worth of the médaille is 68. The appraisal of the médaille is "Un médaillon d'origine mystérieuse, vendu 68 dollars..."

After shooting the médaille:
	say "Vous visez le médaillon, mais Verdeterre le tire de la trajectoire au dernier moment, et au final vous faites un trou de plus dans le pont.";
	now bullettarget is "essayé de tirer sur le médaillon de Verdeterre".



The clé en fer is on the étagère. Understand "clef" as the clé. The clé en fer is female. The clé en fer unlocks the coffre-fort en fer. The description of the clé en fer is "C'est une clé plutôt grosse, le genre de clé qui devrait être plutôt dure à perdre."

After taking the clé en fer the first time, say "Les yeux de Verdeterre se mettent à briller quand vous prenez la clé. 'Je sais ce que c'est ! C'est la clé du coffre-fort dans la cale ! Je savais bien qu'elle était quelque part.'"

The height of the clé en fer is 1. The sinking message of the clé en fer is "La clé en fer coule."

After shooting the clé en fer:
	say "Vous essayez de tirer sur la clé, mais elle est petite, et vous la ratez.";
	now bullettarget is "essayé de tirer sur la clé en fer".

Part - Au Dessus Du Pont

Overdecks is a region. Fo'c'sle and Quarterdeck are in Overdecks.

Section - Château avant

Fo'c'sle is above Capstanroom. The printed name of Fo'c'sle is "Château Avant". The description of Fo'c'sle is "Le beaupré s'élance depuis la proue, et au dessous, la figure de proue. En bas des escaliers, le cabestan.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Le château avant est un pont surélevé sur le devant du bateau.}[roman type][end if]"

Instead of going poupe in fo'c'sle, try going down.


A épissoir is here. "Un épissoir est posé sur le pont." The description of the épissoir is "C'est un long cône en bois avec un bout qui a l'air très pointu. [if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Les épissoirs sont des outils utilisés pour manipuler les cordages.}[roman type][end if]"

After taking the épissoir the first time, say "'Est-ce qu'on a besoin de ça ?' demandez-vous à votre capitaine en montrant l[']épissoir.[paragraph break]Il dit, 'J'en doute un peu, mais pourquoi ne pas le prendre.'[paragraph break]Vous ramassez l[']épissoir."

The height of the épissoir is 1. The sinking message of the épissoir is "L[']épissoir s'éloigne lentement en flottant. 'Tant pis,' dit le capitaine."

After shooting the épissoir:
	say "Vous tirez votre seule balle sur l[']épissoir, et vous arrivez à exploser un bout de la grosse extrémité.";
	now the description of the épissoir is "C'est un long cône en bois avec un bout qui a l'air très pointu, et un morceau qui manque à l'autre bout (là où vous avez tiré, pour on ne sait quelle raison). [if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Les épissoirs sont des outils utilisés pour manipuler les cordages.}[roman type][end if]"



The prou is scenery in Fo'c'sle. Understand "proue" as the prou. The description of the prou is "En ce moment la proue n'est pas vraiment en train de creuser vaillamment un chemin à travers les vagues sans défense.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: La 'proue' est l'avant pointu du navire.}[roman type][end if]"
	[TC: that's not how you spell it, but since it's already the name of the direction 'fore', I have to spell it differently. The fact that it's the same word sucks, but I don't know how to fix it. :(]

Instead of doing something other than examining with the prou, say "Il n'y a pas grand-chose de plus à faire avec la proue."


The beaupré is scenery in Fo'c'sle. The beaupré is a supporter. The description of the beaupré is "Le beaupré pointe avec détermination vers la direction dans laquelle vous alliez. [if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: Le 'beaupré' est l'espar (le poteau) qui dépasse de la proue (la partie pointue du devant) du bateau.}[roman type][end if] Les focs sont replié sur le dessus."

After shooting the beaupré:
	say "Vous tirez votre seule balle vers le beaupré, mais il est assez fin pour que vous le manquiez, même à cette distance. Votre balle se perd dans la mer.";
	now bullettarget is "essayé de tirer sur le beaupré".

Some focs are part of the beaupré. Understand "foc" as the focs. The description of the focs is "Les focs sont repliés sur le beaupré. Ils ont été repliés pour la dernière fois.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Un 'foc' est une voile triangulaire attachée au beaupré.}[roman type][end if]"
	[TC: typo: Period missing at the end of the first sentence.]

The countingtext of the focs is "Il y a trois focs : le foc, le clinfoc et le foc volant"

Instead of doing something other than examining with the focs:
	say "En vérité, les focs en ont fait assez comme ça.";
	now the going nowhere boolean is true.

Instead of taking the beaupré:
	say "Le beaupré est fermement fixé à la proue.";
	now the going nowhere boolean is true.

Check climbing the beaupré:
	if the location is in the currently sinking deck:
		now the going nowhere boolean is true;
		say "Grimper sur le beaupré ne retarderait votre noyade que temporairement." instead;
	otherwise if the currently sinking deck is maindeck:
		if the relative water level is greater than 9:
			now the going nowhere boolean is true;
			say "Grimper sur le beaupré ne retarderait votre noyade que temporairement." instead.
		
Every turn while in fo'c'sle:
	if the currently sinking deck is maindeck:
		if the relative water level is greater than 9:
			if the beaupré supports the player:
				say "L'eau est trop haut à présent pour que vous puissiez vous suspendre au beaupré sans vous noyer.";
				try getting off the beaupré.

Instead of climbing the beaupré:
	move the player to the noun, without printing a room description;
	say "Vous grimpez et vous suspendez au beaupré, dans une position précaire.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: Le beaupré est aussi appelé 'faiseur de veuves', car c'est la partie la plus dangereuse du bateau.}[roman type][end if][line break][description of the figure de proue][paragraph break]";
	if the collier de perles is not handled:
		now the collier de perles is in the location;
		say "Autour de son cou, vous voyez un collier de perles."

Before climbing the beaupré:
	if the beaupré supports the player:
		try getting off the beaupré instead.

instead of going up in fo'c'sle:
	if the player is on the beaupré:
		say "Vous ne pouvez pas aller bien plus loin depuis ici.";
		now the going nowhere boolean is true;
	otherwise:
		try climbing the beaupré.

Understand "descendre" and "redescendre" as exiting.
			
Before going down in fo'c'sle:
	if the beaupré supports the player:
		try getting off the beaupré instead.
		
Before going up in fo'c'sle:
	if the beaupré supports the player:
		try getting off the beaupré instead.

Instead of getting off the beaupré:
	if the beaupré supports the player:
		say "En faisant très, très attention, vous redescendez du beaupré pour vous tenir en relative sécurité sur le château avant.";
		move the player to fo'c'sle, without printing a room description.

The figure de proue is here. The figure de proue is scenery. The figure de proue is female. The description of the figure de proue is "[if the player is not on the beaupré]Il faut que vous vous penchiez par-dessus le plat-bord pour bien la voir, ce qui n'est vraiment pas confortable, mais vous la voyez : une femme humaine en bois qui a besoin d'un coup de peinture[otherwise]Depuis cette position vous pouvez regarder la figure de proue droit dans les yeux. Elle a l'air vraiment trop calme, étant données les circonstances[end if]."

Before examining the figure de proue:
	if the location is in the currently sinking deck:
		now the going nowhere boolean is true;
		say "Vous ne pouvez plus voir la figure de proue à travers l'eau trouble." instead;
	otherwise if the currently sinking deck is maindeck:
		if the relative water level is greater than 9:
			now the going nowhere boolean is true;
			say "Vous ne pouvez plus voir la figure de proue à travers l'eau trouble." instead.

Before doing something other than examining the figure de proue:
	if the location is in the currently sinking deck:
		now the going nowhere boolean is true;
		say "Vous ne pouvez plus voir la figure de proue à travers l'eau trouble." instead;
	otherwise if the currently sinking deck is maindeck:
		if the relative water level is greater than 9:
			now the going nowhere boolean is true;
			say "Vous ne pouvez plus voir la figure de proue à travers l'eau trouble." instead.

After examining the figure de proue the first time:
	if the beaupré does not support the player:
		say "'Hé, c'est quoi ce truc qu'elle porte ?' demande Verdeterre.[paragraph break]En réalité, la figure de proue ne porte pas grand-chose, mais Verdeterre désigne ce qui semble être un collier, qui n'est pas en bois, autour de son cou. 'Va chercher ça !'";
		now the collier de perles is in fo'c'sle.

Before taking the collier de perles:
	if the collier de perles is not handled:
		if the beaupré does not support the player:
			now the going nowhere boolean is true;
			say "Le seul moyen d'atteindre ce collier serait de grimper sur le beaupré." instead;
		otherwise:
			now the collier de perles is handled;
			say "Vous décrochez une main du beaupré pour attraper le collier, et vous manquez de lâcher prise.[paragraph break]'Attention là-dessous !' crie Verdeterre. 'Je ne sais pas ce que je ferais si tu perdais un de nos trésors. Tu devrais sûrement me lancer le collier, pour ne pas que tu le perdes. Ou juste mets-le dans le sac, j'imagine'";
			continue the action.
			

Understand "grimper sur [something]" and "escalader onto [something]" as climbing.

After shooting the figure de proue:
	say "Le simple fait de se mettre en position pour regarder la figure de proue est assez dur comme ça, alors ça ne vous surprend pas (et ça ne surprend vraiment pas le Capitaine Verdeterre) quand votre balle rate complètement sa cible.";
	now bullettarget is "essayé de tirer sur la figure de proue".

The collier de perles is valuable. Understand "perle" as the collier de perles. The collier de perles is wearable. The description of the collier de perles is "Un collier de perles sublimes, parfaites. Certaines font la taille de votre pouce."

The countingtext of the collier de perles is "Il y a exactement cinquante-trois perles"

The worth of the collier de perles is 186. The appraisal of the collier de perles is "Un collier de perles extrêmement délicat, vendu à une 'princesse bavaroise' pour 186 dollars..."

The height of the collier de perles is 1. The sinking message of the collier de perles is "Le collier de perles coule sous l'eau, hors de votre vue."

After shooting the collier de perles:
	Say "Vous visez le collier, et tirez. Il explose: les perles volent partout, rebondissent sur les mors, et roulent hors de portée, et vous ne les voyez plus.";
	remove the collier de perles from play.



Section - Plage Arrière

Quarterdeck is above Main Deck. The printed name of Quarterdeck is "Plage Arrière". "Bien souvent, vous vous teniez ici, à la poupe du navire, une main solide sur le gouvernail, vous demandant où vous alliez. A présent vous n'allez nulle part.[paragraph break]Depuis ici vous voyez les vastes étendues de mer que vous avez traversées pour en arriver ici [unicode 8212] elles ressemblent beaucoup aux étendues de mer que vous pouvez voir dans les autres directions. En bas, c'est le pont principal.[if the nautical vocabulary notes boolean is true][italic type] {Note de vocabulaire nautique: La 'plage arrière' est un pont surélevé à la poupe d'un bateau.}[roman type][end if]"


The statuette en bronze is here. "Une statuette en bronze est posée sur les planches." The statuette en bronze is valuable. The statuette en bronze is female. Understand "statue" and "thoth" as the statuette. 

The description of the statuette is "La statuette représent un homme avec une tête d'oiseau, portant une coiffe extrêmement recherchée. Ou peut-être sont-ce ses propres plumes."

The height of the statuette is 1. The sinking message of the statuette is "La statue s'éloigne en roulant, dans les profondeurs."

The worth of the statuette is 4. The appraisal of the statuette is "Une reproduction médiocre d'une statue ptolémaïque du dieu égyptien Thoth, fondue en lingots de plomb et revendus pour 4 dollars..."
	[TC: really minor typo: you should write '4' instead of 'four' so that the objects' worth are unified.]

After shooting the statuette:
	say "Vous tirez sur la statuelle. La balle se loge sur le côté de la silhouette, et d'ailleurs les métaux semblent se déformer l'un dans l'eau assez confortablement, ce qui semble assez bizarre pour du bronze.";
	now the description of the statuette is "La statuette représent un homme avec une tête d'oiseau, portant une coiffe extrêmement recherchée. Ou peut-être sont-ce ses propres plumes. Une balle [unicode 8212] une vraie balle, que vous avez lui avez tiré dessus avec votre pistolet [unicode 8212] s'est logée sur le flanc de l'homme."


The gouvernail is scenery in quarterdeck. Understand "rayon" or "rayons" as the gouvernail. The description of the gouvernail is "C'est ici que vous vous teniez quand c'est arrivé. Le capitaine avait dit qu'il avait besoin d'aller s'allonger. Vous lui avez dit que vous pourriez naviguer par vous-même pendant un moment. Il vous faisait confiance.[paragraph break]Il faut que vous vous fassiez pardonner."

Understand "tourner [something]" as turning.

Instead of pushing the gouvernail, try turning the noun. Instead of pulling the gouvernail, try turning the noun.

Instead of turning the gouvernail, say "Vous tournez le gouvernail. Rien ne se passe."

The height of the gouvernail is 7. The sinking message of the gouvernail is "Vous ne pouvez plus voir le gouvernail."

After shooting the gouvernail, say "Vous tirez, et votre seule balle passe entre les rayons du gouvernail sans causer de dégâts."



Every turn (this is the tinkling boîte à musique rule):
	if the currently sinking deck is overdecks:
		rule succeeds;
	otherwise:
		If the location is quarterdeck:
			if a random chance of 1 in 3 succeeds:
				if the boîte à musique is not handled:
					if the current action is listening:
						rule succeeds;
					otherwise:
						say "Pendant une seconde, vous auriez pu jurer entendre de la musique.";
						now the music suspicion boolean is true;
				otherwise:
					rule succeeds.

The music suspicion boolean is a truth state that varies. The music suspicion boolean is false.
					
Understand "écouter la musique" as listening.

Instead of listening to quarterdeck:
	if the currently sinking deck is overdecks:
		say "Vous n'entendez rien d'intéressant." instead;
	otherwise:
		if the boîte à musique is not handled:
			say "Vous pouvez [if the music suspicion boolean is true]bien[otherwise][end if] entendre de la musique. Ca vient d'un petit tunnel que quelqu'un a rongé dans les planches."
			
The tunnel étroit is scenery in quarterdeck. Understand "trou" as the tunnel étroit. The description of the tunnel étroit is "Vous ne pouvez pas y voir très loin dans ce trou. Sans doute que celui qui l'a creusé voulait un peu d'intimité."

After shooting the tunnel étroit:
	say "Vous tirez votre seule balle dans le tunnel, ce qui ne semble pas provoquer quoi que ce soit."

Instead of listening to the tunnel étroit:
	if the boîte à musique is handled:
		say "Le trou ne fait plus de bruit.";
	otherwise:
		say "Ce trou est sans nul doute d'où provient la musique. C'est un tintement doux, comme un glockenspiel."
			
[Understand "reach in [something]" as searching.]
	[TC: can't think of a French equivalent, I don't think there is?]

Instead of searching the tunnel étroit:
	if the boîte à musique is handled:
		say "'Il n'y a plus rien là, garçon. Allons-y,' dit le capitaine.";
	otherwise if the currently sinking deck is overdecks:
		say "Le trou est déjà plein d'eau. Rien n'en sort à présent.";
	otherwise if the currently sinking deck is maindeck:
		say "[one of]Vous plongez votre bras dans le trou, aussi loin que vous le pouvez, mais vous n'arrivez pas à attraper quoi que ce soit.[paragraph break]Le Capitaine Verdeterre regarde l'eau qui monte sur le pont principal, et vous regarde. 'Euh, je ne crois pas qu'on aie le temps de faire ça maintenant,' dit-il. 'On devrait probablement rejoindre le canot de sauvetage rapidement.' Vous retirez votre bras[or]Le capitaine vous tire du trou. 'Sérieusement, garçon, allons-y,' vous implore-t-il[stopping].";
	otherwise:
		say "Vous plongez votre bras dans le trou, aussi loin que vous le pouvez, mais vous n'arrivez pas à attraper quoi que ce soit.[paragraph break]'Hé, qu'est-ce que tu fais, là ? Qu'est-ce que tu veux faire avec ce trou ?' demande Verdeterre en vous enlevant la main du tunnel. 'Ne fourre pas ton petit nez plat dans des affaires qui ne sont pas pour toi. Si il y a quelque chose à sortir d'un tunnel à rats, je le ferai. Attends-moi, et [italic type]ne fais pas de bêtises ici pendant mon absence[roman type].'[paragraph break]Le capitaine disparaît dans le tunnel.";
		now Capitaine Verdeterre is in Cuba;
		the triumphant return occurs in three turns from now;
		
Cuba is a room. [Cuba existe uniquement pour fournir une autre exception à la rgèle Captain Follows. Si j'utilisais simplement l'Amérique, la règle plus bas se déclencherait quand Verdeterre abandonne le joueur sur une plage arrière qui coule, ce qui n'aurait aucun sens.]

Instead of doing something other than waiting or examining in quarterdeck while Capitaine Verdeterre is in Cuba:
	say "Il ne vaut mieux pas. Le Capitaine Verdeterre a dit pas de bêtises.";
	now the going nowhere boolean is true.
	
At the time when the triumphant return occurs:
	say "'Ha! Ha ha!' Le capitaine émerge du tunnel en tirant un petit coffre en bois derrière lui. 'Tu y crois, à ça ? C'est ma boîte à musique[if the music suspicion boolean is true]! Elle a dû se mettre en route quand on a touché le récif[end if]!'[paragraph break]Il s'appuie sur la boîte et s'essuie le frong. 'Bon travail, c'est bien de l'avoir trouvée,' dit-il.[paragraph break]Est-ce qu'il vient juste de dire 'bon travail[quotation mark]?[paragraph break]Verdeterre fait claquer sa langue très fort, dissipant votre rêverie. 'Hey. Mets ça dans le sac,' exige-t-il.";
	now Capitaine Verdeterre is in quarterdeck;
	now the boîte à musique is in the location;
	now the boîte à musique is handled;
	try taking the boîte à musique.
	
The boîte à musique is a closed openable container. The boîte à musique is valuable. The boîte à musique is female. Understand "oiseau chanteur" and "oiseau" and "coffre" and "coffret" as the boîte à musique.

Instead of examining the boîte à musique, say "C'est une petite boîte à musique très jolie, avec des bords en bois polis[if the boîte à musique is open] et l'image d'un oiseau chanteur peinte à sous le couvercle[end if]. Une clé en cuivre dépasse d'un des côtés."
	[TC: typo: it says 'pewter key' here, but later it's a 'copper key' ! I choose copper.]

Instead of searching the boîte à musique, try examining the noun.

Instead of inserting something into the boîte à musique:
	say "Ceci ne peut pas contenir d'objets.";
	now the going nowhere boolean is true.

The clé en cuivre is part of the boîte à musique. The clé en cuivre is female. Instead of taking the clé en cuivre, say "Ca ne veut pas sortir." The description of the clé en cuivre is "C'est la clé que vous tournez pour remonter la boîte à musique."

Instead of shooting the clé en cuivre, try shooting the boîte à musique.

Understand "tourner [something]" and "remonter [something]" and "monter [something]" as turning.

Instead of turning the boîte à musique, try turning the clé en cuivre.

Instead of turning the clé en cuivre:
	say "Vous tournez la clé jusqu'à ce qu'elle ne puisse plus tourner.";
	now the winding is 6.
	
winding is a number that varies. Winding is 3.

After opening the boîte à musique:
	if winding is greater than 0:
		say "Vous ouvrez la boîte, et le petit carillon commence à retentir[if capitaine verdeterre is in the location]. Verdeterre semble perdu dans ses pensées pendant un instant[end if].";
	otherwise:
		say "Vous ouvrez la boîte, mais aucun son n'en sort[first time]. Elle a sans doute besoin d'être remontée[only]."
		
After closing the boîte à musique, say "Vous fermez le couvercle de la boîte à musique[if winding is greater than 0], et la musique s'arrête brusquement[end if]."

Every turn (this is the open boîte à musique rule):
	if the boîte à musique is enclosed by the location:
		if the boîte à musique is open:
			if winding is greater than 0:
				decrease winding by 1;
				if winding is 5:
					say "La boîte à musique [one of]joue le début d'une chanson joyeuse[or]recommence sa chanson joyeuse[stopping].";
				if winding is 4:
					say "La mélodie de la boîte à musique se répète, un tout petit peu plus lentement.";
				if winding is 3:
					say "A mesure que la boîte à musique s'essouffle, la musique change. Elle n'est plus très joyeuse maintenant.";
				if winding is 2:
					say "La boîte à musique se traîne, lentement et tristement.";
				if winding is 1:
					say "Maintenant la boîte à musique fait des bruits carrément plaintifs.";
				if winding is 0:
					say "La boîte à musique joue ses dernières notes, puis est silencieuse.";
				
The worth of the boîte à musique is 300. The appraisal of the boîte à musique is "Une boîte à musique genevoise extraordinaire qui vaut 300 dollars..."

The height of the boîte à musique is 1. The sinking message of the boîte à musique is "La boîte à musique coule."

Check shooting the boîte à musique:
	if the boîte à musique is open:
		if winding is greater than 0:
			say "Vous essayez de tirer sur la boîte à musique, mais le son est tellement joli [unicode 8212] vous ne pouvez tout simplement pas le faire." instead;
		otherwise:
			continue the action;
	otherwise:
		continue the action.
		
After shooting the boîte à musique:
	say "Vous tirez sur la boîte à musique, qui est réduite en morceaux.[paragraph break]'Que [unicode 8212] pourquoi diable as-tu fait ça ?' crie Verdeterre. 'C'est quoi ton problème ?'[paragraph break]Mais vous n'avez aucune réponse.";
	remove the boîte à musique from play.

Part - The Airy Domain of Zeus

Zeus is a region. Top is in Zeus.

Section - Top

Top is above Mainmastroom. The description of Top is "[if the nautical vocabulary notes boolean is true][italic type]{Note de vocabulaire nautique: La 'hune' est une plateforme au sommet d'un des petits mâts du bateau, soutenant le mât de perroquet, qui est un mât attaché au sommet d'un petit mât. Sur le mât de perroquet, se trouve le mât de grand perroquet.}[roman type][paragraph break][end if]Quelle hauteur vertigineuse ! Les haubans montent plus haut, bien sûr, mais c'est assez haut ici."
The printed name of Top is "Hune".

The mât de perroquet is scenery in top. Understand "mat" and "mat de perroquet" and "perroquet" and "mât de grand perroquet" as the mât de perroquet. The description of the mât de perroquet is "Ouais, il est toujours là."

Instead of doing something other than examining with the mât de perroquet:
	say "Ne vous en préoccupez pas.";
	now the going nowhere boolean is true.

The petite couronne en laiton is here. The petite couronne en laiton is valuable. The petite couronne en laiton is female. Understand "morceau" and "morceau de laiton" as the couronne. The initial appearance of the couronne is "Un morceau de laiton est pris entre les planches."

Instead of wearing the petite couronne en laiton, say "La couronne est tellement petite qu'elle tombe immédiatement de votre tête[if capitaine verdeterre is in the location]. Le Capitaine Verdeterre vous jette un regard noir[end if]."

The description of the couronne is "C'est une petite couronne en laiton, avec aucun ornement."

After examining the couronne the first time:
	now the initial appearance of the couronne is "Une petite couronne en laiton est coincée entre les planches."

Before taking the couronne the first time, say "C'est une couronne miniature, peut-être de la taille d'une cuillère à soupe.[paragraph break]'Ca !' crie Verdeterre. 'Ca c'est important. Mets-le dans le sac. Ne la perds pas.'"

The worth of the couronne is 0. The appraisal of the couronne is "Une petite couronne en laiton, pour laquelle Verdeterre n'a même pas voulu évoquer l'idée de la vendre..."

The height of the couronne is 1. The sinking message of the couronne is "La couronne est recouverte par l'eau et disparaît."

After shooting the couronne:
	say "Vous essayez de tirer sur la couronne, mais elle est trop petite. Ce sont les planches du bateau qui sont touchées à la place.";
	now bullettarget is "essayé de tirer sur cette couronne en laiton"



The mouette is here. "Une mouette est perchée plus loin sur le gréément." Understand "oiseau" and "serre" and "serress" as the mouette. The mouette is female.

Every turn (this is the mouette escapes rule):
	if the location is top:
		if the mouette is in the location:
			if the currently sinking deck is zeus:
				if the relative water level is 6:
					say "La mouette crie une dernière fois et s'envole.";
					remove the mouette from play.

The description of the mouette is "La mouette semble vous regarder dans les yeux d'un air de défi. Ses serres agrippent une montre en or. Enfin, est-ce que c'est des serres si elles sont palmées ?"



After examining the mouette the first time:
	if Capitaine Verdeterre is in the location:
		say "'Les mouettes ! La vermine de la mer ! Je les déteste,' maugrée le capitaine."

Instead of asking the mouette about something, say "La mouette crie d'un air cruel.[if capitaine verdeterre is in the location].[paragraph break]'Toi-même, patate !' crie Verdeterre[end if]."

Instead of telling the mouette about something, say "La mouette crie d'un air cruel.[if capitaine verdeterre is in the location].[paragraph break]'Toi-même, patate !' crie Verdeterre[end if]."

Instead of answering the mouette that something, say "La mouette crie d'un air cruel.[if capitaine verdeterre is in the location].[paragraph break]'Toi-même, patate !' crie Verdeterre[end if]."

Persuasion rule for asking the mouette to try doing something:
	say "La mouette ne fait que caqueter follement en réponse.";
	persuasion fails.

After shooting the mouette:
	if the currently sinking deck is zeus:
		say "Votre tir manque sa cible de loin, mais le recul est assez fort pour que la mouette lâche son butin et s'envole. La montre tombe dans l'eau.";
		remove the mouette from play;
	otherwise if the currently sinking deck is overdecks:
		say "Votre tir manque sa cible de loin, mais le recul est assez fort pour que la mouette lâche son butin et s'envole. La montre tombe dans l'eau.";
		remove the mouette from play;
	otherwise if the currently sinking deck is maindeck:
		say "Votre tir manque sa cible de loin, mais le recul est assez fort pour que la mouette lâche son butin et s'envole. La montre tombe dans l'eau.";
		remove the mouette from play;
	otherwise:
		remove the mouette from play;
		now the montre en or is in mainmastroom;
		say "Votre tir manque sa cible de loin, mais le recul est assez fort pour que la mouette lâche son butin et s'envole. La montre tombe sur le pont plus bas.";

Instead of taking the mouette:
	say "La mouette est hors de portée. Vous êtes sûr qu'elle en est consciente, et qu'elle se sent très maline.";
	now the going nowhere boolean is true.

Check taking the montre en or:
	if the mouette carries the montre en or:
		now the going nowhere boolean is true;
		say "La mouette est hors de portée, et de plus elle semble assez attachée à l'objet." instead;
	otherwise if the montre en or is not handled:
		say "Vous prenez la montre. 'Cette ordure d'oiseau a essayé de voler notre montre,' dit Verdeterre, 'mais on lui a montré qui est le patron, pas vrai ?'";
		now the montre en or is handled;
		continue the action;

Check shooting the montre en or:
	if the mouette carries the montre en or:
		try shooting the mouette instead.



The mouette carries the montre en or. The montre en or is valuable. The montre en or is female. The initial appearance of the montre en or is "Une montre en or gît sur le pont, apparemment intacte même après sa descente."

The description of the montre en or is "Quand la lumière se reflète sur elle, on dirait presque plus un oeuf en or. C[']était quand la dernière fois que vous avez mangé un oeuf ?"

Instead of turning the montre en or, say "Vous remontez la montre, mais ça ne semble pas accomplir grand-chose."

Instead of opening the montre en or, say "Vous ouvrez la montre. Il y a quelques aiguilles et des nombres à l'intérieur. Vous refermez la montre."

The worth of the montre en or is 160. The appraisal of the montre en or is "Une montre en or, utilisée comme appât dans une arnaque qui vous rapporta 160 dollars..."

The height of the montre en or is 1. The sinking message of the montre en or is "La montre glisse sous les vagues et est perdue."

After shooting the montre en or:
	say "Vous tirez sur la montre, et elle érupte en une orgie d'engrenages et de ressorts.";
	remove the montre en or from play.



Volume - Trucs débiles

casting xyzzy is an action applying to nothing. Understand "xyzzy" and "lancer xyzzy" and "dire xyzzy" as casting xyzzy.

Instead of casting xyzzy:
	say "[italic type]{Note de vocabulaire de fictions interactives: 'XYZZY' est une vieille blague de connaisseurs, une commande que tout auteur de fictions interactives avec parseur doit intégrer à son jeu et réfléchir à une réponse rigolote, même si il a déjà écrit toutes les blagues rigolotes qu'il avait en stock en écrivant le reste du jeu.}[roman type][paragraph break]";
	now the going nowhere boolean is true.

casting plugh is an action applying to nothing. understand "plugh" and "lancer plugh" and "dire plugh" as casting plugh.

Instead of casting plugh:
	say "Gretchen, je veux plus entendre cette expression débile ! Et arrête de jouer les entremetteuses.";
	now the going nowhere boolean is true.
	[TC: oh, this one is soooo tricky. It's a "Mean Girls" quote that kinda spread by itself afterwards among English speakers, but not among French speakers. Like, at all. So nobody really knows who Gretchen is, and we don't have quote websites (or French memes websites) quoting this particular line, so people can't really find it by Googling it, can they?
	I could try to find an equivalent expression/meme (i.e. a "famous" movie quote of someone being shot down for trying to create and spread a new slang word), but I could not think of anything for the life of me. The closest I could find was an example from the French movie "Steak": the hero just got out of prison after 7 years, and a friend drives him home and tell him jokingly "You missed so much in 7 years! For instance, if you want to be hip, don't say "hi". Say "boot"." ("Si tu veux être pointu, tu dis pas "salut". Tu dis "bottine!"."). The only problem is, this movie was very badly reviewed by audiences (it didn't make a lot of sense and wasn't overtly funny either, it was not was people were expecting), and not a lot of people would know that quote. Also, it would probably require creating a new "bottine!" command, since the game is correcting the player...
	So I went and checked out the French version of "Mean Girls", which is called "Lolita Malgré Moi" (that's called dedication to the craft). And the French quote is "Gretchen, je veux plus entendre cette expression débile ! Et arrête de jouer les entremetteuses." ("Gretchen, I don't want to hear this stupid expression anymore ! And stop trying to play matchmaker." cause she just said something like "you like him? that's so fetch!"). It's still kind of the same spirit, you still reprimand the player for using that expression. So I kept the whole line, with the matchmaker thing, so that's it's not just the game calling the player Gretchen but something bigger, this way the player can sense that something is weird and that it's probably a quote, then try to find this quote. But it might fall flat, because it's definitely not a thing over here. Stop trying to make "Stop trying to make [x] happen. It's not going to happen" happen in France. It's not going to happen. ]